# SpatialFear.SFBubbleGenerator

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 |
    //=============================================================================
    // Spatial Fear
    // Class: SFBubbleGenerator
    // Description:
    //	The generator has four modes:
    //	MODE_Manual: Same as the original Bubble generator, spawns up to NumBubblesManual bubbles for
    //	every touch event and then disables timer (used to generate new bubbles),
    //	Timer is set off buy trigger and touch, deactivated on UnTouch. So constant touching will
    //	produce bubbles constantly
    //	MODE_Random: Permanently generated bubbles at random intervals, each time the timer fires
    //	NumBubblesNew are spawned. Cannot be deactivated.
    //	MODE_Event: Only generates a single bubble when triggered. Each time the trigger fires
    //	one bubble is spawned.
    //	MODE_Touch: Only generated bubbles when touched, each time the trigger fires
    //	NumBubblesNew are spawned.
    //	MODE_All: Combines MODE_Random, MODE_Event, MODE_Touch: bubbles are spawned, randomly, on touch and
    //	on a trigger event.
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFBubbleGenerator extends BubbleGenerator ;

    enum EMode
    {
    	MODE_Manual,
    	MODE_Random,
    	MODE_Event,
    	MODE_Touch,
    	MODE_All,
    };

    var (SpatialFear) float BubbleScale; // Scale of generated bubbles, defaults to 1.0
    var (SpatialFear) float BubbleMass; // Mass of spawned bubble, defaults to 3.0, lower values will result in faster bubbles
    var (SpatialFear) EMode Mode; //One of the five modes: 	MODE_Manual, MODE_Random, MODE_Event, MODE_Touch, MODE_All,	defaults to MODE_Manual.
    var (SpatialFear) float NumBubblesManual; // Number of bubbles to generate for Manual mode (=original mode).
    var (SpatialFear) float NumBubblesNewModes; // Number of bubbles to generate for new modes.
    var (SpatialFear) float RandIntervall; // Specifies the range that is used to pick a random number for the sleep time before the next bubble is spawned. There is a fixed offset of two seconds. E.g. setting this value to 4.0 results in a random sleep time between 2 and 6 seconds. Defaults to 2.0
    var int i; // Private. Bubble counting variable for MODE_Manual.

    state Active
    {
    }

    state Manual
    {

    	function Timer()
    	{
    		local vector X,Y,Z;
    		local Bubble bubble;

    		i++;
    		if (i>NumBubblesManual)
    			UnTouch(None);

    		// Spawn new bubble
    	    bubble = Spawn(class'Bubble');
    	    // Change size and mass
    	    bubble.DrawScale	= BubbleScale;
    		bubble.Mass			= BubbleMass;

    		SetTimer(FRand()*2.0+2.0,False);
    	}

    	function Trigger( actor Other, pawn EventInstigator )
    	{
    		SetTimer(0.3,False);
    		i=0;
    	}

    	function Touch( actor Other)
    	{
    		SetTimer(0.3,False);
    		i=0;
    	}

    	function UnTouch( actor Other)
    	{
    		SetTimer(0.0, False);
    	}

    Begin:
    	//class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::State Manual entered");
    	bHidden = True;
    }

    state Random
    {

    	function Timer()
    	{
    		local vector X,Y,Z;
    		local Bubble bubble;
    		local int j;

    		for(j=0; j<NumBubblesNewModes; j++)
    		{
    			// Spawn new bubble
    	    	bubble = Spawn(class'Bubble');
    	    	// Change size and mass
    	    	bubble.DrawScale = BubbleScale;
    			bubble.Mass		 = BubbleMass;
    		}

    		SetTimer(FRand()*2.0+2.0,False);
    	}

    Begin:
    	// class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::State Random entered");
    	bHidden = True;
    	SetTimer(FRand()*2.0+2.0,False);
    }

    state EventMode
    {

    	function Trigger( actor Other, pawn EventInstigator )
    	{
    		local vector X,Y,Z;
    		local Bubble bubble;

      		// Spawn new bubble
    	    bubble = Spawn(class'Bubble');
    	    // Change size and mass
    	    bubble.DrawScale	= BubbleScale;
    		bubble.Mass			= BubbleMass;
    	}

    Begin:
    	//class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::State EventMode entered");
    	bHidden = True;
    }

    state TouchMode
    {

    	function Touch( actor Other)
    	{
    		local vector X,Y,Z;
    		local Bubble bubble;
    		local int j;

    		for(j=0; j<NumBubblesNewModes; j++)
    		{

      		    // Spawn new bubble
    	    	bubble = Spawn(class'Bubble');
    			// Change size and mass
    			bubble.DrawScale	= BubbleScale;
    			bubble.Mass			= BubbleMass;
    		}

    	}

    Begin:
    	//class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::State TouchMode entered");
    	bHidden = True;
    }

    state All
    {

    	function SpawnBubble()
    	{
    		local vector X,Y,Z;
    		local Bubble bubble;
    		local int j;

    		for(j=0; j<NumBubblesNewModes; j++)
    		{
    			// Spawn new bubble
    	    	bubble = Spawn(class'Bubble');
    			// Change size and mass
    			bubble.DrawScale	= BubbleScale;
    			bubble.Mass			= BubbleMass;
    		}
    	}

    	function Timer()
    	{
    		SpawnBubble();

    		SetTimer(FRand()*RandIntervall+2.0,False);
    	}

    	function Trigger( actor Other, pawn EventInstigator )
    	{
    		SpawnBubble();
    	}

    	function Touch( actor Other)
    	{
    		SpawnBubble();
    	}

    Begin:
    	//class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::State All entered");
    	bHidden = true;
    	SetTimer(FRand()*RandIntervall+2.0,False);
    }

    auto state Startup
    {
    Begin:
    	//class'SFUtils'.Static.sfLogEx(15, "SFBubbleGenerator::Startup");
    	// Decide which state to choose
    	switch(Mode)
    	{
    	case MODE_Random:
    		GotoState('Random');
    		break;
    	case MODE_Event:
    		GotoState('EventMode');
    		break;
    	case MODE_Touch:
    		GotoState('TouchMode');
    		break;
    	case MODE_All:
    		GotoState('All');
    		break;
    	default:
    		GotoState('Manual');
    	}
    }

    defaultproperties
    {
         BubbleScale=1.000000
         BubbleMass=3.000000
         NumBubblesManual=15.000000
         NumBubblesNewModes=1.000000
         RandIntervall=2.000000
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX