# SFCharacter.SFSkav

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 |
    //=============================================================================
    // Spatial Fear
    // Class: SFSkav
    // Description:  Big SF enemy. Will work in teams with a leader.
    //
    // Created by: Markus Nuebel
    //=============================================================================
    class SFSkav expands SFScriptedPawn;

    #exec OBJ LOAD FILE=SPF-Content.uax  PACKAGE=SPF-Content GROUP=Creatures

    //#exec AUDIO IMPORT FILE="Sounds\Skav\SkavAquisition.wav"	NAME=Aquisition PACKAGE=SFCharacter GROUP=Skav
    //#exec AUDIO IMPORT FILE="Sounds\Skav\SkavFear.wav"			NAME=Fear PACKAGE=SFCharacter GROUP=Skav
    //#exec AUDIO IMPORT FILE="Sounds\Skav\SkavSwipe.wav"			NAME=Roam PACKAGE=SFCharacter GROUP=Skav
    //#exec AUDIO IMPORT FILE="Sounds\Skav\SkavRoar1.wav"			NAME=Roar PACKAGE=SFCharacter GROUP=Skav

    #exec MESH IMPORT MESH=SFSkav ANIVFILE=MODELS\SFSkav_a.3d DATAFILE=MODELS\SFSkav_d.3d X=0 Y=0 Z=0
    #exec MESH ORIGIN MESH=SFSkav X=0 Y=0 Z=-90 YAW=64 ROLL=0 PITCH=0
    #exec MESH SCALE x=0.075 y=0.075 z=0.15

    #exec MESH SEQUENCE MESH=SFSkav SEQ=All STARTFRAME=0 NUMFRAMES=349

    //Wait Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Breath1 STARTFRAME=184 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Breath2 STARTFRAME=200 NUMFRAMES=10 RATE=10 Group=Waiting
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Breath3 STARTFRAME=270 NUMFRAMES=10 RATE=15 Group=Waiting
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Look STARTFRAME=23 NUMFRAMES=20 RATE=15 Group=Waiting
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Fighter STARTFRAME=1 NUMFRAMES=1

    //Movement Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Run STARTFRAME=44 NUMFRAMES=20 RATE=30
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Run2 STARTFRAME=309 NUMFRAMES=10 RATE=15
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Walk STARTFRAME=2 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Turn STARTFRAME=2 NUMFRAMES=2 RATE=15
    #exec MESH SEQUENCE MESH=SFSkav SEQ=StrafeL STARTFRAME=120 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFSkav SEQ=StrafeR STARTFRAME=100 NUMFRAMES=20 RATE=30 Group=MovingFire
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Jump STARTFRAME=306 NUMFRAMES=1 Group=Jumping // New Frame
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Land STARTFRAME=307 NUMFRAMES=1 Group=Landing // New Frame

    //Attack Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Attack STARTFRAME=140 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Kick STARTFRAME=160 NUMFRAMES=10 RATE=10
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Hack STARTFRAME=170 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Slap STARTFRAME=280 NUMFRAMES=16 RATE=15 // New animation
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Push STARTFRAME=296 NUMFRAMES=9 RATE=10 // New animation
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Swipe STARTFRAME=319 NUMFRAMES=15 RATE=10 // New animation
    #exec MESH SEQUENCE MESH=SFSkav SEQ=KickPunch STARTFRAME=334 NUMFRAMES=15 RATE=10 // New animation

    //Special Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Roar STARTFRAME=230 NUMFRAMES=20 RATE=20

    //Take Hit Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=HeadHit STARTFRAME=319 NUMFRAMES=1 Group=TakeHit // Changed Frame
    #exec MESH SEQUENCE MESH=SFSkav SEQ=GutHit STARTFRAME=74 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFSkav SEQ=LeftHit STARTFRAME=140 NUMFRAMES=1 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFSkav SEQ=RightHit STARTFRAME=158 NUMFRAMES=1 Group=TakeHit

    //Death Animations
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Dead1 STARTFRAME=64 NUMFRAMES=15 RATE=20 Group=TakeHit
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Dead2 STARTFRAME=210 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Dead3 STARTFRAME=79 NUMFRAMES=15 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Dead4 STARTFRAME=250 NUMFRAMES=20 RATE=20
    #exec MESH SEQUENCE MESH=SFSkav SEQ=Dead5 STARTFRAME=319 NUMFRAMES=10 RATE=10 // New animation

    //Body frames.  Used for corpses.
    #exec MESH SEQUENCE MESH=SFSkav SEQ=DeathEnd STARTFRAME=78 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFSkav SEQ=DeathEnd2 STARTFRAME=99 NUMFRAMES=1
    #exec MESH SEQUENCE MESH=SFSkav SEQ=DeathEnd3 STARTFRAME=229 NUMFRAMES=1

    #exec MESHMAP NEW MESHMAP=SFSkav MESH=SFSkav
    #exec MESHMAP SCALE MESHMAP=SFSkav X=0.1 Y=0.1 Z=0.2

    #exec TEXTURE IMPORT NAME=Skav1 FILE=Textures\SkavChest.pcx GROUP=Skins FLAGS=2
    #exec TEXTURE IMPORT NAME=Skav1 FILE=Textures\SkavChest.pcx GROUP=Skins PALETTE=Skav1
    #exec MESHMAP SETTEXTURE MESHMAP=SFSkav NUM=1 TEXTURE=Skav1

    #exec TEXTURE IMPORT NAME=Skav2 FILE=Textures\SkavFace.pcx GROUP=Skins FLAGS=2
    #exec TEXTURE IMPORT NAME=Skav2 FILE=Textures\SkavFace.pcx GROUP=Skins PALETTE=Skav2
    #exec MESHMAP SETTEXTURE MESHMAP=SFSkav NUM=2 TEXTURE=Skav2

    #exec TEXTURE IMPORT NAME=Skav3 FILE=Textures\SkavLegs.pcx GROUP=Skins FLAGS=2
    #exec TEXTURE IMPORT NAME=Skav3 FILE=Textures\SkavLegs.pcx GROUP=Skins PALETTE=Skav3
    #exec MESHMAP SETTEXTURE MESHMAP=SFSkav NUM=3 TEXTURE=Skav3

    #exec TEXTURE IMPORT NAME=Skav4 FILE=Textures\SkavButt.pcx GROUP=Skins FLAGS=2
    #exec TEXTURE IMPORT NAME=Skav4 FILE=Textures\SkavButt.pcx GROUP=Skins PALETTE=Skav4
    #exec MESHMAP SETTEXTURE MESHMAP=SFSkav NUM=4 TEXTURE=Skav4

    var(Sounds) sound Die2;
    var name m_nameRestoreState;
    var vector m_vectPushDir;

    function eAttitude AttitudeToCreature(Pawn Other)
    {

    	local float fDecision;

    	// Check the global attitude flag
    	if(!bFightOtherCreatures)
    		return ATTITUDE_IGNORE;

    	fDecision	= FRand();

    	if ( Other.IsA('SFSkav') )
    	{
    		if(fDecision < 0.04)
    			return ATTITUDE_Threaten;
    		else if ((fDecision < 0.05) && (!Other.IsA('SFSkavLeader')))
    			return ATTITUDE_Hate;
    		else
    			return ATTITUDE_Friendly;
    	}
    	else
    		if(ScriptedPawn(Other).Aggressiveness > Aggressiveness)
    			return ATTITUDE_Ignore;
    		else
    		{
    			if(FRand() < 0.04)
    				return ATTITUDE_Threaten;
    			else
    				return ATTITUDE_Ignore;
    		}
    }

    function TweenToStunned(float tweentime)
    {
    	TweenAnim('Fighter', tweentime);
    }

    function TweenToRunning(float tweentime)
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	if (bIsWalking)
    		TweenToWalking(0.1);
    	else
    		PlayAnim('Run', 1, tweentime);

    	if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    	{
    		// Strafing
    		if ( Dir Dot Y > 0 )
    			PlayAnim('StrafeR', 1.55, tweentime);
    		else
    			PlayAnim('StrafeL', 1.55, tweentime);
    	}
    }

    function PlayStunned()
    {
    	PlayAnim('Fighter');
    }

    function PlayWalking()
    {
    	PlaySound(WalkSound, SLOT_Interact);
    	LoopAnim(WalkAnim, -2.0f/GroundSpeed,0.1,0.4);
    }

    function PlayRunning()
    {
    	local vector X,Y,Z, Dir;

    	GetAxes(Rotation, X,Y,Z);
    	Dir = Normal(Acceleration);

    	PlaySound(RunSound, SLOT_Interact);

    	if(FRand() < 0.92)
    		LoopAnim('Run', -1.35f/GroundSpeed,0.1,0.4);
    	else
    		LoopAnim('Run2', -1.35f/GroundSpeed,0.1,0.4);

    	if ( (Dir Dot X < 0.75) && (Dir != vect(0,0,0)) )
    	{
    		// Strafing
    		if ( Dir Dot Y > 0 )
    			LoopAnim('StrafeR', -1.35f/GroundSpeed);
    		else
    			LoopAnim('StrafeL', -1.35f/GroundSpeed);
    	}

    }

    function TweenToWaiting(float tweentime)
    {
    	TweenAnim('Look', tweentime);
    }

    function PlayWaiting()
    {
    	local float decision;
    	local float animspeed;

    	animspeed = 0.1 + 0.6 * FRand();
    	decision = FRand();

    	if ( !bool(NextAnim) || (decision < 0.1) ) //pick first waiting animation
    		NextAnim = 'Breath1';
    	else if (decision < 0.2)
    		NextAnim = 'Breath2';
    	else if (decision < 0.4)
    		NextAnim = 'Breath3';
    	else if (decision < 0.95)
    		NextAnim = 'Look';
    	else
    	{
    		if ( !bQuiet )
    			PlaySound(Threaten, SLOT_Talk, 0.7,,800);
    		NextAnim	= 'Roar';
    		animspeed	*= 0.7;
    	}

    	LoopAnim(NextAnim, animspeed, , 0.4);

    }

    function PlayChallenge()
    {
    	if ( FRand() < 0.1 )
    		PlayWaiting();
    	else
    		PlayAnim('Roar');
    }

    function TweenToFighter(float tweentime)
    {
    	TweenAnim('Fighter', tweentime);
    }

    function PlayDying(name DamageType, vector HitLocation)
    {
    	local carcass carc;
    	local float	fDist;

    	if(FRand() <0.5)
    		PlaySound(Die, SLOT_Talk, 3.5 * TransientSoundVolume);
    	else
    		PlaySound(Die2, SLOT_Talk, 3.5 * TransientSoundVolume);

    	if ( FRand() < 0.10 )
    	{
    		PlayAnim('Dead5', 0.7, 0.1);
    		fDist = VSize(Target.Location - Location);
    		if (fDist < CollisionRadius + Target.CollisionRadius)
    			MeleeDamageTarget(fMeleeDamage, vect(0,0,0));
    	}
    	else if ( FRand() < 0.35 )
    		PlayAnim('Dead1', 0.7, 0.1);
    	else if ( FRand() < 0.5 )
    	{
    		carc = Spawn(class 'SFCreatureChunks',,, Location + CollisionHeight * vect(0,0,0.8), Rotation + rot(3000,0,16384) );
    		if (carc != None)
    		{
    			carc.Mesh = mesh'SkavHead';
    			carc.Initfor(self);
    			carc.Velocity = Velocity + VSize(Velocity) * VRand();
    			carc.Velocity.Z = FMax(carc.Velocity.Z, Velocity.Z);
    		}
    		PlayAnim('Dead2', 0.7, 0.1);
    	}
    	else if ( FRand() < 0.7 )
    		PlayAnim('Dead3', 0.7, 0.1);
    	else
    	{
    		carc = Spawn(class 'SFCreatureChunks',,, Location + CollisionHeight * vect(0,0,0.8), Rotation + rot(3000,0,16384) );
    		if (carc != None)
    		{
    			carc.Mesh = mesh'SkavArm';
    			carc.Initfor(self);
    			carc.Velocity = Velocity + VSize(Velocity) * VRand();
    			carc.Velocity.Z = FMax(carc.Velocity.Z, Velocity.Z);
    		}
    		PlayAnim('Dead4', 0.7, 0.1);
    	}
    }

    function PlayMeleeAttack()
    {
    	local float dist, decision;

    	m_vectPushDir	= vect(0,0,0);
    	decision		= FRand();
    	dist = VSize(Target.Location - Location);
    	if (dist > CollisionRadius + Target.CollisionRadius + 45)
    		decision = 0.0;

    	if (Physics == PHYS_Falling)
    		decision = 1.0;
    	if (Target == None)
    		decision = 1.0;

    	if(FRand() < 0.9)
      		PlaySound(Threaten, SLOT_Interact);
    	else
      		PlaySound(Roam, SLOT_Interact);

    	if(decision < 0.4)
    	{
    		PlayAnim('Attack', 1.1,0.1);
    		m_vectPushDir	= 8000 * (Normal(Target.Location - Location));
    		MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	}
    	else if(decision < 0.5)
    	{
    		// Save the current state name
    		m_nameRestoreState	= GetStateName();
    		// Calculate momentum for this attack
    		m_vectPushDir		= 60000 * (Normal(Target.Location - Location));
    		// Play the animation
    		PlayAnim('Kick', 1.9,0.1);
    		// Switch to delaying state
    		GotoState('Kicking');
    	}
    	else if(decision < 0.7)
    	{
    		// Save the current state name
    		m_nameRestoreState	= GetStateName();
    		// Calculate momentum for this attack
    		m_vectPushDir	= 5000 * (Normal(Target.Location - Location));
    		// Play the animation
    		PlayAnim('Hack', 1.3,0.1);
    		// Switch to delaying state
    		GotoState('Hacking');
    	}
    	else if(decision < 0.75)
    	{
    		PlayAnim('Slap', 1.2,0.1);
    		m_vectPushDir	= 5000 * (Normal(Target.Location - Location));
    		MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	}
    	else if(decision < 0.95)
    	{
    		// Save the current state name
    		m_nameRestoreState	= GetStateName();
    		// Calculate momentum for this attack
    		m_vectPushDir	= 21000 * (Normal(Target.Location - Location));
    		// Play the animation
    		PlayAnim('Push', 1.1,0.1);
    		// Switch to delaying state
    		GotoState('Pushing');
    	}
    	else if(decision < 0.97)
    	{
    		// Save the current state name
    		m_nameRestoreState	= GetStateName();
    		// Calculate momentum for this attack
    		m_vectPushDir	= 31000 * (Normal(Target.Location - Location));
    		// Play the animation
    		PlayAnim('Swipe', 1.2,0.1);
    		// Switch to delaying state
    		GotoState('Swiping');
    	}
    	else
    	{
    		// Save the current state name
    		m_nameRestoreState	= GetStateName();
    		// Calculate momentum for this attack
    		m_vectPushDir	= 51000 * (Normal(Target.Location - Location));
    		// Play the animation
    		PlayAnim('KickPunch', 1.2,0.1);
    		// Switch to delaying state
    		GotoState('KickPunching');
    	}
    }

    // State used to delay the MeleeDamageTarget
    // until part of the kicking animation has been played
    state Kicking
    {
    Begin:
    	Sleep(0.2);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    // State used to delay the MeleeDamageTarget
    // until part of the hacking animation has been played
    state Hacking
    {
    Begin:
    	Sleep(0.4);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    // State used to delay the MeleeDamageTarget
    // until part of the push animation has been played
    state Pushing
    {
    Begin:
    	Sleep(0.5);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    // State used to delay the MeleeDamageTarget
    // until part of the swipe animation has been played
    state Swiping
    {
    Begin:
    	Sleep(0.5);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    // State used to delay the MeleeDamageTarget
    // until part of the KickPunch animation has been played
    state KickPunching
    {
    Begin:
    	Sleep(0.5);
    	MeleeDamageTarget(fMeleeDamage, m_vectPushDir);
    	GotoState(m_nameRestoreState);
    }

    //	Threaten=Sound'UnrealShare.Brute.yell2br'
    //	Acquire=Sound'UnrealShare.Brute.yell1br'
    //	Fear=Sound'UnrealShare.Brute.injur2br'
    //	Roam=Sound'UnrealShare.Brute.nearby2br'

    defaultproperties
    {
         Die2=Sound'UnrealShare.Brute.death2br'
         WalkSound=Sound'UnrealShare.Brute.walk1br'
         WalkAnim=Walk
         RunSound=Sound'UnrealShare.Brute.walk2br'
         RunAnim=Run
         ThreatenAnim=Roar
         TakeHitAnim=GutHit
         VictoryAnim=Roar
         SmellRadius=2700.000000
         fMeleeDamage=22.000000
         fStunnedTime=4.000000
         CarcassType=Class'SFCharacter.SFSkavCarcass'
         TimeBetweenAttacks=0.900000
         Aggressiveness=1.000000
         Acquire=Sound'SPF-Content.Creatures.SkavAquisition'
         Fear=Sound'SPF-Content.Creatures.SkavFear'
         Roam=Sound'SPF-Content.Creatures.SkavSwipe'
         Threaten=Sound'SPF-Content.Creatures.SkavRoar'
         bCanStrafe=True
         bCanJump=True
         MeleeRange=50.000000
         GroundSpeed=300.000000
         WaterSpeed=100.000000
         AccelRate=900.000000
         JumpZ=140.000000
         Visibility=120
         SightRadius=2600.000000
         Health=250
         Intelligence=BRAINS_HUMAN
         HitSound1=Sound'UnrealShare.Brute.injur1br'
         HitSound2=Sound'UnrealShare.Brute.injur2br'
         Die=Sound'UnrealShare.Brute.death1br'
         CombatStyle=1.000000
         DrawType=DT_Mesh
         Mesh=LodMesh'SFCharacter.SFSkav'
         ScaleGlow=0.150000
         CollisionRadius=43.000000
         CollisionHeight=46.000000
    }

class file time: 12/7/2003 3:58:26 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX