# SFVehicle.SFVehicleLadder

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 |
    //=============================================================================
    // Spatial Fear
    // Name: SFVehicleLadder
    // Description: Special ladder type object that can be moved and rotated with a SFVehicle (i.e. - planes)
    //
    // Author: Gert Jen Peltenburg
    //=============================================================================
    class SFVehicleLadder expands Pickup;
    var SFVehicleLadder Original;               // set in SpawnCopy
    var bool go;
    var float aircontrol;
    var float ownerspeed;
    var bool ownerwantstomove;

    final function int sign(float value)
    {
     if(value==0)
      return 0;
     if(value<0)
      return -1;
     return 1;
    }

    // atan2 determines 360 degree angle (between -pi and Pi, more precisely)
    final function float atan2(float Y,float X)
    {
     local float tempang;

     if(X==0) {
      if(Y<0)
       tempang=-pi/2;
      else if(Y>0)
       tempang=pi/2;
      else
       tempang=0;
     }
     else if(X<0) {
      tempang=atan(Y/X)+pi; // Third quadrant
     }
     else
      tempang=atan(Y/X);        //

     if(tempang>pi)
      tempang-=pi*2;

     if(tempang<-pi)
      tempang+=pi*2;

     return tempang;
    }

    // Possibly useful functions below

    // RealWorldLocation determines the position of a point after its origin is rotated.
    // this is needed to properly rotate and move a child when its starting rotation is different
    // from that of the parent
    // (otherwise, the 'rotateby' could just be added to the child's rotation)
    final function vector RealWorldLocation(vector oldpoint,rotator rotateby)
    {
     local vector temppoint;
     local rotator temprot;
     local float dist;
     local float axisdist;
     local float axisangle;

     temppoint=oldpoint;
     dist = VSize(temppoint);
     temppoint = temppoint/dist; // unity vector, requires less calculations

    // rotate around X-axis (Roll)
     axisangle = atan2(temppoint.Z,temppoint.Y);
     axisdist  = sqrt(square(temppoint.Z)+square(temppoint.Y));
     temppoint.Z= sin(axisangle-(RotateBy.Roll*pi)/32768.0)*axisdist;
     temppoint.Y= cos(axisangle-(RotateBy.Roll*pi)/32768.0)*axisdist;

    // rotate around Y-axis (Pitch)
     axisangle = atan2(temppoint.Z,temppoint.X);
     axisdist  = sqrt(square(temppoint.Z)+square(temppoint.X));
     temppoint.Z= sin(axisangle+(RotateBy.Pitch*pi)/32768.0)*axisdist;
     temppoint.X= cos(axisangle+(RotateBy.Pitch*pi)/32768.0)*axisdist;

     temprot=rotateby;
     temprot.Roll=0;
     temprot.Pitch=0;
    // return origin+vector(rotator(temppoint)+temprot)*dist;

    // rotate around Z-axis (Yaw)
     axisangle = atan2(temppoint.Y,temppoint.X);
     axisdist  = sqrt(square(temppoint.Y)+square(temppoint.X));
     temppoint.Y= sin(axisangle+(RotateBy.Yaw*pi)/32768.0)*axisdist;
     temppoint.X= cos(axisangle+(RotateBy.Yaw*pi)/32768.0)*axisdist;

     return vector(rotator(temppoint))*dist;
    }

    final function vector VirtualLocation(vector oldpoint,rotator rotateby)
    {
     local vector temppoint;
     local rotator temprot;
     local float dist;
     local float axisdist;
     local float axisangle;

     temppoint=oldpoint;
     dist = VSize(temppoint);
     temppoint = temppoint/dist; // unity vector, requires less calculations

    // rotate around Z-axis (Yaw)
     axisangle = atan2(temppoint.Y,temppoint.X);
     axisdist  = sqrt(square(temppoint.Y)+square(temppoint.X));
     temppoint.Y= sin(axisangle-(RotateBy.Yaw*pi)/32768.0)*axisdist;
     temppoint.X= cos(axisangle-(RotateBy.Yaw*pi)/32768.0)*axisdist;

    // rotate around Y-axis (Pitch)
     axisangle = atan2(temppoint.Z,temppoint.X);
     axisdist  = sqrt(square(temppoint.Z)+square(temppoint.X));
     temppoint.Z= sin(axisangle-(RotateBy.Pitch*pi)/32768.0)*axisdist;
     temppoint.X= cos(axisangle-(RotateBy.Pitch*pi)/32768.0)*axisdist;

    // rotate around X-axis (Roll)
     axisangle = atan2(temppoint.Z,temppoint.Y);
     axisdist  = sqrt(square(temppoint.Z)+square(temppoint.Y));
     temppoint.Z= sin(axisangle+(RotateBy.Roll*pi)/32768.0)*axisdist;
     temppoint.Y= cos(axisangle+(RotateBy.Roll*pi)/32768.0)*axisdist;

     temprot=rotateby;
     temprot.Roll=0;
     temprot.Pitch=0;
    // return origin+vector(rotator(temppoint)+temprot)*dist;

     return vector(rotator(temppoint))*dist; // add origin and distance again
    }

    // VirtualRotation rotates a rotation
    final function rotator VirtualRotation(rotator CurrentRotation,rotator planeangles)
    {
     local vector X,Y;

     //return CurrentRotation+planeangles;

     X=RealWorldLocation(vect(1,0,0),CurrentRotation);
     Y=RealWorldLocation(vect(0,1,0),CurrentRotation);
     X=VirtualLocation(X,planeangles);
     Y=VirtualLocation(Y,planeangles);

     return GetPlaneRotation(X,Y);
    }

    // getplanerotation determines the angles of a plane defined by two vectors, relative to the ground.
    // Two vectors are needed, because roll needs to be determined.
    final function rotator GetPlaneRotation(vector Xaxis,vector Yaxis)
    {
     local rotator temprot;
     local rotator rotat;
     local vector X,Y;

     X=Xaxis/VSize(Xaxis);
     Y=Yaxis/VSize(Yaxis);

     rotat.Yaw=(atan2(X.y,X.x)*32768.0)/pi;
    // rotat.Yaw=rotator(X).Yaw;
     temprot = rot(0,0,0);
     temprot.Yaw=-rotat.Yaw;
     X = RealWorldLocation(X,temprot);
     Y = RealWorldLocation(Y,temprot);
     rotat.Pitch = (atan2(X.z,X.x)*32768.0)/pi;
    // rotat.Pitch=rotator(X).Pitch;
     temprot = rot(0,0,0);
     temprot.Pitch=-rotat.Pitch;
     X = RealWorldLocation(X,temprot);
     Y = RealWorldLocation(Y,temprot);
     rotat.Roll = -(atan2(Y.Z,Y.Y)*32768.0)/pi;
     temprot = rot(0,0,0);
     temprot.Roll=-rotat.Roll;
     X = RealWorldLocation(X,temprot);
     Y = RealWorldLocation(Y,temprot);

     return rotat;
    }

    // RealWorldRotation rotates a rotation
    final function rotator RealWorldRotation(rotator CurrentRotation,rotator planeangles)
    {
     local vector X,Y;

     //return CurrentRotation+planeangles;

     X=RealWorldLocation(vect(1,0,0),CurrentRotation);
     Y=RealWorldLocation(vect(0,1,0),CurrentRotation);
     X=RealWorldLocation(X,planeangles);
     Y=RealWorldLocation(Y,planeangles);

     return GetPlaneRotation(X,Y);
    }

    final function rotator InverseRotation(rotator rotat)
    {
     local rotator newrot;

     newrot.Yaw=-rotat.Yaw;
     newrot.Pitch=-rotat.Pitch;
     newrot.Roll=-rotat.Roll;
     return newrot;
    }

    function bool LadderCheck(pawn specificuser)
    {
     local pawn user;
     local float userrot;

     foreach touchingactors(class'pawn',user) {
      if(user==specificuser) {
       userrot=VirtualRotation(user.rotation,rotation).Yaw;
       if(userrot>-16384 && userrot<16384)
        return true;
       else
        return false;
      }
     }
     return false;
    }

    function Tick(float DeltaTime)
    {
     local pawn p;

     if(Owner==None) { // only pickup item, not inventory item
      foreach touchingactors(class'pawn',p) {
       if(p.FindInventoryType(class'SFVehicleladder')==None)
        SpawnCopy(p);
      }
     }
     else
     if(go && Original!=None) {
      p=pawn(owner);
      if(Original.LadderCheck(p)) {
       p.setphysics(PHYS_Flying);
       p.TweenToRunning(deltatime);
       ownerspeed=p.groundspeed/2*(virtuallocation(vector(p.viewrotation),original.rotation).Z);
       p.velocity=ownerspeed*realworldlocation(vect(0,0,1),original.rotation);//-owner.region.zone.zonegravity*deltatime; // any player can take two steps per second
      }
      else {
       p.setphysics(PHYS_Falling);
       Destroy();
      }
     }
    }

    function inventory SpawnCopy( pawn Other )
    {
    	local SFVehicleLadder Copy;

    	Copy = spawn(Class,Other);
    	Copy.Tag           = Tag;
    	Copy.Event         = Event;
    	Copy.Original=Self;

    	Copy.RespawnTime = 0.0;
    	Copy.aircontrol=other.aircontrol;
    	Copy.GiveTo( Other );
    	copy.ownerwantstomove=false;
    	Copy.Go = true;
    	Copy.SetTimer(1,true);

    //	log("Pawn touched me");
    	return Copy;
    }

    function SetRespawn()
    {
    }

    function bool validtouch(actor other)
    {
     return true;
    }

    function OwnerJumped()
    {
     ownerwantstomove=!ownerwantstomove;
    }

    function BeginPlay()
    {
     super.beginplay();
     DrawType=DT_None;
    }

    defaultproperties
    {
         bAutoActivate=True
         PickupMessage=""
         BobDamping=1.000000
         MaxDesireability=0.000000
         M_Activated=""
         M_Selected=""
         M_Deactivated=""
         bHidden=True
         Texture=Texture'Editor.B_MenuUp'
         CollisionRadius=20.000000
         CollisionHeight=128.000000
    }

class file time: 12/7/2003 3:58:26 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX