# SpatialFear.SFComParser

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 00473 00474 00475 00476 00477 00478 00479 00480 00481 00482 00483 00484 00485 00486 00487 00488 00489 00490 00491 00492 00493 00494 00495 00496 00497 00498 00499 00500 00501 00502 00503 00504 00505 00506 00507 00508 00509 00510 00511 00512 00513 00514 00515 00516 00517 00518 00519 00520 00521 00522 00523 00524 00525 00526 00527 00528 00529 00530 00531 00532 00533 00534 00535 00536 00537 00538 00539 00540 00541 00542 00543 00544 00545 00546 00547 00548 00549 |
    //=============================================================================
    // Spatial Fear
    // Name: SFComParser
    // Description: Parser subclass for a hud communication.
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFComParser extends SFTextParser;

    var SFCommWindow 	m_wndComWindow;	// Private: Reference to communication window, used to set some values on it.
    var SFCommunication	m_oCurrentComm; // Private: Reference to communication actor
    var float			m_fSavedTickRate;
    var float			m_fAnimationRate;	// Private: Rate of animation playback. Default: 1.0
    var int				m_nBranch1;	// Private: Branch to use for a Yes answered message box. -1 does not change the branch
    var int				m_nBranch2;	// Private: Branch to use for a No answered message box. -1 does not change the branch
    var int				m_nBranch3;	// Private: Branch to use for an InstantShow action.
    var name			m_nameSavedAnim; // Private: Saved animation for paused captain

    // Sets the communication wfindow to drive by this parser
    simulated function setData(SFCommunication oCom, SFCommWindow wndComWindow)
    {
    	m_oCurrentComm	= oCom;
    	m_wndComWindow	= wndComWindow;
    	m_nameSavedAnim	= '';

    	// init the base class with the provided text
    	Super.init(m_oCurrentComm.CommunicationProtocol[0]);
    }

    // Cleanup
    simulated function terminate()
    {
    	// Release references
    	m_oCurrentComm	= None;
    	m_wndComWindow	= None;

    	// Call to base class
    	Super.terminate();

    }

    function stopPlaying()
    {
    	SFNPCDeco(m_oCurrentComm.m_oEventActor).stopPlaying();
    }

    // Checks if the item is already possessed
    function bool alreadyOwned(SFPlayer oPlayer, Class<actor> InventoryItem)
    {
    	local Inventory oItem;

    	oItem = oPlayer.FindInventoryType(InventoryItem);

    	return (None != oItem);
    }

    // Gives the configured item to the player
    function giveToPlayer(SFPlayer oPlayer, String InventoryItem)
    {
    	local Inventory oInv;
    	local SFPickup	oSFPick;
    	local SFHUD		oHUD;
    	local Class<actor>	oClass;

    	// Some inits
    	oHUD	= SFHUD(oPlayer.myHud);
    	oClass	= class<actor>(DynamicLoadObject(InventoryItem, class'Class'));

    	if (!alreadyOwned(oPlayer, oClass))
    	{
    		// Spawn a copy of the new inventory item
    		oInv = Inventory(oPlayer.Spawn(oClass,,,oPlayer.Location));

    		if(oInv.IsA('SFPickup'))
    			SFPickup(oInv).bManualPickup=False;

    		if(None != oInv)
    		{
    			oInv.ReSpawnTime	= 0.0f;
    			oInv.GiveTo(oPlayer);
    			 if(oInv.IsA('SFPickup'))
    			 {
    				oHUD.insertIntoBelt(SFPickup(oInv));
    				if(SFPickup(oInv).bIsPassiveItem)
    					oHUD.passiveItem();
    				if(SFPickup(oInv).bIsActiveItem)
    					oHUD.nextItem();
    			 }
    		}
    	}

    }
    // Called every time to process a new char
    // Overwritten here to use the pause state of the communication actor
    // to simulate a WaitForEvent action
    simulated function bool process()
    {
    	//Check actor
    	if(m_oCurrentComm.m_bPaused)
    	{
    		return false;
    	}
    	else
    	{
    		// Check for paused captain animation
    		if(m_wndComWindow.IsA('SFCapWindow') && (m_nameSavedAnim != ''))
    		{
    			m_wndComWindow.m_actMesh.LoopAnim(m_nameSavedAnim, m_fAnimationRate);
    			m_nameSavedAnim	= '';
    		}

    		if(-1 != m_nBranch3)
    		{
    			executeBranch(string(m_nBranch3));
    			m_nBranch3 = -1;
    		}
    		else
    			// Call to base class
    			return Super.process();
    	}
    }

    simulated function executeGiveToPlayer(String strParameter)
    {
    	local SFPlayer	oPlayer;

    	oPlayer	= SFPlayer(m_oCurrentComm.m_oEventInstigator);
    	giveToPlayer(oPlayer, strParameter);
    }

    // Macro to pause the execution an wait for an event
    // to hit the communication actor
    simulated function executeWaitForEvent(string  strParameter)
    {
    	local int	nEventNumber;
    	local name	nameEvent;

    	nEventNumber	= int(strParameter);
    	// Retrieve event from list
    	nameEvent		= m_oCurrentComm.Events[nEventNumber];

    	// Set the new tag for the communication actor
    	m_oCurrentComm.tag			= nameEvent;
    	// Flag the comm actor
    	m_oCurrentComm.m_bPaused	= true;
    }

    // Macro to branch into a new branch of the communication protocol
    simulated function executeBranch(string strNext)
    {
    	local	int i;

    	i	= int(strNext);

    	// First execute an CLS
    	executeCLS();
    	if(-1 != i)
    		// Once again init the base class with a new text
    		Super.init(m_oCurrentComm.CommunicationProtocol[i]);
    }

    // Macro function to set wait for the passed
    // in amount of seconds
    simulated function executeWait(string strParameter)
    {
    	local float	fWait;
    	local name	nameNewAnim;

    	fWait = Float(strParameter);
    	m_wndComWindow.SetTimer(fWait, false);

    	// Notify com window that the timer has already been set
    	m_wndComWindow.m_bParserAlreadySet	= true;

    	// Pause the captain/trainer animation
    	if(m_wndComWindow.IsA('SFCapWindow'))
    	{
    		// Save current animation
    		m_nameSavedAnim	= m_wndComWindow.m_actMesh.AnimSequence;
    		nameNewAnim		= m_oCurrentComm.Animations[0];
    		m_wndComWindow.m_actMesh.PlayAnim(nameNewAnim, m_fAnimationRate);
    	}
    }

    // Macro function to send an event
    simulated function executeEvent(string  strParameter)
    {
    	local int	nEventNumber;
    	local name	nameEvent;

    	nEventNumber	= int(strParameter);
    	// Retrieve event from list
    	nameEvent		= m_oCurrentComm.Events[nEventNumber];

    	if('' != nameEvent)
    		FireEvent(nameEvent, Self);
    }

    // Macro to change the running text tickrate
    simulated function	executeTickRate(string strParameter)
    {
    	local float	fRate;

    	fRate	= Float(strParameter);
    	if(-1 != fRate)
    	{
    		m_fSavedTickRate			= m_wndComWindow.m_fIntervall;
    		m_wndComWindow.m_fIntervall = fRate;
    	}
    	else
    		m_wndComWindow.m_fIntervall = m_fSavedTickRate;
    }

    // Macro to show the current text branch instantly
    simulated function	executeInstantShow(string strParameter, string strParameter2)
    {
    	local float	fRate;

    	fRate		= Float(strParameter);
    	m_nBranch3	= int(strParameter2);
    	m_wndComWindow.instantShow(fRate);
    }

    // Macro to set the animation rate for following playAnim and loopAnim
    // commands on the mesh actor
    simulated function executeAnimRate(string strParameter)
    {
    	m_fAnimationRate	= float(strParameter);
    }

    // Macro to play a named animation on the displayed
    // actor
    simulated function executePlayAnim(string strParameter)
    {
    	local int	nAnimNumber;
    	local name	nameAnim;

    	if(None == m_wndComWindow.m_actMesh)
    		return;

    	nAnimNumber	= int(strParameter);
    	nameAnim	= m_oCurrentComm.Animations[nAnimNumber];
    	if('' != nameAnim)
    		m_wndComWindow.m_actMesh.PlayAnim(nameAnim, m_fAnimationRate);
    }

    // Macro to play a named animation with a tweentime
    // on the displayed actor
    simulated function executePlayAnim2(string strParameter, string strParameter2)
    {
    	local int	nAnimNumber;
    	local float fTweenTime;
    	local name	nameAnim;

    	if(None == m_wndComWindow.m_actMesh)
    		return;

    	nAnimNumber	= int(strParameter);
    	fTweenTime	= float(strParameter2);
    	nameAnim	= m_oCurrentComm.Animations[nAnimNumber];
    	if('' != nameAnim)
    		m_wndComWindow.m_actMesh.PlayAnim(nameAnim, m_fAnimationRate, fTweenTime);
    }

    // Macro to play a looping named animation on the
    // displayed actor
    simulated function executeLoopAnim(string strParameter)
    {
    	local int	nAnimNumber;
    	local name	nameAnim;

    	if(None == m_wndComWindow.m_actMesh)
    		return;
    	nAnimNumber	= int(strParameter);
    	nameAnim	= m_oCurrentComm.Animations[nAnimNumber];

    	if('' != nameAnim)
    	{
    		m_wndComWindow.m_actMesh.LoopAnim(nameAnim, m_fAnimationRate);
    	}
    }

    // Macro to play a looping named animation on the
    // displayed actor. The tweentime can be specified.
    simulated function executeLoopAnim2(string strParameter, string strParameter2)
    {
    	local int	nAnimNumber;
    	local float fTweenTime;
    	local name	nameAnim;

    	if(None == m_wndComWindow.m_actMesh)
    		return;

    	nAnimNumber	= int(strParameter);
    	fTweenTime	= float(strParameter2);
    	nameAnim	= m_oCurrentComm.Animations[nAnimNumber];

    	if('' != nameAnim)
    	{
    		m_wndComWindow.m_actMesh.LoopAnim(nameAnim, m_fAnimationRate, fTweenTime);
    	}
    }

    // Macro to show an actor tip on the HUD.
    // This is used to point out something to the gamer
    // By displaying a tip above the actor
    simulated function executeShowActorTip(string strParameter1, string strParameter2)
    {
    	local SFPlayer	oPlayer;
    	local SFHUD		oHUD;
    	local int		nNameNumber;
    	local name		nameActor;

    	// Some inits
    	oPlayer	= SFPlayer(m_oCurrentcomm.m_oEventInstigator);
    	if(None == oPlayer)
    		return;
    	oHUD	= SFHUD(oPlayer.myHUD);
    	if(None == oHUD)
    		return;

    	// Set the actor tip
    	oHUD.m_strCommunicationTip	= strParameter2;

    	// Set the name of the object.
    	nNameNumber	= int(strParameter1);
    	nameActor	= m_oCurrentComm.Tipnames[nNameNumber];
    	if('' == nameActor)
    		return;

    	// Set the tip actorname for the HUD
    	oHUD.m_nameTipActor	= nameActor;

    	// Activate the display on the HUD
    	oHUD.m_bShowCommunicationTip	= true;
    }

    // Macro to hide an actor tip on the HUD.
    simulated function executeHideActorTip()
    {
    	local SFPlayer	oPlayer;
    	local SFHUD		oHUD;

    	// Some inits
    	oPlayer	= SFPlayer(m_oCurrentcomm.m_oEventInstigator);
    	if(None == oPlayer)
    		return;
    	oHUD	= SFHUD(oPlayer.myHUD);
    	if(None == oHUD)
    		return;

    	// Hide the actor tip
    	oHUD.m_bShowCommunicationTip	= false;
    }

    // Macro to enable the item and weapon description for the player
    simulated function executeItemDesc()
    {
    	local SFPlayer	oPlayer;

    	// Some inits
    	oPlayer	= SFPlayer(m_oCurrentcomm.m_oEventInstigator);
    	if(None == oPlayer)
    		return;
    	// Enable the HUD upgrade
    	oPlayer.m_bWeaponDescUpgrade	= true;
    }

    // Resumes a paused communication by
    // eventually branching to a new communication
    simulated function resumeComm(bool bYes)
    {
    	// Check for player decision
    	if(bYes)
    		executeBranch(string(m_nBranch1));
    	else
    		executeBranch(string(m_nBranch2));
    }

    // Macro to pause the current communication.
    // It brings up a Yes/No dialog box and continues with  a new branch
    // depending on the user selection
    simulated function executeAskYesNo(string strParameter1, string strParameter2)
    {
    	local SFPlayer	oPlayer;
    	local SFHUD		oHUD;
    	local int		nBranch1, nBranch2;

    	// Some inits
    	oPlayer	= SFPlayer(m_oCurrentcomm.m_oEventInstigator);
    	if(None == oPlayer)
    		return;
    	oHUD	= SFHUD(oPlayer.myHUD);
    	if(None == oHUD)
    		return;

    	// Get the branches
    	m_nBranch1	= int(strParameter1);
    	m_nBranch2	= int(strParameter2);

    	// Bring up the dialog
    	oHUD.PauseComm();
    	oHUD.openWindow(class'SFCommYesNo', 0, 0, 0, 0);

    }

    // Shows the weapon description box on the HUD
    // Used to intorduce the new upgrade
    simulated function executeShowWeaponDesc(string strShow)
    {
    	local SFPlayer	oPlayer;
    	local SFHUD		oHUD;
    	local int	  nShow;

    	// Some inits
    	oPlayer	= SFPlayer(m_oCurrentcomm.m_oEventInstigator);
    	if(None == oPlayer)
    		return;
    	oHUD	= SFHUD(oPlayer.myHUD);
    	if(None == oHUD)
    		return;
    	nShow	= int(strShow);

    	if(0 != nShow)
    	{
    		// Enable the HUD upgrade
    		oPlayer.m_bWeaponDescUpgrade	= true;
    		// Show the window
    		oHUD.showWeaponDesc(TournamentWeapon(oPlayer.Weapon));
    	}
    	else
    		oHUD.hideWeaponDesc();

    }

    // Base class override, to handle additional macros
    simulated function bool executeMacro(string strMacro, string strParameter, string strParameter2)
    {
    	local bool	bRet;
    	// Some inits
    	bRet	= false;

    	// Check for known macros
    	if(strMacro == "wait")
    	{
    		executeWait(strParameter);
    		bRet = true;
    	}
    	else
    	if(strMacro == "event")
    	{
    		executeEvent(strParameter);
    	}
    	else
    	if(strMacro == "tickrate")
    	{
    		executeTickRate(strParameter);
    	}
    	else
    	if(strMacro == "playanim")
    	{
    		executePlayAnim(strParameter);
    	}
    	else
    	if(strMacro == "playtweenanim")
    	{
    		executePlayAnim2(strParameter, strParameter2);
    	}
    	else
    	if(strMacro == "loopanim")
    	{
    		executeLoopAnim(strParameter);
    	}
    	else
    	if(strMacro == "looptweenanim")
    	{
    		executeLoopAnim2(strParameter, strParameter2);
    	}
    	else
    	if(strMacro == "giveToPlayer")
    	{
    		executeGiveToPlayer(strParameter);
    	}
    	else
    	if(strMacro == "showActorTip")
    	{
    		executeShowActorTip(strParameter, strParameter2);
    	}
    	else
    	if(strMacro == "hideActorTip")
    	{
    		executeHideActorTip();
    	}
    	else
    	if(strMacro == "branch")
    	{
    		executeBranch(strParameter);
    	}
    	else
    	if(strMacro == "enableItemDesc")
    	{
    		executeItemDesc();
    	}
    	else
    	if(strMacro == "askYesNo")
    	{
    		executeAskYesNo(strParameter, strParameter2);
    	}
    	else
    	if(strMacro == "showWeaponDesc")
    	{
    		executeShowWeaponDesc(strParameter);
    	}
    	else
    	if(strMacro == "waitForEvent")
    	{
    		executeWaitForEvent(strParameter);
    	}
    	else
    	if(strMacro == "instantShow")
    	{
    		executeInstantShow(strParameter, strParameter2);
    	}
    	else
    	if(strMacro == "animRate")
    	{
    		executeAnimRate(strParameter);
    	}
    	else
    		// Delegate to base
    		return Super.executeMacro(strMacro, strParameter, strParameter2);

    	return bRet;
    }

    defaultproperties
    {
         m_fAnimationRate=0.200000
         m_nBranch3=-1
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX