# SpatialFear.SFFadeWindow

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 |
    //=============================================================================
    // Spatial Fear
    // Name: SFFadeWindow
    // Description: Subclass of SFTextWindow, shows it's contents and fades away
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFFadeWindow extends SFTextWindow;

    var float	m_fFadeOutTime; // Private: Time in seconds for the whole fade action
    var float	m_fFadeOutDelay;	// Private: Time it takes, before finished running text fades out. Default: 3 seconds
    var float	m_fFadeTime; // Priave: Current fade time
    var bool	m_bFlicker; // Private: If set to true, the fading starts again, when having reached the lower bound. Default: false
    var color   m_colStart; // Private: Color, starting the fade. Default: (R=255,G=255,B=255)
    var color   m_colEnd; // Private: Color, ending the fade. Default: (R=0,G=0,B=0)
    var bool	m_bReverse; // Private: Reverse the fading direction: Default: false
    var bool	m_bNoFade; // Private: Enables/Disables fading. Default: false
    var bool	m_bHideOnFullFade; // Private: Whether to hide the window after the fade finishes or not: Default:true;
    var SFFadeWindow	m_wndFadeParent; // Private: Typed reference to parent, to prevent too much casting

    simulated event FadedOut();

    // Stops the current fade progress
    simulated function stopFading()
    {
    	m_bNoFade	= true;
    }

    // Configures the window for a single fade in upward direction
    simulated function setSingleFade(float fFadeTime)
    {
    	m_bReverse			= false;
    	m_bNoFade			= false;
    	m_bHideOnFullFade	= true;
    	m_fFadeOutTime		= fFadeTime;
    }

    // Configures the window for a single fade in reverse direction
    simulated function setSingleFadeReverse(float fFadeTime)
    {
    	m_bReverse			= true;
    	m_bNoFade			= false;
    	m_bHideOnFullFade	= false;
    	m_fFadeOutTime		= fFadeTime;
    }

    // Check if we are in a fade move
    simulated function bool isFading()
    {
    	return (!m_bRunningText) && (!m_bNoFade);
    }

    // Check if we are fading out
    simulated function bool isFadingOut()
    {
    	return !m_bRunningText && !m_bNoFade && !m_bReverse;
    }

    // Check if we are fading in
    simulated function bool isFadingIn()
    {
    	return !m_bRunningText && !m_bNoFade && m_bReverse;
    }

    // Check if we are fully faded in
    simulated function bool isFadedIn()
    {
    	return (m_bNoFade && isVisible()) || m_bRunningText;
    }

    // Check if we are fully faded out
    simulated function bool isFadedOut()
    {
    	return m_bNoFade && !isVisible();
    }

    // Clock down the fade time
    simulated function Tick(float fDelta)
    {
    	// First check, if we use the parent settings
    	if(None != m_wndFadeParent)
    	{
    		// Early out
    		if(!m_wndFadeParent.m_bVisible)
    			return;

    		m_fFadeTime 	= m_wndFadeParent.m_fFadeTime;
    		m_fFadeOutTime	= m_wndFadeParent.m_fFadeOutTime;
    		m_bVisible 		= m_wndFadeParent.m_bVisible;
    		m_bReverse		= m_wndFadeParent.m_bReverse;
    		m_bVisible		= m_wndFadeParent.m_bVisible;
    		m_bNoFade		= m_wndFadeParent.m_bNoFade;

    		// Stop processing here
    		return;
    	}

    	if(m_bRunningText)
    		return;

    	if(!m_bVisible)
    		return;

    	if(m_bNoFade)
    		return;

    	if((m_fFadeOutDelay	> 0) && !m_bReverse && m_bUsedRunningText)
    	{
    		m_fFadeOutDelay	-= fDelta;
    		return;
    	}

    	// Do not use parent settings, calcualte your own
    	if(!m_bReverse)
    	{
    		// Fade down
    		m_fFadeTime -= fDelta;
    		if(0.0f > m_fFadeTime)
    		{
    			if(!m_bFlicker)
    			{
    				if(m_bHideOnFullFade)
    					m_bVisible = false;
    				else
    					stopFading();
    			}
    			else
    			{
    				m_fFadeTime	= 0.0f;
    				m_bReverse	= !m_bReverse;
    			}
    			// Call event
    			FadedOut();
    		}
    	}
    	else
    	{
    		// Fade up
    		m_fFadeTime += fDelta;
    		if(m_fFadeTime > m_fFadeOutTime)
    		{
    			if(!m_bFlicker)
    			{
    				if(m_bHideOnFullFade)
    					m_bVisible = false;
    				else
    					stopFading();
    			}
    			else
    			{
    				m_fFadeTime	= m_fFadeOutTime;
    				m_bReverse	= !m_bReverse;
    			}
    			// Call event
    			FadedOut();
    		}
    	}

    }

    // Set up the canvas
    simulated function prepareCanvas(Canvas C)
    {
     	// Call to base class
    	Super.prepareCanvas(C);
    	if(!m_bNoFade)
    		C.DrawColor = m_colStart * (m_fFadeTime/m_fFadeOutTime) + m_colEnd;
    	else
    		C.DrawColor = m_colStart;
    }

    simulated function resetFadeCounter()
    {
    	m_fFadeOutDelay	= Default.m_fFadeOutDelay;

    	if(m_bReverse)
    		m_fFadeTime = 0.0f;
    	else
    		m_fFadeTime = m_fFadeOutTime;
    }

    // Overwritten base class function to trackt the fade time
    function show()
    {
    	// Call to base class
    	Super.show();

    	if(None != m_wndParent)
    	{
    		if(m_wndParent.IsA('SFFadeWindow'))
    		{
    			// Parent settings are used
    			m_wndFadeParent	= SFFadeWindow(m_wndParent);
    			m_fFadeTime		= m_wndFadeParent.m_fFadeTime;

    			// Stop processing here
    			return;
    		}
    		else
    			m_wndFadeParent	= None;
    	}

    	resetFadeCounter();
    }

    defaultproperties
    {
         m_fFadeOutTime=2.000000
         m_fFadeOutDelay=3.000000
         m_colStart=(R=255,G=255,B=255)
         m_bHideOnFullFade=True
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX