# SFCharacter2.SFMaleOfficer

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 00473 00474 00475 00476 00477 00478 00479 00480 00481 00482 00483 00484 00485 00486 00487 00488 00489 00490 00491 00492 00493 00494 00495 00496 00497 00498 00499 00500 00501 00502 00503 00504 00505 00506 00507 00508 00509 00510 00511 00512 00513 00514 00515 00516 00517 00518 00519 00520 00521 00522 00523 00524 00525 00526 00527 00528 00529 00530 00531 00532 00533 00534 00535 00536 00537 00538 00539 00540 00541 00542 00543 00544 00545 00546 00547 00548 00549 00550 00551 00552 00553 00554 00555 00556 00557 00558 00559 00560 00561 00562 00563 00564 00565 00566 00567 00568 00569 00570 00571 00572 00573 00574 00575 00576 00577 00578 00579 00580 00581 00582 00583 00584 00585 00586 00587 00588 00589 00590 00591 00592 00593 00594 00595 00596 00597 00598 00599 00600 00601 00602 00603 00604 00605 00606 00607 00608 00609 00610 00611 00612 00613 00614 00615 00616 00617 00618 00619 00620 00621 00622 00623 00624 00625 00626 00627 00628 00629 00630 00631 00632 00633 00634 00635 00636 00637 00638 00639 00640 00641 00642 00643 00644 00645 00646 00647 00648 00649 00650 00651 00652 00653 00654 00655 00656 00657 00658 00659 00660 00661 00662 00663 00664 00665 00666 00667 00668 00669 00670 00671 00672 00673 00674 00675 00676 00677 00678 |
    //=============================================================================
    // Spatial Fear
    // Class: SFMaleOfficer
    // Descripton: SpatialFear NPC. No enemy, will fear, when attacked.
    //
    // Author: Markus Nuebel
    //=============================================================================
    class SFMaleOfficer expands SFScriptedPawn;

    #exec MESH IMPORT MESH=SFMaleOfficer ANIVFILE=MODELS\SFMaleOfficer_a.3d DATAFILE=MODELS\SFMaleOfficer_d.3d
    #exec MESH ORIGIN MESH=SFMaleOfficer X=0 Y=0 Z=-39 YAW=64 ROLL=0 PITCH=0

    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=All STARTFRAME=0 NUMFRAMES=362

    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Breath1 STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Breath2 STARTFRAME=220 NUMFRAMES=15 RATE=5 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=CockGun STARTFRAME=275 NUMFRAMES=10 RATE=20 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Breath1L STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Breath2L STARTFRAME=220 NUMFRAMES=15 RATE=5 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=CockGunL STARTFRAME=275 NUMFRAMES=10 RATE=20 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=LookL STARTFRAME=124 NUMFRAMES=30 RATE=15 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Chat1 STARTFRAME=261 NUMFRAMES=14 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Chat2 STARTFRAME=261 NUMFRAMES=14 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Look STARTFRAME=124 NUMFRAMES=30 RATE=15 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Fighter STARTFRAME=25 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=RunLg STARTFRAME=64 NUMFRAMES=20 RATE=30
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=RunLgFr STARTFRAME=84 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=RunSm STARTFRAME=64 NUMFRAMES=20 RATE=30
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=RunSmFr STARTFRAME=84 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=WalkLg STARTFRAME=44 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=WalkLgFr STARTFRAME=104 NUMFRAMES=20 RATE=20 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=WalkSm STARTFRAME=44 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=WalkSmFr STARTFRAME=104 NUMFRAMES=20 RATE=20 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Walk STARTFRAME=44 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=TurnLg STARTFRAME=44 NUMFRAMES=2 RATE=15 //2 frames of walklgfr
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=TurnSm STARTFRAME=44 NUMFRAMES=2 RATE=15 //2 frames of walksmfr
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DuckWlkL STARTFRAME=285 NUMFRAMES=15 RATE=15 Group=Ducking
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DuckWlkS STARTFRAME=285 NUMFRAMES=15 RATE=15 Group=Ducking
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=SwimLg STARTFRAME=1 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=SwimSm STARTFRAME=1 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=TreadLg STARTFRAME=1 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=TreadSm STARTFRAME=1 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=BackRun STARTFRAME=342 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=StrafeL STARTFRAME=321 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=StrafeR STARTFRAME=301 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=StillFrRp STARTFRAME=275 NUMFRAMES=10 RATE=40 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=StillLgFr STARTFRAME=275 NUMFRAMES=10 RATE=20 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=StillSmFr STARTFRAME=275 NUMFRAMES=10 RATE=20 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=AimDnLg STARTFRAME=33 NUMFRAMES=1 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=AimDnSm STARTFRAME=36 NUMFRAMES=1 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=AimUpLg STARTFRAME=34 NUMFRAMES=1 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=AimUpSm STARTFRAME=35 NUMFRAMES=1 Group=Waiting
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DodgeB STARTFRAME=5 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DodgeF STARTFRAME=6 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DodgeR STARTFRAME=7 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DodgeL STARTFRAME=8 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=HeadHit STARTFRAME=37 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=GutHit STARTFRAME=32 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=LeftHit STARTFRAME=38 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=RightHit STARTFRAME=39 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=JumpLgFr STARTFRAME=40 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=JumpSmFr STARTFRAME=41 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=LandLgFr STARTFRAME=43 NUMFRAMES=1 Group=Landing
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=LandSmFr STARTFRAME=42 NUMFRAMES=1 Group=Landing
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Taunt1 STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Gesture
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Wave STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Gesture
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=WaveL STARTFRAME=250 NUMFRAMES=10 RATE=10 Group=Gesture
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Thrust STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Gesture
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Victory1 STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Gesture
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Flip STARTFRAME=16 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead1 STARTFRAME=154 NUMFRAMES=20 RATE=20 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead2 STARTFRAME=175 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead3 STARTFRAME=195 NUMFRAMES=15 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead4 STARTFRAME=235 NUMFRAMES=15 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead5 STARTFRAME=195 NUMFRAMES=15 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead6 STARTFRAME=175 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead7 STARTFRAME=154 NUMFRAMES=20 RATE=20 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead8 STARTFRAME=154 NUMFRAMES=20 RATE=20 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead9 STARTFRAME=195 NUMFRAMES=5 RATE=20 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead9B STARTFRAME=195 NUMFRAMES=25 RATE=20
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Dead11 STARTFRAME=235 NUMFRAMES=15 RATE=20

    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DeathEnd STARTFRAME=174 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DeathEnd2 STARTFRAME=194 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=DeathEnd3 STARTFRAME=219 NUMFRAMES=1

    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Panic STARTFRAME=1 NUMFRAMES=20 RATE=30
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=HandScan STARTFRAME=250 NUMFRAMES=11 RATE=10
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Injured STARTFRAME=220 NUMFRAMES=5 RATE=5
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=InjuredTurn STARTFRAME=220 NUMFRAMES=2 RATE=10
    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=InjuredWalk STARTFRAME=225 NUMFRAMES=10 RATE=10

    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunLG TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunLG TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunLGFR TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunLGFR TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunSM TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunSM TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunSMFR TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=RunSMFR TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=StrafeL TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=StrafeL TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=StrafeR TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=StrafeR TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=BackRun TIME=0.25 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=BackRun TIME=0.75 FUNCTION=PlayFootStep
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead1 TIME=0.7 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead2 TIME=0.9 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead3 TIME=0.45 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead4 TIME=0.6 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead7 TIME=0.7 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead8 TIME=0.7 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead9B TIME=0.8 FUNCTION=LandThump
    #exec MESH NOTIFY MESH=SFMaleOfficer SEQ=Dead11 TIME=0.57 FUNCTION=LandThump

    #exec MESH SEQUENCE MESH=SFMaleOfficer SEQ=Stunned STARTFRAME=21 NUMFRAMES=1

    #exec MESHMAP NEW MESHMAP=SFMaleOfficer MESH=SFMaleOfficer
    #exec MESHMAP SCALE MESHMAP=SFMaleOfficer X=0.045 Y=0.045 Z=0.09

    #exec MESHMAP SETTEXTURE MESHMAP=SFMaleOfficer NUM=1 TEXTURE=Face2

    #exec TEXTURE IMPORT NAME=MaOf1 FILE=Textures\MaleOfficerChest.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaOf1 FILE=Textures\MaleOfficerChest.pcx GROUP=Skins PALETTE=MaOf1
    #exec MESHMAP SETTEXTURE MESHMAP=SFMaleOfficer NUM=2 TEXTURE=MaOf1

    #exec TEXTURE IMPORT NAME=MaOf2 FILE=Textures\MaleOfficerLegs.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaOf2 FILE=Textures\MaleOfficerLegs.pcx GROUP=Skins PALETTE=MaOf2
    #exec MESHMAP SETTEXTURE MESHMAP=SFMaleOfficer NUM=3 TEXTURE=MaOf2

    #exec TEXTURE IMPORT NAME=Mask1 FILE=Textures\Mask.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=Mask1 FILE=Textures\Mask.pcx GROUP=Skins PALETTE=Mask1

    #exec MESHMAP SETTEXTURE MESHMAP=SFMaleOfficer NUM=4 TEXTURE=Mask1

    #exec TEXTURE IMPORT NAME=MaOf1a FILE=Textures\MaleOfficerChestBlue.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaOf1a FILE=Textures\MaleOfficerChestBlue.pcx GROUP=Skins PALETTE=MaOf1a

    #exec TEXTURE IMPORT NAME=MaAr1 FILE=Textures\MaleArmyChest.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaAr1 FILE=Textures\MaleArmyChest.pcx GROUP=Skins PALETTE=MaAr1

    #exec TEXTURE IMPORT NAME=MaAr2 FILE=Textures\MaleArmyLegs.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaAr2 FILE=Textures\MaleArmyLegs.pcx GROUP=Skins PALETTE=MaAr2

    #exec TEXTURE IMPORT NAME=MaBi1 FILE=Textures\MaleBits1.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi1 FILE=Textures\MaleBits1.pcx GROUP=Skins PALETTE=MaBi1

    #exec TEXTURE IMPORT NAME=MaBi2 FILE=Textures\MaleBits2.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi2 FILE=Textures\MaleBits2.pcx GROUP=Skins PALETTE=MaBi2

    #exec TEXTURE IMPORT NAME=MaBi3 FILE=Textures\MaleBits3.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi3 FILE=Textures\MaleBits3.pcx GROUP=Skins PALETTE=MaBi3

    #exec TEXTURE IMPORT NAME=MaBi4 FILE=Textures\MaleBits4.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi4 FILE=Textures\MaleBits4.pcx GROUP=Skins PALETTE=MaBi4

    #exec TEXTURE IMPORT NAME=MaBi5 FILE=Textures\MaleBits5.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi5 FILE=Textures\MaleBits5.pcx GROUP=Skins PALETTE=MaBi5

    #exec TEXTURE IMPORT NAME=MaBi6 FILE=Textures\MaleBits6.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi6 FILE=Textures\MaleBits6.pcx GROUP=Skins PALETTE=MaBi6

    #exec TEXTURE IMPORT NAME=MaBi7 FILE=Textures\MaleBits7.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi7 FILE=Textures\MaleBits7.pcx GROUP=Skins PALETTE=MaBi7

    #exec TEXTURE IMPORT NAME=MaBi8 FILE=Textures\MaleBits8.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=MaBi8 FILE=Textures\MaleBits8.pcx GROUP=Skins PALETTE=MaBi8

    var (SpatialFear) bool bPanicWhenTriggered; // Go to panic state when triggered. Default: false
    var (SpatialFear) sound sndBreath;			// Breath sound
    var (SpatialFear) float fInjuryThreshold;	// Threshold, where the scientist starts to play the injured animations. Default: 0.6
    var (SpatialFear) float fPanicTime; // Panic duration in seconds: Default: 60
    var float	m_fCurrentSpeed; // Private: current walk/run speed

    function PostBeginPlay()
    {
    	// Call to base class
    	Super.PostBeginPlay();

    	m_fCurrentSpeed	= GroundSpeed;
    	SetPhysics(PHYS_Walking);
    }

    function eAttitude AttitudeWithFear()
    {
    	return ATTITUDE_Fear;
    }

    function damageAttitudeTo(pawn Other)
    {
    	local eAttitude OldAttitude;

    	if ( (Other == Self) || (Other == None) || (FlockPawn(Other) != None) )
    		return;
    	if( Other.bIsPlayer ) //change attitude to player
    		AttitudeToPlayer = ATTITUDE_Fear;
    	else if ( ScriptedPawn(Other) == None )
    		Hated = Other;
    	SetEnemy(Other);
    }

    function eAttitude AttitudeToCreature(Pawn Other)
    {
    	if ( Other.IsA('SFMaleOfficer') )
    		return ATTITUDE_Friendly;
    	else if ( Other.IsA('ScriptedPawn'))
    		return ATTITUDE_Fear;
    	else
    		return ATTITUDE_Ignore;
    }

    function Trigger( actor Other, pawn EventInstigator )
    {
    	local Pawn currentEnemy;

    	if ( (Other == Self) || (Health <= 0) )
    		return;
    	if ( bPanicWhenTriggered )
    	{
    		GotoState('Panic');
    	}
    	else
    		Super.Trigger(Other, EventInstigator);
    }

    function TweenToStunned(float tweentime)
    {
    	TweenAnim('Stunned', tweentime);
    }

    function PlayStunned()
    {
    	PlayAnim('Stunned');
    }

    function TweenToWaiting(float tweentime)
    {
    	TweenAnim('Look', tweentime);
    }

    function PlayWaiting()
    {
    	local float decision;
    	local float animspeed;

    	animspeed = 0.4 + 0.6 * FRand();
    	decision = FRand();

    	if ( !bool(NextAnim) || (decision < 0.95) ) //pick first waiting animation
    	{
    		if ( !bQuiet )
    			PlaySound(sndBreath, SLOT_Talk, 0.7,,800);
    		NextAnim = 'Breath1';
    	}
    	else
    		NextAnim = 'Look';

    	LoopAnim(NextAnim, animspeed, 0.4, 0.4);

    }

    function PlayChallenge()
    {
    	if ( FRand() < 0.3 )
    		PlayWaiting();
    	else
    		PlayAnim('Taunt1');
    }

    function TweenToFighter(float tweentime)
    {
    	TweenAnim('Fighter', tweentime);
    }

    function PlayBigDeath(name DamageType)
    {
    	PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    	PlayAnim('Dead2',0.7, 0.1);
    }

    function PlayHeadDeath(name DamageType)
    {
    	local carcass carc;

    	carc = Spawn(class 'CreatureChunks',,, Location + CollisionHeight * vect(0,0,0.8), Rotation + rot(3000,0,16384) );
    	if (carc != None)
    	{
    		carc.Mesh = mesh'NaliHead';
    		carc.Initfor(self);
    		carc.Velocity = Velocity + VSize(Velocity) * VRand();
    		carc.Velocity.Z = FMax(carc.Velocity.Z, Velocity.Z);
    	}
    	PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    	PlayAnim('Dead2',0.5, 0.1);
    }

    function PlayLeftDeath(name DamageType)
    {
    	PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    	PlayAnim('Dead4',0.7, 0.1);
    }

    function PlayRightDeath(name DamageType)
    {
    	PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    	PlayAnim('Dead3',0.7, 0.1);
    }

    function PlayGutDeath(name DamageType)
    {
    	PlaySound(Die, SLOT_Talk, 4 * TransientSoundVolume);
    	if ( FRand() < 0.5 )
    		PlayAnim('Dead1',0.7, 0.1);
    	else
    		PlayAnim('Dead9b',0.7, 0.1);
    }

    function TweenToPanic(float tweentime)
    {
    	if (AnimSequence != 'Panic' || !bAnimLoop)
    		TweenAnim(RunAnim, tweentime);
    }

    function PlayPanic()
    {
    	LoopAnim('Panic', -1.5/GroundSpeed,,0.4);
    }

    function PlayWalking()
    {
    	if(getHurtRate() > fInjuryThreshold)
    		LoopAnim('InjuredWalk', -10.5/GroundSpeed,,0.4);
    	else
    		LoopAnim(WalkAnim, -0.9/GroundSpeed,,0.4);
    	PlayFootStep();
    }

    function PlayVictoryDance()
    {
    	PlaySound(Sound'UnrealShare.Nali.sweat1n', SLOT_Talk);
    	PlayAnim('WaveL', 1.0, 0.1);
    }

    function PlayMeleeAttack()
    {
    	PlayThreatening();
    }

    function PlayRangedAttack()
    {
    	PlayThreatening();
    }

    function PlayFootStep()
    {
    	PlaySound(sound'UnrealShare.Nali.WalkC', SLOT_Interact);
    }

    function PlayRunning()
    {
    	LoopAnim(RunAnim, -1.5/GroundSpeed,,0.4);
    }

    // Mostly copy of Retreating
    state Panic expands Retreating
    {
    	ignores  HearNoise, EnemyNotVisible, SeePlayer;
    	// No tactical moves here
    	function PickDestination()
    	{
    		if (HomeBase(Home) == None)
    			Home = FindRandomDest(); //find temporary home
    	}
    	function ChangeDestination()
    	{
    		local actor oldTarget;
    		local Actor path;

    		oldTarget = Home;
    		PickDestination();
    		if ( (Home == oldTarget) || (Home == None) )
    			MoveTarget = None;
    		else
    		{
    			path = FindPathToward(Home);
    			if (path == None)
    				MoveTarget = None;
    			else
    			{
    				MoveTarget = path;
    				Destination = path.Location;
    			}
    		}
    	}

    	function AnimEnd()
    	{
    		PlayPanic();
    	}

    	function Timer()
    	{
    		if(FRand() < 0.8)
    			GotoState('Wandering');
    		else
    			GotoState('Waiting');
    	}

    	function EndState()
    	{
    		SetTimer(0, false);
    		Super.EndState();
    	}

    	function BeginState()
    	{
    		SetTimer(fPanicTime, false);
    		Super.BeginState();
    	}

    Begin:
    	if (Physics == PHYS_None)
    		SetPhysics(PHYS_Walking);
    	TweenToPanic(0.1);
    	WaitForLanding();
    	PickDestination();

    Landed:
    	TweenToPanic(0.1);
    RunAway:
    	PickNextSpot();
    Moving:
    	if ( MoveTarget == None )
    	{
    		Sleep(0.0);
    		Goto('RunAway');
    	}
    	if ( !bCanStrafe || !LineOfSightTo(Enemy) || !bCanSee ||
    		(Skill - 2 * FRand() + (Normal(Enemy.Location - Location - vect(0,0,1) * (Enemy.Location.Z - Location.Z))
    			Dot Normal(MoveTarget.Location - Location - vect(0,0,1) * (MoveTarget.Location.Z - Location.Z))) < 0) )
    	{
    		bCanFire = false;
    		MoveToward(MoveTarget);
    	}
    	else
    	{
    		bCanFire = true;
    		StrafeFacing(MoveTarget.Location, Enemy);
    	}
    	Goto('RunAway');

    TakeHit:
    	TweenToPanic(0.1);
    	Goto('Moving');

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	MoveTo(Destination);
    	Goto('Moving');

    TurnAtHome:
    	Acceleration = vect(0,0,0);
    	TurnTo(Homebase(Home).lookdir);
    	GotoState('Ambushing', 'FindAmbushSpot');

    }

    state Retreating
    {
    ignores  HearNoise;

    	function EnemyNotVisible()
    	{
    		Disable('EnemyNotVisible');
    		Enable('SeePlayer');
    	}

    	function SeePlayer(actor SeenPlayer)
    	{
    		MakeNoise(1.0);
    		Enable('EnemyNotVisible');
    		Disable('SeePlayer');
    	}

    	// No tactical moves here
    	function PickDestination()
    	{
    		//log("find retreat destination");
    		if (HomeBase(Home) == None)
    			Home = FindRandomDest(); //find temporary home
    	}
    	function ChangeDestination()
    	{
    		local actor oldTarget;
    		local Actor path;

    		oldTarget = Home;
    		PickDestination();
    		if ( (Home == oldTarget) || (Home == None) )
    			MoveTarget = None;
    		else
    		{
    			path = FindPathToward(Home);
    			if (path == None)
    				MoveTarget = None;
    			else
    			{
    				MoveTarget = path;
    				Destination = path.Location;
    			}
    		}
    	}

    	function AnimEnd()
    	{
    		if ( bSpecialPausing )
    			PlayPatrolStop();
    		else if ( bCanFire && LineOfSightTo(Enemy) )
    			PlayCombatMove();
    		else
    		{
    			if(getHurtRate() < fInjuryThreshold)
    				PlayRunning();
    			else
    				PlayWalking();
    		}
    	}

    Begin:
    	if(getHurtRate() < fInjuryThreshold)
    		TweenToRunning(0.1);
    	else
    	{
    		TweenToWalking(0.1);
    		PlayWalking();
    		m_fCurrentSpeed=WalkingSpeed;
    	}

    	WaitForLanding();
    	PickDestination();

    Landed:
    	if(getHurtRate() < fInjuryThreshold)
    		TweenToRunning(0.1);
    	else
    	{
    		TweenToWalking(0.1);
    		FinishAnim();
    		PlayWalking();
    		m_fCurrentSpeed=WalkingSpeed;
    	}

    RunAway:
    	PickNextSpot();
    SpecialNavig:
    	if (SpecialPause > 0.0)
    	{
    		if ( LineOfSightTo(Enemy) && bCanSee )
    		{
    			bFiringPaused = true;
    			NextState = 'Retreating';
    			NextLabel = 'Moving';
    			GotoState('RangedAttack');
    		}
    		bSpecialPausing = true;
    		Acceleration = vect(0,0,0);
    		TweenToPatrolStop(0.25);
    		Sleep(SpecialPause);
    		SpecialPause = 0.0;
    		bSpecialPausing = false;
    		if(getHurtRate() < fInjuryThreshold)
    			TweenToRunning(0.1);
    		else
    		{
    			TweenToWalking(0.1);
    			FinishAnim();
    			PlayWalking();
    			m_fCurrentSpeed=WalkingSpeed;
    		}
    	}
    Moving:
    	if ( MoveTarget == None )
    	{
    		Sleep(0.0);
    		Goto('RunAway');
    	}
    	if ( !bCanStrafe || !LineOfSightTo(Enemy) || !bCanSee ||
    		(Skill - 2 * FRand() + (Normal(Enemy.Location - Location - vect(0,0,1) * (Enemy.Location.Z - Location.Z))
    			Dot Normal(MoveTarget.Location - Location - vect(0,0,1) * (MoveTarget.Location.Z - Location.Z))) < 0) )
    	{
    		bCanFire = false;
    		MoveToward(MoveTarget, m_fCurrentSpeed);
    	}
    	else
    	{
    		bCanFire = true;
    		StrafeFacing(MoveTarget.Location, Enemy);
    	}
    	Goto('RunAway');

    TakeHit:
    	if(getHurtRate() < fInjuryThreshold)
    		TweenToRunning(0.1);
    	else
    	{
    		TweenToWalking(0.1);
    		PlayWalking();
    		m_fCurrentSpeed=WalkingSpeed;
    	}
    	Goto('Moving');

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	MoveTo(Destination, m_fCurrentSpeed);
    	Goto('Moving');

    TurnAtHome:
    	Acceleration = vect(0,0,0);
    	TurnTo(Homebase(Home).lookdir);
    	GotoState('Ambushing', 'FindAmbushSpot');

    }

    defaultproperties
    {
         sndBreath=Sound'UnrealShare.Nali.breath1n'
         fInjuryThreshold=0.600000
         fPanicTime=60.000000
         m_fCurrentSpeed=1.000000
         WalkAnim=Walk
         RunAnim=RunSmFr
         ThreatenAnim=Taunt1
         TakeHitAnim=GutHit
         VictoryAnim=WaveL
         bCanSee=False
         bCanSmell=False
         fHealingTimer=-1.000000
         CarcassType=Class'Botpack.TMale1Carcass'
         TimeBetweenAttacks=0.500000
         Aggressiveness=-10.000000
         WalkingSpeed=0.100000
         Acquire=Sound'UnrealShare.Nali.contct1n'
         Fear=Sound'UnrealShare.Nali.fear1n'
         Roam=Sound'UnrealShare.Nali.breath1n'
         Threaten=Sound'UnrealShare.Nali.contct3n'
         MeleeRange=40.000000
         GroundSpeed=220.000000
         WaterSpeed=60.000000
         AccelRate=900.000000
         JumpZ=140.000000
         Visibility=100
         SightRadius=800.000000
         Health=40
         AttitudeToPlayer=ATTITUDE_Friendly
         Intelligence=BRAINS_HUMAN
         HitSound1=Sound'UnrealShare.Nali.injur1n'
         HitSound2=Sound'UnrealShare.Nali.injur2n'
         Die=Sound'UnrealShare.Nali.death1n'
         DrawType=DT_Mesh
         Mesh=LodMesh'SFCharacter2.SFMaleOfficer'
         CollisionRadius=20.000000
         CollisionHeight=40.000000
         Mass=80.000000
         Buoyancy=95.000000
         RotationRate=(Pitch=2048,Yaw=40000,Roll=0)
    }

class file time: 12/7/2003 3:58:26 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX