# SpatialFear.SFDistinctCounter

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 |
    //=============================================================================
    // Spatial Fear
    // Class: SFDistinctCounter
    // Description: Counter subclass that counts only events from distinct
    // triggers. If the counter is configured to reset on success
    // it again accepts events from triggers, that were already seen during the
    // first count sequence.
    // This is achieved by saving a reference to a trigger and only counting
    // it's events once in a count sequence. Event order doesn't matter.
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFDistinctCounter extends Counter;

    const  TRIGGER_COUNT=10;

    var (Counter) bool				ResetOnSucces;	 // Enables/diables counter reset on success
    var (Counter) float 			fFreezeTimeAfterReset; // Counter freeze time after reset. Prevents an immediate counting of the current trigger for the next round. Default: 2.0 secs.
    var Actor	arTriggers[10];	// Private. References to already seen triggers
    var int		nCount; // Private. Number of trigger refs in list.

    var bool	bFreeze; // Private. Freeze state of counter

    // Clears the trigger reference array
    function ClearTriggerList()
    {
    	local int i;

    	// Just clear the reference array
    	for(i=0; i<nCount; i++)
    	{
    		arTriggers[i] = none;
    	}
    	nCount=0;
    }

    // Check, if trigger is already contained in list
    function bool InList(Actor oTrigger)
    {
    	local int i;
    	local bool bFound;

    	// Some inits
    	bFound = false;
    	i=0;

    	while((i<TRIGGER_COUNT) && !bFound)
    	{
    		// Check slot
    		if(arTriggers[i] == oTrigger)
    			bFound = true;

    		// Continue
    		i++;
    	}

    	return bFound;
    }

    // Adds a trigger to the list.
    function bool RememberTrigger(Actor oTrigger)
    {
    	if(nCount < TRIGGER_COUNT)
    	{
    		// Remember ref
    		arTriggers[nCount] = oTrigger;
    		nCount++;
    		return true;
    	}
    	else
    	{
    		class'SFUtils'.Static.sfError("Number of triggers to remember exceeded!!");
    		return false;
    	}

    }

    // Checks, if the trigger was already seen and otherwise counts the event
    function bool CheckTrigger(Actor oTrigger)
    {
    	// Valid parameter?
    	if(None == oTrigger)
    		return false;

    	// Already seen?
    	if(InList(oTrigger))
    		return false;

    	// Not seen already, so remember
    	if(!RememberTrigger(oTrigger))
    		return false;

    	return true;
    }

    // Resets the freeze state
    event timer()
    {
    	class'SFUtils'.Static.sfLogEx(15,"Resetting freeze state");
    	bFreeze = false;
    }

    // Called when triggered.
    function Trigger(actor Other, pawn EventInstigator )
    {
    	local 	Actor	 oTrigger;
    	local	Pawn     oPawn;

    	class'SFUtils'.Static.sfLogEx(15,"TriggerCounterEvent " $ Other.name $ " " $ EventInstigator.name);

    	// Check for freeze state
    	if(bFreeze)
    		return;

    	// First check, if triggered by other trigger
    	if(Other.IsA('Triggers') || Other.IsA('Mover'))
    	{
    		class'SFUtils'.Static.sfLogEx(15,"Triggered by a Trigger or Mover");

    		oTrigger = Other;
    		if(CheckTrigger(oTrigger))
    		{
    			Super.Trigger(Other, EventInstigator);
    			if(0 == NumToCount)
    				Reset();
    		}
    		else
    			return;
    	}
    	else if (Other.IsA('Pawn')) // Check for pawn
    	{
    		class'SFUtils'.Static.sfLogEx(15,"Triggered by a pawn");

    		oPawn = Pawn(Other);

    		// Check all touching actors
    		oTrigger = Trigger(oPawn.Touching[0]);
    		if(CheckTrigger(oTrigger))
    		{
    			class'SFUtils'.Static.sfLogEx(15,"Accepting trigger from [0]: " $ oTrigger.name);
    			Super.Trigger(Other, EventInstigator);
    			if(0 == NumToCount)
    				Reset();
    		}

    		oTrigger = Trigger(oPawn.Touching[1]);
    		if(CheckTrigger(oTrigger))
    		{
    			class'SFUtils'.Static.sfLogEx(15,"Accepting trigger from [1]: " $ oTrigger.name);
    			Super.Trigger(Other, EventInstigator);
    			if(0 == NumToCount)
    				Reset();
    		}

    		oTrigger = Trigger(oPawn.Touching[2]);
    		if(CheckTrigger(oTrigger))
    		{
    			class'SFUtils'.Static.sfLogEx(15,"Accepting trigger from [2]: " $ oTrigger.name);
    			Super.Trigger(Other, EventInstigator);
    			if(0 == NumToCount)
    				Reset();
    		}

    		oTrigger = Trigger(oPawn.Touching[3]);
    		if(CheckTrigger(oTrigger))
    		{
    			class'SFUtils'.Static.sfLogEx(15,"Accepting trigger from [3]: " $ oTrigger.name);
    			Super.Trigger(Other, EventInstigator);
    			if(0 == NumToCount)
    				Reset();
    		}
    	}
    }

    // Resets this counter and all triggers
    function Reset()
    {
    	if(!ResetOnSucces)
    		return;

    	//Freeze counter to prevent new events during reset time
    	bFreeze=true;
    	SetTimer(fFreezeTimeAfterReset, false);
    	class'SFUtils'.Static.sfLogEx(15,"Freezed counter");

    	// Reset local state
    	ClearTriggerList();
    	// Reset the base counter
    	Super.Reset();
    }

    defaultproperties
    {
         fFreezeTimeAfterReset=2.000000
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX