# ScriptedLight.ScriptedLight

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 00473 00474 00475 00476 00477 00478 00479 00480 00481 00482 00483 00484 00485 00486 00487 00488 00489 00490 00491 00492 00493 00494 00495 00496 00497 00498 00499 00500 00501 00502 00503 00504 00505 00506 00507 00508 00509 00510 00511 00512 00513 00514 00515 00516 00517 00518 00519 00520 00521 00522 00523 00524 00525 00526 00527 00528 00529 00530 00531 00532 00533 00534 00535 00536 00537 00538 00539 00540 00541 00542 00543 00544 00545 00546 00547 00548 00549 00550 00551 00552 00553 00554 00555 00556 00557 00558 00559 00560 00561 00562 00563 00564 00565 00566 00567 00568 00569 00570 00571 00572 00573 00574 00575 00576 00577 00578 00579 00580 00581 00582 00583 00584 00585 00586 00587 00588 00589 00590 00591 00592 00593 00594 00595 00596 00597 00598 00599 00600 00601 00602 00603 00604 00605 00606 00607 00608 00609 00610 00611 00612 00613 00614 00615 00616 00617 00618 00619 00620 00621 00622 00623 00624 00625 00626 00627 00628 00629 00630 00631 00632 00633 00634 00635 00636 00637 00638 00639 00640 |
    //=============================================================================
    // ScriptedLight. (version 1.1)
    //=============================================================================
    //
    //
    // Copyright © 2001, Lode Vandevenne.
    //
    //The ScriptedLight Allows you to dynamicly change LightBrightness, LightHue, LightSaturation,   LightRadius, VolumeBrightness, VolumeFog, VolumeRadius, DrawScale, LightType and LightEffect  during  gameplay.  These changes can be done by Waves(WAVE_Sinus, WAVE_DoubleSinus, WAVE_SawTooth,   WAVE_Square,  WAVE_AdvancedSquare, WAVE_Random or WAVE_Constant) or Keys(Up to 4 pre-defined   combinations of settings), and all of this can be controlled by Triggers or by  Father Time.  You   have control over the speed, smoothness, amplitude, phase and much more of the Waves.  And, with the   ScriptedLight, you can make lights  similar to the TriggerLight, but here the corona will be  triggered  on and off too! (the classic, official TriggerLight doesn't do this).  A special effect is   added:  FX_TriggerFlickerOn, to simulate a tubelight that flickers before going on.
    //
    //A detailed manual and example map should be included.  If you don't have these, you can find them at http://www.planetunreal.com/lode  Also check there for new versions.
    //
    //Do not distribute any scripts that are based on this script without permission of the   author.  The author of this script is not responsible for any damage caused by this script.
    //
    //Contact me at lode@altern.org for suggestions, bugs, questions or whatever

    class ScriptedLight expands Light;

    enum ETriggerAction //For TriggerToggle please set ReTriggerDelay of the trigger to 0.5 or more
    {
    	TA_IgnoreTrigger, //Ignore any Events
    	TA_TriggerTurnsOn, //Light remains on after Event
    	TA_TriggerTurnsOff, //Light remains off after Event
    	TA_TriggerToggle, //Light toggles on/off for every event
    	TA_TriggerControlOn, //light is on while you stand in trigger radius
    	TA_TriggerControlOff, //light is off while you stand in trigger radius
    	TA_TriggerRandom, //if you touch the trigger the light will go randomly on or off
    };

    var(SLWave) float A; //Variables for waveformulas.
    var(SLWave) float B; //The use of these variables depends on the wavetype.
    var(SLWave) float C;
    var(SLWave) float D;
    var(SLWave) float E;
    var(SLWave) float F;
    var(SLWave) float G;
    var(SLWave) float H;
    var(SLWave) byte SquareOffValue; //The values the wave has when the SquareWave, RandomWave
    var(SLWave) byte SquareOnValue; //and SimpleSquareWave get in their "Off" or "On" position
    var(SLWave) float FlickerTime; //The time FX_TriggerFlickersOn keeps flickering
    var(SLWave) float ScriptedLightPeriod; //This is the length of one TimeCycle

    var(SLUse) bool bUseBrightness; //If True, the waves and keys...
    var(SLUse) bool bUseHue; //...are used on the chosen lightsettings...
    var(SLUse) bool bUseSaturation; //...If False, the settings in Lighting...
    var(SLUse) bool bUseRadius; //...and LightColor are kept
    var(SLUse) bool bUseVolumeBrightness;
    var(SLUse) bool bUseVolumeFog;
    var(SLUse) bool bUseVolumeRadius;
    var(SLUse) bool bUseDrawScale;
    var(SLUse) bool bUseBrightness2; //These are used for the DoubleSinusWave
    var(SLUse) bool bUseHue2;
    var(SLUse) bool bUseSaturation2;
    var(SLUse) bool bUseRadius2;
    var(SLUse) bool bUseVolumeBrightness2;
    var(SLUse) bool bUseVolumeFog2;
    var(SLUse) bool bUseVolumeRadius2;
    var(SLUse) bool bUseDrawScale2;
    var(SLUse) byte HueStartPoint; //LightHue to start with (you'll rarely need this, if ever)
    var(SLUse) bool bUseCorona; //These 3 are only used for "digital" waves such as...
    var(SLUse) bool bUseLightEffect; //...SquareWave and RandomWave...
    var(SLUse) bool bUseLightType; //...but also for Keys
    var(SLUse) float DrawScaleStartPoint;

    var(SLTrigger) ETriggerAction TriggerAction; //How a trigger affects the light
    var(SLTrigger) bool bInitiallyOff; //If True, the light will be off before triggered.
    var(SLTrigger) byte TriggerOffValue; //The values used on Light settings when it's...
    var(SLTrigger) byte TriggerOnValue; //...triggered "Off" or "On"
    var(SLTrigger) bool bTriggerCoronaToo; //If True, corona is only there when the light is on.
    var(SLTrigger) bool bUseEvent;

    var(SLKeys) byte KeyBrightness[4]; //These are the settings that you can set for...
    var(SLKeys) byte KeyHue[4]; //...Key0, Key1, Key2 and Key3...
    var(SLKeys) byte KeySaturation[4]; //...Only if the appropriate bUse___ bool is True...
    var(SLKeys) byte KeyRadius[4]; //...These settings are used
    var(SLKeys) byte KeyVolumeBrightness[4];
    var(SLKeys) byte KeyVolumeFog[4];
    var(SLKeys) byte KeyVolumeRadius[4];
    var(SLKeys) byte KeyDrawScale[4];
    var(SLKeys) float KeyTime[4]; //The time the key remains constant
    var(SLKeys) float TransTime[4]; //The time the key needs to smoothly change to the next key
    var(SLKeys) int StartKey; //Only for KEY_Trigger: the key the light starts at
    var(SLKeys) int NumKeys; //Only for KEY_Trigger: the number of keys (2,3 or 4)
    var(SLKeys) ELightType KeyLightType[4]; //These work for the constant parts of the keytransition and...
    var(SLKeys) ELightEffect KeyLightEffect[4]; //...are kept constant during smooth transitions
    var(SLKeys) byte bKeyCorona[4]; //This is a byte because bools don't support arrays. 1 means True
    var(SLKeys) bool bSwapDirection; //Doesn't work (yet) :)

    var float SLTicker;
    var float TimerControl;
    var int ArrayValue;
    var float TurnOnTimer;
    var int FlickerStatus;
    var float RandomValue;
    var float SLWave;
    var bool bSLWave;
    var float SLWave2;

    ////////////////////////////////
    function PostBeginPlay()
    {
    	TurnOnTimer = 0;
    	FlickerStatus = 0;
    	ScriptedLightperiod = 1/ScriptedLightPeriod;
    	if (bInitiallyOff == True)
    	{
    		LightBrightness = TriggerOffValue;
    		if (bTriggerCoronaToo) bCorona = False;
    	}
    }

    ////////////////////////////////
    function TriggerActions()
    {
    Switch(TriggerAction)
    	{
    		case TA_IgnoreTrigger:
    			break;
    		case TA_TriggerTurnsOff:
    			LightBrightness = TriggerOffValue;
    			if (bTriggerCoronaToo) bCorona = False;
    			bInitiallyOff = True;
    			break;
    		case TA_TriggerTurnsOn:
    			LightBrightness = TriggerOnValue;
    			if (bTriggerCoronaToo) bCorona = True;
    			bInitiallyOff = False;
    			break;
    		case TA_TriggerToggle:
    			Switch ( bInitiallyOff )
    			{
    				case True:
    					LightBrightness = TriggerOnValue;
    					if (bTriggerCoronaToo) bCorona = True;
    					bInitiallyOff = False;
    					break;
    				case False:
    					LightBrightness = TriggerOffValue;
    					if (bTriggerCoronaToo) bCorona = False;
    					bInitiallyOff = True;
    					break;
    			}
    			break;
    		case TA_TriggerControlOn:
    			LightBrightness = TriggerOnValue;
    			if (bTriggerCoronaToo) bCorona = True;
    			bInitiallyOff = False;
    			break;
    		case TA_TriggerControlOff:
    			LightBrightness = TriggerOffValue;
    			if (bTriggerCoronaToo) bCorona = False;
    			bInitiallyOff = True;
    			break;
    		case TA_TriggerRandom:
    			RandomValue = FRand();
    			if (RandomValue < 0.5)
    			{
    				LightBrightness = TriggerOnValue;
    				if (bTriggerCoronaToo) bCorona = True;
    				bInitiallyOff = False;
    			}
    			else
    			{
    				LightBrightness = TriggerOffValue;
    				if (bTriggerCoronaToo) bCorona = False;
    				bInitiallyOff = True;
    				DoEvent();
    			}
    			break;
    	}
    }

    ////////////////////////////////
    function UnTriggerActions()
    {
    Switch( TriggerAction )
    	{
    		case TA_TriggerControlOn:
    			LightBrightness = TriggerOffValue;
    			if (bTriggerCoronaToo) bCorona = False;
    			bInitiallyOff = True;
    			break;
    		case TA_TriggerControlOff:
    			LightBrightness = TriggerOnValue;
    			if (bTriggerCoronaToo) bCorona = True;
    			bInitiallyOff = False;
    			break;
    		default:
    			break;
    	}
    }

    ////////////////////////////////
    function DoEvent()
    {
    	local actor A;
    	if (bUseEvent)
    	{
    		foreach AllActors( class 'Actor', A, Event ) { if (a!=None) a.Trigger(self, None); }
    	}
    }

    ////////////////////////////////
    function ApplySettings(float SLApply, bool bApply)
    {
    		If (bUseBrightness && bInitiallyOff == False) LightBrightness = SLApply;
    		If (bUseHue) LightHue = SLApply + HueStartPoint;
    		If (bUseSaturation) LightSaturation = SLApply;
    		If (bUseRadius) LightRadius = SLApply;
    		If (bUseVolumeBrightness) VolumeBrightness = SLApply;
    		If (bUseVolumeFog) VolumeFog = SLApply;
    		If (bUseVolumeRadius) VolumeRadius = SLApply;
    		If (bUseDrawScale) DrawScale = DrawScaleStartPoint*SLApply/255;
    		If (bUseCorona && bInitiallyOff == False) bCorona = bApply;
    }

    ////////////////////////////////
    function ModifyKeySingle(int Array1)
    {
    	If (bUseBrightness && bInitiallyOff == False) LightBrightness = KeyBrightness[Array1];
    	If (bUseHue) LightHue = KeyHue[Array1] + HueStartPoint;
    	If (bUseSaturation) LightSaturation = KeySaturation[Array1];
    	If (bUseRadius) LightRadius = KeyRadius[Array1];
    	If (bUseVolumeBrightness) VolumeBrightness = KeyVolumeBrightness[Array1];
    	If (bUseVolumeFog) VolumeFog = KeyVolumeFog[Array1];
    	If (bUseVolumeRadius) VolumeRadius = KeyVolumeRadius[Array1];
    	If (bUseDrawScale) DrawScale = KeyDrawScale[Array1]/64;
    	If (bUseCorona && bKeyCorona[Array1] == 0) bCorona = False;
    	If (bUseCorona && bKeyCorona[Array1] == 1) bCorona = True;
    	If (bUseLightType) LightType = KeyLightType[Array1];
    	If (bUseLightEffect) LightEffect = KeyLightEffect[Array1];
    }

    ////////////////////////////////
    state() WAVE_Sinus
    {
    	function tick(float DeltaTime)
    	{
    		SLWave = 255*(D+A*Sin(B*ScriptedLightPeriod*Level.TimeSeconds*2*pi));
    		ApplySettings(SLWave, bCorona);
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}

    }

    ////////////////////////////////
    state() WAVE_SawTooth
    {
    	function tick(float deltatime)
    	{
    		SLTicker = ScriptedLightPeriod*Level.TimeSeconds - TimerControl;
    		if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    		{
    			TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    		}
    		SLWave = A*SLTicker+B;
    		ApplySettings(SLWave, bCorona);
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}
    }

    /////////////////////////////
    state() WAVE_AdvancedSquare
    {
    	function tick(float DeltaTime)
    	{
    		SLTicker = ScriptedLightPeriod*Level.TimeSeconds - TimerControl;
    		if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    		{
    			TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    		}
    		If (SLTicker < H) {SLWave = SquareOffValue; bSLWave = False;}
    		If (SLTicker < G) {SLWave = SquareOnValue; bSLWave = True;}
    		If (SLTicker < F) {SLWave = SquareOffValue; bSLWave = False;}
    		If (SLTicker < E) {SLWave = SquareOnValue; bSLWave = True;}
    		If (SLTicker < D) {SLWave = SquareOffValue; bSLWave = False;}
    		If (SLTicker < C) {SLWave = SquareOnValue; bSLWave = True;}
    		If (SLTicker < B) {SLWave = SquareOffValue; bSLWave = False;}
    		If (SLTicker < A) {SLWave = SquareOnValue; bSLWave = True;}
    		ApplySettings(SLWave, bSLWave);
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}

    }

    /////////////////////////////
    state() WAVE_Square
    {
    	function tick(float DeltaTime)
    	{
    		SLTicker = ScriptedLightPeriod*Level.TimeSeconds - TimerControl;
    		if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    		{
    			TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    		}

    		If (SLTicker < 0.5)  ApplySettings(SquareOffValue, False);
    		If (SLTicker >= 0.5) ApplySettings(SquareOnValue, True);
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}
    }

    ////////////////////////////////
    state() WAVE_Random
    {
    	function tick(float DeltaTime)
    	{
    		SLTicker = ScriptedLightPeriod*Level.TimeSeconds - TimerControl;
    		if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    		{
    			TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    			DoRandom();
    		}
    	}

    	function DoRandom()
    	{
    		RandomValue = FRand();
    		If (RandomValue < A) ApplySettings(SquareOffValue, False);
    		If (RandomValue >= A) ApplySettings(SquareOnValue, True);
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}
    }

    ////////////////////////////////
    state() WAVE_DoubleSinus
    {
    	function tick(float deltatime)
    	{
    		SLWave = 255*(D+A*Sin(B*ScriptedLightPeriod*Level.TimeSeconds*2*pi + C));
    		SLWave2 = 255*(H+E*Sin(F*ScriptedLightPeriod*Level.TimeSeconds*2*pi + G));

    		If (bUseHue && !bUseHue2) LightHue = SLWave + HueStartPoint;
    		If (bUseSaturation && !bUseSaturation2) LightSaturation = SLWave;
    		If (bUseRadius && !bUseRadius2) LightRadius = SLWave;
    		If (bUseVolumeBrightness && !bUseVolumeBrightness2) VolumeBrightness = SLWave;
    		If (bUseVolumeFog && !bUseVolumeFog2) VolumeFog = SLWave;
    		If (bUseVolumeRadius && !bUseVolumeRadius2) VolumeRadius = SLWave;
    		If (bUseDrawScale && !bUseDrawScale2) DrawScale = DrawScaleStartPoint*SLWave/255;
    		If (bUseBrightness && !bUseBrightness2 && bInitiallyOff == False) LightBrightness =  SLWave;

    		If (!bUseHue && bUseHue2) LightHue = SLWave2 + HueStartPoint;
    		If (!bUseSaturation && bUseSaturation2) LightSaturation = SLWave2;
    		If (!bUseRadius && bUseRadius2) LightRadius = SLWave2;
    		If (!bUseVolumeBrightness && bUseVolumeBrightness2) VolumeBrightness = SLWave2;
    		If (!bUseVolumeFog && bUseVolumeFog2) VolumeFog = SLWave2;
    		If (!bUseVolumeRadius && bUseVolumeRadius2) VolumeRadius = SLWave2;
    		If (!bUseDrawScale && bUseDrawScale2) DrawScale = DrawScaleStartPoint*SLWave2/255;
    		If (!bUseBrightness && bUseBrightness2 && bInitiallyOff == False) LightBrightness =  SLWave2;

    		If (bUseHue && bUseHue2) LightHue = (SLWave+SLWave2) + HueStartPoint;
    		If (bUseSaturation && bUseSaturation2) LightSaturation = (SLWave+SLWave2);
    		If (bUseRadius && bUseRadius2) LightRadius = (SLWave+SLWave2);
    		If (bUseVolumeBrightness && bUseVolumeBrightness2) VolumeBrightness =  (SLWave+SLWave2);
    		If (bUseVolumeFog && bUseVolumeFog2) VolumeFog = (SLWave+SLWave2);
    		If (bUseVolumeRadius && bUseVolumeRadius2) VolumeRadius = (SLWave+SLWave2);
    		If (bUseDrawScale && bUseDrawScale2) DrawScale =  DrawScaleStartPoint*(SLWave+SLWave2)/255;
    		If (bUseBrightness && bUseBrightness2 && bInitiallyOff == False) LightBrightness =  (SLWave+SLWave2);

    	}

    	function trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger( actor Other, pawn EventInstigator )
    	{
    		UnTriggerActions();
    	}

    }

    ///////////////////////////
    state() WAVE_Constant
    {
    	function trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger( actor Other, pawn EventInstigator )
    	{
    		UnTriggerActions();
    	}

    }

    ///////////////////////////////
    state() KEY_Timed
    {
    	function tick(float DeltaTime)
    	{
    	//	local bool bSLWave;
    		SLTicker = ScriptedLightPeriod*Level.TimeSeconds - TimerControl;
    		if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    		{
    			TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    		}
    		If (SLTicker > KeyTime[0] && SLTicker <= TransTime[0]) ModifyKeySingle(0);
    		If (SLTicker > TransTime[0] && SLTicker <= KeyTime[1])  ModifyKeyDouble(0,1,KeyTime[1],SLTicker);
    		If (SLTicker > KeyTime[1] && SLTicker <= TransTime[1]) ModifyKeySingle(1);
    		If (SLTicker > TransTime[1] && SLTicker <= KeyTime[2])  ModifyKeyDouble(1,2,KeyTime[2],SLTicker);
    		If (SLTicker > KeyTime[2] && SLTicker <= TransTime[2]) ModifyKeySingle(2);
    		If (SLTicker > TransTime[2] && SLTicker <= KeyTime[3])  ModifyKeyDouble(2,3,KeyTime[3],SLTicker);
    		If (SLTicker > KeyTime[3] && SLTicker <= TransTime[3]) ModifyKeySingle(3);
    		If (SLTicker > TransTime[3] && SLTicker <= 1-KeyTime[0])  ModifyKeyDouble(3,0,1-KeyTime[0],SLTicker);
    	}

    	function ModifyKeyDouble(int Array1, int Array2, float Time2, float Ticker)
    	{
    		local float Mult1, Mult2, Mult3;
    		Mult1 = (Ticker - TransTime[Array1])/(Time2-TransTime[Array1]);
    		Mult2 = (Time2 - Ticker)/(Time2-TransTime[Array1]);
    		If (bUseHue) LightHue = Mult2*KeyHue[Array1] + Mult1*KeyHue[Array2] + HueStartPoint;
    		If (bUseSaturation) LightSaturation = Mult2*KeySaturation[Array1] +  Mult1*KeySaturation[Array2];
    		If (bUseRadius) LightRadius = Mult2*KeyRadius[Array1] + Mult1*KeyRadius[Array2];
    		If (bUseVolumeFog) VolumeFog = Mult2*KeyVolumeFog[Array1] +  Mult1*KeyVolumeFog[Array2];
    		If (bUseVolumeRadius) VolumeRadius = Mult2*KeyVolumeRadius[Array1] +  Mult1*KeyVolumeRadius[Array2];
    		If (bUseDrawScale) DrawScale = (Mult2*KeyDrawScale[Array1] +  Mult1*KeyDrawScale[Array2])/64;
    		If (bUseCorona && bKeyCorona[Array1] == 0) bCorona = False;
    		If (bUseCorona && bKeyCorona[Array1] == 1) bCorona = True;
    		If (bUseLightType) LightType = KeyLightType[Array1];
    		If (bUseLightEffect) LightEffect = KeyLightEffect[Array1];
    		If (bUseBrightness && bInitiallyOff == False) LightBrightness =  Mult2*KeyBrightness[Array1] + Mult1*KeyBrightness[Array2];
    		If (bUseVolumeBrightness) VolumeBrightness = Mult2*KeyVolumeBrightness[Array1] +  Mult1*KeyVolumeBrightness[Array2];
    	}

    	function Trigger(actor Other, pawn EventInstigator)
    	{
    		TriggerActions();
    	}

    	function UnTrigger(actor Other, pawn EventInstigator)
    	{
    		UnTriggerActions();
    	}
    }

    /////////////////////////////////
    state() KEY_Triggered
    {
    	function tick(float DeltaTime)
    	{
    	if (StartKey < 4) ModifyKeySingle(StartKey);
    	}

    	function trigger(actor Other, pawn EventInstigator)
    	{
    		Switch (NumKeys)
    		{
    			case 2:
    				Switch( StartKey )
    				{
    					case 0:
    						StartKey = 1;
    						ModifyKeySingle(1);
    						break;
    					case 1:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    					default:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    				}
    				break;
    			case 3:
    				Switch( StartKey )
    				{
    					case 0:
    						StartKey = 1;
    						ModifyKeySingle(1);
    						break;
    					case 1:
    						StartKey = 2;
    						ModifyKeySingle(2);
    						break;
    					case 2:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    					default:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    				}
    				break;
    			case 4:
    				Switch( StartKey )
    				{
    					case 0:
    						StartKey = 1;
    						ModifyKeySingle(1);
    						break;
    					case 1:
    						StartKey = 2;
    						ModifyKeySingle(2);
    						break;
    					case 2:
    						StartKey = 3;
    						ModifyKeySingle(3);
    						break;
    					case 3:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    					default:
    						StartKey = 0;
    						ModifyKeySingle(0);
    						break;
    				}
    				break;
    			default:
    				break;
    		}
    	}
    }

    //////////////////////////////////
    state() FX_TriggerFlickersOn
    {
    	function trigger(actor Other, pawn EventInstigator)
    	{
    		Switch(TriggerAction)
    		{
    			case TA_IgnoreTrigger:
    				break;
    			case TA_TriggerTurnsOff:
    				LightBrightness = TriggerOffValue;
    				if (bTriggerCoronaToo) bCorona = False;
    				FlickerStatus = 2;
    				break;
    			case TA_TriggerTurnsOn:
    				If (FlickerStatus != 2) {FlickerStatus = 1; bInitiallyOff = False; TurnOnTimer = Level.TimeSeconds;}
    				break;
    			case TA_TriggerToggle:
    				Switch (bInitiallyOff)
    				{
    					case False:
    						LightBrightness = TriggerOffValue;
    						if (bTriggerCoronaToo) bCorona = False;
    						FlickerStatus = 0;
    						bInitiallyOff = True;
    						break;
    					case True:
    						If (FlickerStatus == 0) {FlickerStatus = 1; bInitiallyOff = False; TurnOnTimer = Level.TimeSeconds;}
    						break;
    					default:
    						break;
    				}
    				break;
    		}
    	}

    	function tick(float deltatime)
    	{
    		if (FlickerStatus == 1)
    		{
    			if (ScriptedLightPeriod*Level.TimeSeconds - TimerControl > 1)
    			{
    				TimerControl = ScriptedLightPeriod*Level.TimeSeconds;
    				DoRandom();
    			}

    			if (Level.TimeSeconds - TurnOnTimer > FlickerTime)
    			{
    				FlickerStatus = 2;
    				If (bUseBrightness) LightBrightness = SquareOnValue;
    				If (bUseCorona) bCorona = True;
    				DoEvent();
    			}
    		}
    	}

    	function DoRandom()
    	{
    		RandomValue = FRand();
    		If (RandomValue < A) {SLWave = SquareOffValue; bSLWave = False;}
    		If (RandomValue >= A) {SLWave = SquareOnValue; bSLWave = True;}
    		If (bUseBrightness) LightBrightness = SLWave;
    		If (bUseCorona) bCorona = bSLWave;
    	}
    }

    defaultproperties
    {
         bStatic=False
         InitialState=WAVE_Sinus
         Style=STY_Translucent
         bMovable=True
    }

class file time: 12/7/2003 3:58:28 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX