# SpatialFear.SFSelectWeaponBelt

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 |
    //=============================================================================
    // Spatial Fear
    // Name: SFSelectWeaponBelt
    // Description: Collection of item slot windows, that possible weapons for a
    //				weapon upgrade
    //
    // Author: Markus Nuebel
    //=============================================================================

    ///////////////////////
    class SFSelectWeaponBelt extends SFWindow;

    var int		m_nNumberOfIcons; // Number of icons that the belt can show, depending on it's size.
    var int		m_nNumberOfItems; // Number of items in the belt. Can be more than the belt can show. You need to scroll.
    var int		m_nSelected; // Index of the currently selected slot
    var int		m_nSelectionSlot; // Index that shows up the selected item. Normally this is the mid slot of the belt, but you can place it everywhere.
    var float	m_fSelectionSlotOffset; // Offset in X dimension of selection slot;
    var int		m_nIconSize; // Dimension of Icon (texture)
    var int		m_nIconDisplaySize; // Dimension of Icon (display)
    var int		m_nIconBorder; // Border size between icons. Size for one side ONLY!
    var float	m_fCountdown; // Number of seconds before automatically closing the belt window. Default: 5 secs.

    var SFItemSlot	m_arSlots[9]; // Array of slot icons
    var SFPickup	m_oWeaponUpgrade;	// The upgrade, that has opened the window
    var bool		m_bLaserSightUpgrade; // Is this the laser sight or the energy booster upgrade.

    // All initialization stuff
    simulated function init(float fHUDScale, int X, int Y, int nWidth, int nHeight, optional Pawn Owner, optional string strText, optional SFWindow wndParent)
    {
    	// Call to base class
    	Super.init(fHUDScale, X, Y, nWidth, nHeight, Owner, strText, wndParent);

    	// Special belt inits
    	m_nNumberOfIcons		= m_nWidth/(m_nIconDisplaySize+m_nIconBorder);
    	m_nSelectionSlot		= (m_nNumberOfIcons-1)/2;
    	m_nSelected				= -1;
    	m_nNumberOfItems		= 0;
    	//class'SFUtils'.static.sfLogEx(15, "SFSelectWeaponBelt - init: NumberOfIcons " $ m_nNumberOfIcons $ " SelectionSlot: " $ m_nSelectionSlot $ " X: " $ m_XCur $ " Y: " $ m_YCur $ " Width " $ m_nWidth $ " Height: " $ m_nHeight   );

    }

    // Populates the belt by cheching the inventory for applicable weapons
    simulated function queryInventory()
    {
    	local SFPlayer	oPlayer;
    	local Inventory oInv;
    	local bool		bFound;

    	// Some inits
    	oPlayer	= SFPlayer(m_oWeaponUpgrade.Owner);
    	if(None == oPlayer)
    		return;

    	bFound=false;
    	// Clear the thing up
    	reset();

    	// Check the players inventory
    	for ( oInv=oPlayer.Inventory; oInv!=None; oInv=oInv.Inventory )
    	{
    		if(oInv.IsA('SFWeapon'))
    		{
    			if(m_bLaserSightUpgrade)
    			{
    				if(SFWeapon(oInv).bCanUpgradeLaserSight)
    				{
    					bFound=true;
    					insert(SFWeapon(oInv));
    				}
    			}
    			else
    			{
    				if(SFWeapon(oInv).bCanUpgradeEnergyBooster)
    				{
    					bFound=true;
    					insert(SFWeapon(oInv));
    				}
    			}
    		}
    	}

    	if(!bFound)
    		hide();
    }

    // Overwrite of show, to set the inventory open flag for the player pawn
    simulated function show()
    {
    	// Get the qualified weapons
    	queryInventory();

    	// Call to base class
    	Super.show();

    	SFPlayer(m_oPawnOwner).m_bWeaponSelectOpen=true;

    	// Make the selection blinking
    	if(-1 != m_nSelected)
    		m_arSlots[m_nSelected].select();
    }

    // Cleanup
    simulated function terminate()
    {
    	local int i;

    	// Call to base class
    	Super.terminate();

    	// Cleanup slot array
    	for(i=0; i<m_nNumberOfItems; i++)
    		m_arSlots[i] = None;

    }

    // Resets the belt, called before new population
    simulated function reset()
    {
    	local int i;

    	// Free references
    	// Cleanup slot array
    	for(i=0; i<m_nNumberOfItems; i++)
    		m_arSlots[i] = None;

    	// Rest counters
    	m_nSelected				= -1;
    	m_nNumberOfItems		= 0;
    }

    // Selects the next item
    simulated function nextItem()
    {
    	// if not visible activate on first keypress
    	if(!isVisible())
    	{
    		show();
    		return;		// Do not modify current selection on first keypress
    	}

    	if(m_nSelected<m_nNumberOfItems-1)
    	{
    		m_arSlots[m_nSelected].deselect();
    		m_nSelected++;
    		m_arSlots[m_nSelected].select();
    	}

    	//class'SFUtils'.static.sfLogEx(15, "SFSelectWeaponBelt - nextItem: Selecting " $ m_nSelected);
    }

    // Selects the previous item
    simulated function prevItem()
    {
    	// if not visible activate on first keypress
    	if(!isVisible())
    	{
    		show();
    		return;		// Do not modify current selection on first keypress
    	}

    	if(m_nSelected>0)
    	{
    		m_arSlots[m_nSelected].deselect();
    		m_nSelected--;
    		m_arSlots[m_nSelected].select();
    	}

    	//class'SFUtils'.static.sfLogEx(15, "SFSelectWeaponBelt - prevItem: Selecting " $ m_nSelected);
    }

    // Upgrades the currently selected weapon and
    // disposes the window
    simulated function upgradeWeapon()
    {
    	// Check for valid selection
    	if(-1 != m_nSelected)
    	{
    		// Upgrade the weapon
    		if(m_bLaserSightUpgrade)
    			m_arSlots[m_nSelected].m_weapon.upgradeLaserSight();
    		else
    			m_arSlots[m_nSelected].m_weapon.upgradeEnergyBooster(m_oWeaponUpgrade.fUpgradeAmount);
    	}

    	// Reset player pawn flag
    	SFPlayer(m_oPawnOwner).m_bWeaponSelectOpen=false;
    	hide();
    }

    // Removes an item from the belt
    simulated function bool removeItem(SFPickup item)
    {
    	local int i, nSlot;

    	// Some inits
    	nSlot = -1;

    	// First find the item
    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Check matching and early out
    		if(m_arSlots[i].m_item.class == item.class)
    		{
    			nSlot = i;
    			//class'SFUtils'.static.sfLogEx(5, "SFSelectWeaponBelt - removeItem: Item" $ item.class $ " found in belt." );
    		}
    	}

    	if(-1 == nSlot)
    		return true;

    	// Kick it out
    	m_arSlots[nSlot] = None;

    	// Rebuild belt
    	for(i=nSlot; i<m_nNumberOfItems-1; i++)
    		m_arSlots[i] = m_arSlots[i+1];

    	// Clear the last (now free) entry
    	m_arSlots[m_nNumberOfItems-1] = None;

    	// Decrease belt size
    	m_nNumberOfItems--;

    	// Reset the current selection
    	if(m_nSelected >0)
    		m_nSelected--;

    	return true;

    }

    // Checks, if the weapon is already possesed
    simulated function bool findWeapon(SFWeapon oWeapon)
    {
    	local int i;

    	// FIXME: just for testing, everything is accepted
    	return false;

    	return findActor(oWeapon);
    }

    // Checks, if the item is already possesed
    simulated function bool findItem(SFPickup item)
    {
    	local int i;

    	// FIXME: just for testing, everything is accepted
    	return false;

    	return findActor(item);
    }

    // Checks, if the actor is already possesed
    simulated function bool findActor(Actor oActor)
    {
    	local int i;

    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Check matching and early out
    		if(m_arSlots[i].m_item.class == oActor.class)
    		{
    			return true;
    		}
    	}

    	// Not Found
    	return false;
    }

    // Inserts a new item into the belt
    simulated function bool insert(SFWeapon oWeapon)
    {
    	// Check for maximum belt capacity
    	if(m_nNumberOfItems >= 9)
    		return false;

    	// Check, if already equipped
    	if(findWeapon(oWeapon))
    		return false;

    	// Insert item
    	m_arSlots[m_nNumberOfItems] = m_oPawnOwner.Spawn(class'SFItemSlot');
    	m_arSlots[m_nNumberOfItems].insertWeapon(m_nNumberOfIcons, oWeapon);
    	m_arSlots[m_nNumberOfItems].init(m_fHUDScale, m_XCur, m_YCur, m_nIconSize, m_nIconSize, m_oPawnOwner);
    	m_arSlots[m_nNumberOfItems].setParent(Self);

    	// If window is currently visible, show the item icon
    	if(isVisible())
    		m_arSlots[m_nNumberOfItems].show();

    	// First item will automatically be selected
    	if(0 == m_nNumberOfItems)
    	{
    		m_arSlots[m_nNumberOfItems].select();
    		m_nSelected = 0;
    	}

    	// Increment item count
    	m_nNumberOfItems++;

    	return true;
    }

    // Recalculates the icons positions based on the currently selected item
    simulated function recalcPositions()
    {
    	local int	i, x, y;
    	local int	nOffset;
    	local float	fIconOffset;

    	m_fSelectionSlotOffset	= m_nSelectionSlot*(m_nIconDisplaySize+m_nIconBorder);

    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Offset to selection slot
    		nOffset	= i - m_nSelected;
    		if(nOffset < -m_nSelectionSlot)
    		{
    			m_arSlots[i].hide();
    		}
    		else if(nOffset > m_nSelectionSlot)
    		{
    			m_arSlots[i].hide();
    		}
    		else
    		{
    			// Otherwise calculat the new position
    			x			= m_XCur + nOffset*(m_nIconDisplaySize+m_nIconBorder)+ m_fSelectionSlotOffset;
    			y			= m_YCur;
    			m_arSlots[i].setPos(x, y);
    			if(!m_arSlots[i].isVisible())
    				m_arSlots[i].show();
    		}
    	}
    }

    // Overwritten here to display the single item slots
    simulated function renderBackground(Canvas C)
    {
    	local int	i;

    	// Call to base class
    	Super.renderBackground(C);

    	// Recalculate the icon positions
    	recalcPositions();

    	// render icons
    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		if(None != m_arSlots[i])
    			m_arSlots[i].render(C, m_fHUDScale);
    	}

    }

    // Owerwritten here to prepare the canvas
    simulated function prepareCanvas(Canvas C)
    {
    	// Call to base class
    	Super.prepareCanvas(C);
    }

    defaultproperties
    {
         m_nIconSize=64
         m_nIconDisplaySize=32
         m_nIconBorder=4
         m_bLaserSightUpgrade=True
         m_texBkg=Texture'SfResource1.Background.ActiveBelt'
         m_nBorderSize=8
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX