# SpatialFear.SFGameInfoDreamLand

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 |
    //=============================================================================
    // Spatial Fear
    // Class: SFGameInfoDreamLand
    // Description: Changes game behaviour of Spatial Fear MOD
    // Custom game type to hide the HUD, etc. for dream- and cut- scenes.
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFGameInfoDreamLand expands  SFGameInfo config;

    var PlayerPawn Player;

    event playerpawn Login
    (
         string Portal,
         string Options,
         out string Error,
         class<playerpawn> SpawnClass
    )
    {
    	// Call to base class
    	Player = Super.Login(Portal, Options, Error, SpawnClass);

    	return Player;
    }

    event PostLogin(PlayerPawn playerpawn)
    {
    	local SFPlayer	player;

    	// Call to base class
    	Super.PostLogin(playerpawn);

    	// Very silent in dreamland
    	SFPlayer(playerpawn).m_fFootstepVolume	= 0.45;
    	// Cannot drown in dreamland
    	SFPlayer(playerpawn).m_bCannotDrown		=  true;
    }

    function AddDefaultInventory( pawn PlayerPawn )
    {
    	local SFPlayer	player;

    	// Call to base class
    	Super.AddDefaultInventory(PlayerPawn);

    	if(!PlayerPawn.IsA('SFPlayer'))
    		return;

    	player = SFPlayer(PlayerPawn);

    	if(None != player.weapon)
    	{
    		// Remove the weapon
    		player.weapon=None;
    		// Set dream mode to prevent footsteps, etc.
    		player.m_bDreamMode=true;
    	}

    	Level.bAllowFOV				=true;
    	player.FOVAngle				= 120;
    	player.DesiredFOV			= 120;
    }

    //
    // Called when pawn has a chance to pick Item up (i.e. when
    // the pawn touches a weapon pickup). Should return true if
    // he wants to pick it up, false if he does not want it.
    //
    function bool PickupQuery( Pawn Other, Inventory item )
    {
    	// Does nothing to prevent the player from picking something up.
    	return false;
    }

    // No damage in dreamland
    function int ReduceDamage( int Damage, name DamageType, pawn injured, pawn instigatedBy )
    {
    	return 0;
    }

    function StartPlayer(PlayerPawn Other)
    {
    	local Inventory	oInv;

    	// Call to base class
    	Super.StartPlayer(Other);

    	if(None != Other.Inventory)
    	{
    		oInv	= Other.Inventory;
    		while(None != oInv)
    		{
    log(oInv);
    			if(oInv.IsA('SFFlashlight'))
    			{
    				oInv.Activate();
    				return;
    			}
    			oInv = oInv.Inventory;
    		}
    	}

    }

    defaultproperties
    {
         HUDType=Class'SpatialFear.SFNullHUD'
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX