# SFCharacter4.SFReaver

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 |
    //=============================================================================
    // Spatial Fear
    // Class: SFReaver
    // Description: Hardcore enemy. Added in v1.2
    //
    // Author: Chris Rogers
    //=============================================================================
    Class SFReaver extends SFScriptedPawn;

    // Importing and Scaling Mesh
    #exec MESH MODELIMPORT MESH=SFReaver MODELFILE=Models\Reaver.PSK LODSTYLE=10 X=0 Y=0 Z=0
    #exec MESH ORIGIN MESH=SFReaver X=0 Y=5 Z=0 YAW=-64 PITCH=00 ROLL=64
    #exec MESHMAP SCALE MESHMAP=SFReaver X=10 Y=10 Z=10

    // Importing, Defining Extra, and Digesting Animations
    #exec ANIM IMPORT ANIM=SFReaver ANIMFILE=Models\Reaver.PSA IMPORTSEQS=1 COMPRESS=1 MAXKEYS=999999
    #exec MESH SEQUENCE MESH=SFReaver SEQ=DeathFront1End STARTFRAME=251 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFReaver SEQ=DeathFront2End STARTFRAME=263 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFReaver SEQ=DeathBackEnd STARTFRAME=279 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFReaver SEQ=DeathRunEnd STARTFRAME=292 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFReaver SEQ=DeathLeapEnd STARTFRAME=307 NUMFRAMES=1
    #exec ANIM DIGEST ANIM=SFReaver VERBOSE

    // Linking Mesh and Animations
    #exec MESH DEFAULTANIM MESH=SFReaver ANIM=SFReaver

    // Notification Callbacks
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=LeapHit TIME=0.0 FUNCTION=Attack
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=AttackR TIME=0.0 FUNCTION=Attack
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=AttackL TIME=0.0 FUNCTION=Attack
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=Hack TIME=0.2 FUNCTION=Attack
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=slice TIME=0.2 FUNCTION=Attack
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=Hit TIME=0.0 FUNCTION=Hit
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=HitLeap TIME=0.0 FUNCTION=Hit
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=DeathFront1 TIME=0.0 FUNCTION=Death
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=DeathFront2 TIME=0.0 FUNCTION=Death
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=DeathBack TIME=0.0 FUNCTION=Death
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=DeathRun TIME=0.0 FUNCTION=Death
    #exec ANIM NOTIFY ANIM=SFReaver SEQ=DeathLeap TIME=0.0 FUNCTION=Death

    // Importing and Linking Textures
    #exec TEXTURE IMPORT NAME=Reaver1 FILE=Skins\reaver1.pcx GROUP="Skins" MIPS=ON
    #exec TEXTURE IMPORT NAME=Reaver2 FILE=Skins\reaver2.pcx GROUP="Skins" MIPS=ON
    #exec TEXTURE IMPORT NAME=Reaver3 FILE=Skins\reaver3.pcx GROUP="Skins" MIPS=ON
    #exec MESHMAP SETTEXTURE MESHMAP=SFReaver NUM=0 TEXTURE=Reaver1
    #exec MESHMAP SETTEXTURE MESHMAP=SFReaver NUM=1 TEXTURE=Reaver2
    #exec MESHMAP SETTEXTURE MESHMAP=SFReaver NUM=2 TEXTURE=Reaver3

    var (SpatialFear) byte HitDamage, HackDamage, SliceDamage;

    var name	m_nameRestoreState;
    var vector	m_vectPushDir;
    var float	m_fAttackWait, fAttackDamage, WSpeed, RSpeed, SSpeed;

    //=============================================================================
    // General Functions

    function eAttitude AttitudeToCreature(Pawn Other)
    {

    	local float fDecision;

    	if ( Other.IsA('SFScientist') || Other.IsA('SFMaleOfficer') || Other.IsA('SFFemaleOfficer') )
    	{
    		if (FRand() < 0.5)
    			return ATTITUDE_Hate;
    		else
    			return ATTITUDE_Frenzy;
    	}

    	if(!bFightOtherCreatures)
    		return ATTITUDE_IGNORE;

    	fDecision	= FRand();

    	if ( Other.IsA('SFReaver') )
    	{
    		if(fDecision < 0.02)
    			return ATTITUDE_Threaten;
    		else if ((fDecision < 0.03))
    			return ATTITUDE_Hate;
    		else
    			return ATTITUDE_Friendly;
    	}
    	else
    		if(ScriptedPawn(Other).Aggressiveness > Aggressiveness)
    			return ATTITUDE_Ignore;
    		else
    		{
    			if(FRand() < 0.02)
    				return ATTITUDE_Threaten;
    			else
    				return ATTITUDE_Ignore;
    		}
    }

    function TweenToRunning(float tweentime)
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	if (bIsWalking)
    		TweenToWalking(0.1);
    	else
    	{
    		TweenAnim('Run', tweentime);
    	}

    	if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    	{
    		if ( Dir Dot Y > 0 )
    			TweenAnim('StrafeR', tweentime);
    		else
    			TweenAnim('StrafeL', tweentime);
    	}
    }

    function TweenToWalking(float tweentime)
    {
    	TweenAnim('Walk', tweentime);
    }

    function PlayRunning()
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	PlaySound(RunSound, SLOT_Interact);

    	LoopAnim('Run', RSpeed/GroundSpeed,0.1,0.4);

    	if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    	{
    		if ( Dir Dot Y > 0 )
    			LoopAnim('StrafeR', SSpeed/GroundSpeed);
    		else
    			LoopAnim('StrafeL', SSpeed/GroundSpeed);
    	}
    }

    function PlayTurning()
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	if ( Dir Dot Y > 0 )
    		LoopAnim('TurnR', SSpeed/GroundSpeed);
    	else
    		LoopAnim('TurnL', SSpeed/GroundSpeed);
    }

    function PlayStunned()
    {
    	PlayAnim('Fighter');
    	GoToState('Waiting');
    }

    function PlayWalking()
    {
    	PlaySound(WalkSound, SLOT_Interact);
    	LoopAnim(WalkAnim, WSpeed/GroundSpeed,0.09,0.4);
    }

    function TweenToWaiting(float tweentime)
    {
    	TweenAnim('Look', tweentime);
    }

    function PlayTakeHit(float tweentime, vector HitLoc, int damage)
    {
    	Velocity /= 4;
    	if ( AnimSequence == 'Leap' )
    		return;
    	else
    		PlayAnim(TakeHitAnim);
    }

    function PlayWaiting()
    {
    	local float decision;
    	local float animspeed;

    	animspeed = 0.1 + 0.6 * FRand();
    	decision = FRand();

    	if ( !bool(NextAnim) || (decision < 0.85) )
    		NextAnim = 'Breath';
    	else
    		NextAnim = 'Look';

    	LoopAnim(NextAnim, animspeed, , 1.0);
    }

    function PlayChallenge()
    {
    	if ( FRand() < 0.1 )
    		PlayWaiting();
    	else
    		PlayAnim('Roar', 1.4);
    }

    function TweenToFighter(float tweentime)
    {
    	TweenAnim('Fighter', tweentime);
    }

    function PlayDying(name DamageType, vector HitLocation)
    {
    	local carcass carc;
    	local vector Dir;

    	PlaySound(Die, SLOT_Talk, 3.5 * TransientSoundVolume);

    	Dir = Normal(Acceleration);

    	if ( (Dir Dot Normal(HitLocation) >= 0.25) )
    	{
    		PlayAnim('DeathBack', 0.6, 0.1);
    	} else {
    		if ( AnimSequence == 'Run' )
    			PlayAnim('DeathRun', 0.6, 0.1);
    		else if ( AnimSequence == 'Jump' )
    			PlayAnim('DeathLeap', 0.6, 0.1);
    		else
    			if ( FRand() < 0.5 )
    				PlayAnim('DeathFront1', 0.6, 0.1);
    			else
    				PlayAnim('DeathFront2', 0.6, 0.1);
    	}
    }

    function PlayMeleeAttack()
    {
    	local float dist, decision;

      	PlaySound(Threaten, SLOT_Interact);

    	m_vectPushDir	= vect(0,0,0);
    	decision		= FRand();

    	if(decision < 0.4)
    	{
    		m_nameRestoreState	= GetStateName();
    		m_vectPushDir		= 30000 * (Normal(Target.Location - Location));
    		m_fAttackWait		= 0.2;
    		fAttackDamage		= HitDamage;
    		PlayAnim('AttackR', 1.4,0.1);
    		GotoState('Hitting');
    	} else if(decision < 0.6) {
    		m_nameRestoreState	= GetStateName();
    		m_vectPushDir		= 30000 * (Normal(Target.Location - Location));
    		m_fAttackWait		= 0.2;
    		fAttackDamage		= HitDamage;
    		PlayAnim('AttackL', 1.4,0.1);
    		GotoState('Hitting');
    	} else if(decision < 0.85) {
    		m_nameRestoreState	= GetStateName();
    		m_vectPushDir		= 40000 * (Normal(Target.Location - Location));
    		m_fAttackWait		= 0.35;
    		fAttackDamage		= HackDamage;
    		PlayAnim('Hack', 1.3,0.1);
    		GotoState('Hitting');
    	} else {
    		m_nameRestoreState	= GetStateName();
    		m_vectPushDir		= 25000 * (Normal(Target.Location - Location));
    		m_fAttackWait		= 0.21;
    		fAttackDamage		= SliceDamage;
    		PlayAnim('slice', 1.0,0.1);
    		GotoState('Hitting');
    	}
    }

    function PlayVictoryDance()
    {
    	PlayAnim(VictoryAnim, 0.7, 0.1);
    }

    //=============================================================================
    // Animation Callback Functions

    exec function Attack()
    {
    	Log("Callback for an SFReaver attack animation");
    }

    exec function Hit()
    {
    	Log("Callback for an SFReaver being attacked animation");
    }

    exec function Death()
    {
    	Log("Callback for an SFReaver death animation");
    }

    //=============================================================================
    // States

    auto state Waiting
    {
    Begin:
    	PlayWaiting();
    }

    state Charging
    {
    ignores SeePlayer, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state TakeHit
    {
    ignores seeplayer, hearnoise, bump, hitwall;

    	function BeginState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.BeginState();
    	}
    }

    state Retreating
    {
    ignores SeePlayer, EnemyNotVisible, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state TacticalMove
    {
    ignores SeePlayer, HearNoise;

    	function EndState()
    	{
    		bFire = 0;
    		bAltFire = 0;
    		Super.EndState();
    	}
    }

    state Hitting
    {
    Begin:
    	Sleep(m_fAttackWait);
    	MeleeDamageTarget(fMeleeDamage+fAttackDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    defaultproperties
    {
         hitdamage=15
         HackDamage=26
         SliceDamage=23
         WSpeed=-1.300000
         RSpeed=-2.550000
         SSpeed=-2.000000
         WalkSound=Sound'SFCharacter4.Reaver.ReaverSearching'
         WalkAnim=Walk
         RunAnim=Run
         ThreatenAnim=Roar
         TakeHitAnim=Hit
         VictoryAnim=Hack
         SmellRadius=3000.000000
         fMeleeDamage=17.000000
         fStunnedTime=3.500000
         bFightOtherCreatures=False
         CarcassType=Class'SFCharacter.SFSkavCarcass'
         TimeBetweenAttacks=0.000000
         Aggressiveness=1.000000
         Acquire=Sound'SFCharacter4.Reaver.ReaverAcquire'
         Fear=Sound'SFCharacter4.Reaver.ReaverAttack1'
         Roam=Sound'SFCharacter4.Reaver.ReaverSearching'
         Threaten=Sound'SFCharacter4.Reaver.ReaverAttack1'
         bCanStrafe=True
         MeleeRange=60.000000
         GroundSpeed=600.000000
         WaterSpeed=400.000000
         AccelRate=400.000000
         JumpZ=180.000000
         Visibility=80
         SightRadius=3000.000000
         Health=260
         SelectionMesh="SFCharacter4.SFReaver"
         Intelligence=BRAINS_HUMAN
         Skill=1.000000
         HitSound1=Sound'SFCharacter4.Reaver.ReaverPain01'
         HitSound2=Sound'SFCharacter4.Reaver.ReaverPain01'
         Die=Sound'UnrealShare.Brute.death1br'
         CombatStyle=1.000000
         DrawType=DT_Mesh
         Mesh=SkeletalMesh'SFCharacter4.SFReaver'
         DrawScale=0.780000
         ScaleGlow=0.350000
         CollisionRadius=44.000000
         CollisionHeight=39.000000
         Mass=90.000000
    }

class file time: 12/7/2003 3:58:26 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX