# SpatialFear.SFPassiveItemBelt

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 |
    //=============================================================================
    // Spatial Fear
    // Name: SFPassiveItemBelt
    // Description: Collection of item slot windows, that show the currently
    //              equipped passive inventory.
    //
    // Author: Markus Nuebel
    //=============================================================================

    class SFPassiveItemBelt extends SFFadeWindow;

    var int		m_nNumberOfIcons; // Number of icons that the belt can show, depending on it's size.
    var int		m_nNumberOfItems; // Number of items in the belt. Can be more than the belt can show. You need to scroll.
    var int		m_nIconSize; // Dimension of Icon
    var int		m_nIconDisplaySize; // Dimension of Icon (display)
    var int		m_nIconBorder; // Border size between icons. Size for one side ONLY!

    var SFItemSlot	m_arSlots[9]; // Array of slot icons

    // All initialization stuff
    simulated function init(float fHUDScale, int X, int Y, int nWidth, int nHeight, optional Pawn Owner, optional string strText, optional SFWindow wndParent)
    {
    	// Call to base class
    	Super.init(fHUDScale, X, Y, nWidth, nHeight, Owner, strText, wndParent);

    	// Special belt inits
    	m_nNumberOfIcons		= m_nWidth/(m_nIconDisplaySize+m_nIconBorder);
    	m_nNumberOfItems		= 0;

    	//class'SFUtils'.static.sfLogEx(15, "SFPassiveItemBelt - init: NumberOfIcons " $ m_nNumberOfIcons $ " X: " $ m_XCur $ " Y: " $ m_YCur $ " Width " $ m_nWidth $ " Height: " $ m_nHeight   );

    }

    // Cleanup
    simulated function terminate()
    {
    	local int i;

    	// Call to base class
    	Super.terminate();

    	// Cleanup slot array
    	for(i=0; i<m_nNumberOfItems; i++)
    		m_arSlots[i] = None;

    }

    // Overwritten to do fade effect
    simulated function show()
    {
    	local int i;

    	setSingleFadeReverse(2.0f);

    	Super.show();
    }

    // Overwritten to do fade effect
    simulated function hide()
    {
    	local int i;

    	setSingleFade(2.0f);

    	// Because the fade out replaces the hide command
    	if(None != m_sndClose)
    		m_oPawnOwner.PlaySound(m_sndClose, SLOT_Misc, m_fCloseSoundVol);

    	// No super here, since fade out does the hide
    	//Super.hide();
    }

    // Resets the belt, called before new population
    simulated function reset()
    {
    	local int i;

    	// Free references
    	// Cleanup slot array
    	for(i=0; i<m_nNumberOfItems; i++)
    		m_arSlots[i] = None;

    	// Rest counters
    	m_nNumberOfItems		= 0;
    }

    // Checks, if the item is already possesed
    simulated function bool findItem(SFPickup item)
    {
    	local int i;

    	// FIXME: just for testing, everything is accepted
    	return false;

    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Check matching and early out
    		if(m_arSlots[i].m_item.class == item.class)
    		{
    			//class'SFUtils'.static.sfLogEx(5, "SFPassiveItemBelt - findItem: Item" $ item.class $ " already equipped." );
    			return true;
    		}
    	}

    	// Not Found
    	return false;
    }

    // Removes an item from the belt
    simulated function bool removeItem(SFPickup item)
    {
    	local int i, nSlot;

    	// Some inits
    	nSlot = -1;

    	// First find the item
    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Check matching and early out
    		if(m_arSlots[i].m_item.class == item.class)
    		{
    			nSlot = i;
    		}
    	}

    	if(-1 == nSlot)
    		return true;

    	// Kick it out
    	m_arSlots[nSlot] = None;

    	// Rebuild belt
    	for(i=nSlot; i<m_nNumberOfItems-1; i++)
    		m_arSlots[i] = m_arSlots[i+1];

    	// Clear the last (now free) entry
    	m_arSlots[m_nNumberOfItems-1] = None;

    	// Decrease belt size
    	m_nNumberOfItems--;

    	return true;

    }
    // Inserts a new item into the belt
    simulated function bool insert(SFPickup item)
    {
    	// Check for maximum belt capacity
    	if(m_nNumberOfItems >= 9)
    		return false;

    	// Check, if already equipped
    	if(findItem(item))
    		return false;

    	//class'SFUtils'.static.sfLogEx(5, "SFPassiveItemBelt - insert: Inserting" $ item.name $ " at pos: " $ m_nNumberOfItems );

    	// Insert item
    	m_arSlots[m_nNumberOfItems] = m_oPawnOwner.Spawn(class'SFItemSlot');
    	m_arSlots[m_nNumberOfItems].insert(m_nNumberOfItems, item);
    	m_arSlots[m_nNumberOfItems].init(m_fHUDScale, m_XCur, m_YCur, m_nIconSize, m_nIconSize, m_oPawnOwner);
    	m_arSlots[m_nNumberOfItems].setParent(Self);
    	m_arSlots[m_nNumberOfItems].m_bNoFade = false;

    	// Increment item count
    	m_nNumberOfItems++;

    	return true;
    }

    // Recalculates the icons positions based on the currently selected item
    simulated function recalcPositions()
    {
    	local int	i, x, y;

    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		// Calculat the new position
    		x			= m_XCur + i*(m_nIconDisplaySize+m_nIconBorder);
    		y			= m_YCur;
    		m_arSlots[i].setPos(x, y);
    		if(!m_arSlots[i].isVisible())
    			m_arSlots[i].show();
    	}
    }

    // Overwritten here to display the single item slots
    simulated function renderBackground(Canvas C)
    {
    	local int	i;

    	// Call to base class
    	Super.renderBackground(C);

    	// Recalculate the icon positions
    	recalcPositions();

    	// render icons
    	for(i=0; i<m_nNumberOfItems; i++)
    	{
    		if(None != m_arSlots[i])
    			m_arSlots[i].render(C, m_fHUDScale);
    	}

    }

    defaultproperties
    {
         m_nIconSize=64
         m_nIconDisplaySize=32
         m_nIconBorder=4
         m_texBkg=Texture'SfResource1.Background.PassiveBelt'
         m_nBorderSize=16
         m_sndOpen=Sound'SfResource1.Window.OpenPassiveWnd'
         m_sndClose=Sound'SfResource1.Window.ClosePassiveWnd'
         m_fOpenSoundVol=14.000000
         m_fCloseSoundVol=14.000000
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX