# SFCharacter3.SFHunter

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 00473 00474 00475 00476 00477 00478 00479 00480 00481 00482 00483 00484 00485 00486 00487 00488 00489 00490 00491 00492 00493 00494 00495 00496 00497 00498 00499 00500 00501 00502 00503 00504 00505 00506 00507 00508 00509 00510 00511 00512 00513 00514 00515 00516 00517 00518 00519 00520 00521 00522 00523 00524 00525 00526 00527 00528 00529 00530 00531 00532 00533 00534 00535 00536 00537 00538 00539 00540 00541 00542 00543 00544 00545 00546 00547 00548 00549 00550 00551 00552 00553 00554 00555 00556 00557 00558 00559 00560 00561 00562 |
    //=============================================================================
    // Spatial Fear
    // Class: SFHunter
    // Description:  Medium SF enemy. Melee and Long Range attacks if has weapon
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFHunter expands SFScriptedPawn;

    #exec OBJ LOAD FILE=SPF-Content.uax  PACKAGE=SPF-Content GROUP=Creatures

    #exec MESH IMPORT MESH=SFHunter ANIVFILE=MODELS\SFHunter_a.3d DATAFILE=MODELS\SFHunter_d.3d X=0 Y=0 Z=0
    #exec MESH ORIGIN MESH=SFHunter X=0 Y=0 Z=-123 YAW=-64 ROLL=0 PITCH=0
    #exec MESH SCALE x=0.075 y=0.075 z=0.15

    #exec MESH SEQUENCE MESH=SFHunter SEQ=All STARTFRAME=0 NUMFRAMES=229

    //General Animations, can be used if Hunter is holding a weapon or not.

    //Movement Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=StrafeL STARTFRAME=159 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFHunter SEQ=StrafeR STARTFRAME=169 NUMFRAMES=10 RATE=10

    //Wait Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Breath1 STARTFRAME=21 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Look1 STARTFRAME=179 NUMFRAMES=15 RATE=5 Group=Waiting
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Fighter STARTFRAME=1 NUMFRAMES=1

    //Special Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Roar1 STARTFRAME=194 NUMFRAMES=15 RATE=10

    //Take Hit Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=HeadHit STARTFRAME=181 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFHunter SEQ=GutHit STARTFRAME=68 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFHunter SEQ=LeftHit STARTFRAME=79 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFHunter SEQ=RightHit STARTFRAME=79 NUMFRAMES=1 Group=TakeHit

    //Death Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Dead1 STARTFRAME=69 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Dead2 STARTFRAME=79 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Dead3 STARTFRAME=89 NUMFRAMES=15 RATE=10

    //Body frames.  Used for corpses.
    #exec MESH SEQUENCE MESH=SFHunter SEQ=DeathEnd STARTFRAME=78 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFHunter SEQ=DeathEnd2 STARTFRAME=99 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFHunter SEQ=DeathEnd3 STARTFRAME=229 NUMFRAMES=1

    //Melee Animations, Only used if Hunter is NOT holding a weapon.
    //Movement Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Run STARTFRAME=1 NUMFRAMES=20 RATE=30
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Run2 STARTFRAME=31 NUMFRAMES=15 RATE=20
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Walk STARTFRAME=1 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Turn STARTFRAME=2 NUMFRAMES=2 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=StrafeL STARTFRAME=159 NUMFRAMES=10 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=StrafeR STARTFRAME=169 NUMFRAMES=10 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Jump STARTFRAME=134 NUMFRAMES=1 Group=Jumping
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Land STARTFRAME=138 NUMFRAMES=1 Group=Landing

    //Attack Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Attack1 STARTFRAME=46 NUMFRAMES=23 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Attack2 STARTFRAME=104 NUMFRAMES=21 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Attack3 STARTFRAME=125 NUMFRAMES=14 RATE=15

    //Melee Animations, Only used if Hunter IS holding a weapon.
    //Movement Animations
    #exec MESH SEQUENCE MESH=SFHunter SEQ=RunGun STARTFRAME=139 NUMFRAMES=20 RATE=30

    //Attack Animations

    #exec MESH SEQUENCE MESH=SFHunter SEQ=Shoot1 STARTFRAME=209 NUMFRAMES=10 RATE=15
    #exec MESH SEQUENCE MESH=SFHunter SEQ=Shoot2 STARTFRAME=219 NUMFRAMES=10 RATE=15

    #exec MESHMAP NEW MESHMAP=SFHunter MESH=SFHunter
    #exec MESHMAP SCALE MESHMAP=SFHunter X=0.1 Y=0.1 Z=0.2

    #exec TEXTURE IMPORT NAME=HuntHead1 FILE=TEXTURES\HunterHead.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=HuntHead1 FILE=TEXTURES\HunterHead.pcx GROUP=Skins PALETTE=HuntHead1
    #exec MESHMAP SETTEXTURE MESHMAP=SFHunter NUM=1 TEXTURE=HuntHead1

    #exec TEXTURE IMPORT NAME=HuntBody1 FILE=TEXTURES\HunterBody.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=HuntBody1 FILE=TEXTURES\HunterBody.pcx GROUP=Skins PALETTE=HuntBody1
    #exec MESHMAP SETTEXTURE MESHMAP=SFHunter NUM=2 TEXTURE=HuntBody1

    #exec TEXTURE IMPORT NAME=HuntArm1 FILE=TEXTURES\HunterArm.pcx GROUP=Skins FLAGS=2 LODSET=0
    #exec TEXTURE IMPORT NAME=HuntArm1 FILE=TEXTURES\HunterArm.pcx GROUP=Skins PALETTE=HuntArm1
    #exec MESHMAP SETTEXTURE MESHMAP=SFHunter NUM=3 TEXTURE=HuntArm1

    var name	m_nameRestoreState;
    var vector	m_vectPushDir;
    var float	m_fAttackWait;

    var float WSpeed;
    var float RSpeed;
    var float SSpeed;
    var (SpatialFear) bool bHasWeapon; // Determines if enemy is spawned with or without a weapon. Default: false

    function PostBeginPlay()
    {
    	// Call to base class
    	Super.PostBeginPlay();

    	if(bHasWeapon)
    	{
    		// Set parameters
    		WeaponType=Class'SFWeapon.SFAlien';
    		bCanFire=true;
    		bHasRangedAttack=true;
    		bMovingRangedAttack=true;

    	}
    }

    function eAttitude AttitudeToCreature(Pawn Other)
    {

    	local float fDecision;

    	// Check the global attitude flag
    	if(!bFightOtherCreatures)
    		return ATTITUDE_IGNORE;

    	fDecision	= FRand();

    	if ( Other.IsA('SFHunter') )
    	{
    		if(fDecision < 0.02)
    			return ATTITUDE_Threaten;
    		else if ((fDecision < 0.03) && (!SFHunter(Other).bHasWeapon))
    			return ATTITUDE_Hate;
    		else
    			return ATTITUDE_Friendly;
    	}
    	else
    		if(ScriptedPawn(Other).Aggressiveness > Aggressiveness)
    			return ATTITUDE_Ignore;
    		else
    		{
    			if(FRand() < 0.02)
    				return ATTITUDE_Threaten;
    			else
    				return ATTITUDE_Ignore;
    		}
    }

    function TweenToRunning(float tweentime)
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	if (bIsWalking)
    		TweenToWalking(0.1);
    	else
    	{
    		if(bHasWeapon)
    			PlayAnim('RunGun', 1, tweentime);
    		else
    			PlayAnim('Run', 1, tweentime);
    	}

    	if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    	{
    		// Strafing
    		if ( Dir Dot Y > 0 )
    			PlayAnim('StrafeR', SSpeed, tweentime);
    		else
    			PlayAnim('StrafeL', SSpeed, tweentime);
    	}
    }

    function PlayStunned()
    {
    	PlayAnim('Fighter');
    }

    function PlayWalking()
    {
    	PlaySound(WalkSound, SLOT_Interact);
    	LoopAnim(WalkAnim, WSpeed/GroundSpeed,0.1,0.4);
    }

    function PlayRunning()
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	PlaySound(RunSound, SLOT_Interact);

    	if(bHasWeapon)
    		LoopAnim('RunGun', RSpeed/GroundSpeed,0.1,0.4);
    	else
    	{
    		if(FRand() < 0.72)
    			LoopAnim('Run', RSpeed/GroundSpeed,0.1,0.4);
    		else
    			LoopAnim('Run2', RSpeed/GroundSpeed,0.1,0.4);

    		if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    		{
    			// Strafing
    			if ( Dir Dot Y > 0 )
    				LoopAnim('StrafeR', SSpeed/GroundSpeed);
    			else
    				LoopAnim('StrafeL', SSpeed/GroundSpeed);
    		}

    	}
    }

    function TweenToWaiting(float tweentime)
    {
    	TweenAnim('Look1', tweentime);
    }

    function PlayWaiting()
    {
    	local float decision;
    	local float animspeed;

    	animspeed = 0.1 + 0.6 * FRand();
    	decision = FRand();

    	if ( !bool(NextAnim) || (decision < 0.7) ) //pick first waiting animation
    		NextAnim = 'Breath1';
    	else if (decision < 0.94)
    		NextAnim = 'Look1';
    	else
    	{
    		if ( !bQuiet )
    			PlaySound(Threaten, SLOT_Talk, 0.7,,800);
    		NextAnim	= 'Roar1';
    	}

    	LoopAnim(NextAnim, animspeed, , 0.4);

    }

    function PlayChallenge()
    {
    	if ( FRand() < 0.1 )
    		PlayWaiting();
    	else
    		PlayAnim('Roar1', 1.4);
    }

    function TweenToFighter(float tweentime)
    {
    	TweenAnim('Fighter', tweentime);
    }

    function PlayDying(name DamageType, vector HitLocation)
    {
    	local carcass carc;

    	PlaySound(Die, SLOT_Talk, 3.5 * TransientSoundVolume);

    	if ( FRand() < 0.70 )
    		PlayAnim('Dead1', 0.7, 0.1);
    	else if ( FRand() < 0.95 )
    		PlayAnim('Dead2', 0.7, 0.1);
    	else
    		PlayAnim('Dead3', 0.7, 0.1);
    }

    function PlayMeleeAttack()
    {
    	local float dist, decision;

    	if(bHasWeapon)
    	{
    		Acceleration = AccelRate * VRand();
    		TweenToWaiting(0.15);
    		FireWeapon();
    	}
    	else
    	{
    		m_vectPushDir	= vect(0,0,0);
    		decision		= FRand();
    		dist = VSize(Target.Location - Location);
    		if (dist > CollisionRadius + Target.CollisionRadius + 45)
    			decision = 0.0;

    		if (Physics == PHYS_Falling)
    			decision = 1.0;
    		if (Target == None)
    			decision = 1.0;

    		if(FRand() < 0.9)
    			PlaySound(Threaten, SLOT_Interact);
    		else
    			PlaySound(Roam, SLOT_Interact);

    		if(decision < 0.8)
    		{
    			// Save the current state name
    			m_nameRestoreState	= GetStateName();
    			// Calculate momentum for this attack
    			m_vectPushDir		= 30000 * (Normal(Target.Location - Location));
    			// Set the wait time for the damage application
    			m_fAttackWait		= 0.5;
    			// Play the animation
    			PlayAnim('Attack1', 1.4,0.1);
    			// Switch to delaying state
    			GotoState('Hitting');
    		}
    		else if(decision < 0.95)
    		{
    			// Save the current state name
    			m_nameRestoreState	= GetStateName();
    			// Calculate momentum for this attack
    			m_vectPushDir		= 50000 * (Normal(Target.Location - Location));
    			// Set the wait time for the damage application
    			m_fAttackWait		= 0.5;
    			// Play the animation
    			PlayAnim('Attack2', 1.4,0.1);
    			// Switch to delaying state
    			GotoState('Hitting');
    		}
    		else
    		{
    			// Save the current state name
    			m_nameRestoreState	= GetStateName();
    			// Calculate momentum for this attack
    			m_vectPushDir		= 25000 * (Normal(Target.Location - Location));
    			// Set the wait time for the damage application
    			m_fAttackWait		= 0.5;
    			// Play the animation
    			PlayAnim('Attack3', 1.3,0.1);
    			// Switch to delaying state
    			GotoState('Hitting');
    		}
    	}
    }

    function PlayRangedAttack()
    {
    	PlayFiring();
    }

    function PlayFiring()
    {
    	local float	fDecision;
    	local name	nameAnim;

    	fDecision	= FRand();
    	if(fDecision < 0.8)
    		nameAnim	= 'Shoot1';
    	else
    		nameAnim	= 'Shoot2';

    	PlayAnim(nameAnim, 1.8, 0.3);

    	if ( (Weapon != None) && (Weapon.AmmoType != None) )
    		Weapon.AmmoType.AmmoAmount = Weapon.AmmoType.Default.AmmoAmount;
    }

    function FireWeapon()
    {
    	local float rating;
    	local int bUseAltMode;

    	if( Weapon!=None )
    	{
    		Weapon.RateSelf(bUseAltMode);
    		ViewRotation = Rotation;
    		if ( bUseAltMode > 0 )
    		{
    			bFire = 0;
    			bAltFire = 1;
    			Weapon.AltFire(1.0);
    		}
    		else
    		{
    			bFire = 1;
    			bAltFire = 0;
    			Weapon.Fire(1.0);
    		}
    		PlayFiring();
    	}
    }

    state TakeHit
    {
    ignores seeplayer, hearnoise, bump, hitwall;

    	function BeginState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.BeginState();
    	}
    }

    state Retreating
    {
    ignores SeePlayer, EnemyNotVisible, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state Charging
    {
    ignores SeePlayer, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state TacticalMove
    {
    ignores SeePlayer, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state Hunting
    {
    ignores EnemyNotVisible;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		if ( !Region.Zone.bWaterZone )
    			bCanSwim = false;
    		Super.EndState();
    	}
    }

    // State used to delay the MeleeDamageTarget
    // until part of the attack animation has been played
    state Hitting
    {
    Begin:
    	Sleep(m_fAttackWait);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	FinishAnim();
    	GotoState(m_nameRestoreState);
    }

    state RangedAttack
    {
    	function PlayRangedAttack()
    	{
    		local float dist;

    		if(bHasWeapon)
    		{
    			Disable('Bump');
    			FireWeapon();
    		}
    		else
    			Super.PlayRangedAttack();
    	}

    	function AnimEnd()
    	{
    		if(bHasWeapon)
    		{
    			if ( (FRand() < 0.5) || ((bFire == 0) && (bAltFire == 0)) )
    				GotoState('RangedAttack', 'DoneFiring');
    			else
    				TweenAnim('Shoot1', 0.2);
    		}
    		else
    			Super.AnimEnd();

    	}

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}

    }

    defaultproperties
    {
         WSpeed=-3.000000
         RSpeed=-4.550000
         SSpeed=-6.550000
         WalkSound=Sound'SPF-Content.Creatures.HunterWalk'
         WalkAnim=Walk
         RunSound=Sound'SPF-Content.Creatures.HunterWalk'
         RunAnim=Run
         ThreatenAnim=Roar1
         TakeHitAnim=GutHit
         VictoryAnim=Roar1
         SmellRadius=2700.000000
         fMeleeDamage=15.000000
         fStunnedTime=3.000000
         CarcassType=Class'SFCharacter.SFSkavCarcass'
         TimeBetweenAttacks=0.000000
         Aggressiveness=1.000000
         Acquire=Sound'SPF-Content.Creatures.HunterAquire'
         Fear=Sound'SPF-Content.Creatures.HunterFear'
         Roam=Sound'SPF-Content.Creatures.HunterRoam'
         Threaten=Sound'SPF-Content.Creatures.HunterThreaten'
         bCanStrafe=True
         bCanJump=True
         MeleeRange=50.000000
         GroundSpeed=700.000000
         WaterSpeed=400.000000
         AccelRate=450.000000
         JumpZ=180.000000
         Visibility=80
         SightRadius=2600.000000
         Health=225
         Intelligence=BRAINS_HUMAN
         Skill=1.500000
         HitSound1=Sound'SPF-Content.Creatures.HunterHit1'
         HitSound2=Sound'SPF-Content.Creatures.HunterHit2'
         Die=Sound'SPF-Content.Creatures.HunterDie'
         CombatStyle=1.000000
         DrawType=DT_Mesh
         Mesh=LodMesh'SFCharacter3.SFHunter'
         ScaleGlow=0.150000
         MultiSkins(1)=Texture'SFCharacter.NewSkins.hunt1'
         MultiSkins(2)=Texture'SFCharacter.NewSkins.hunt2'
         MultiSkins(3)=Texture'SFCharacter.NewSkins.hunt3'
         CollisionRadius=30.000000
         CollisionHeight=44.000000
    }

class file time: 12/7/2003 3:58:26 PM - creation time: 12/7/2003 4:03:44 PM
Created with UnCodeX