# SpatialFear.SFScriptedPawn

00001 00002 00003 00004 00005 00006 00007 00008 00009 00010 00011 00012 00013 00014 00015 00016 00017 00018 00019 00020 00021 00022 00023 00024 00025 00026 00027 00028 00029 00030 00031 00032 00033 00034 00035 00036 00037 00038 00039 00040 00041 00042 00043 00044 00045 00046 00047 00048 00049 00050 00051 00052 00053 00054 00055 00056 00057 00058 00059 00060 00061 00062 00063 00064 00065 00066 00067 00068 00069 00070 00071 00072 00073 00074 00075 00076 00077 00078 00079 00080 00081 00082 00083 00084 00085 00086 00087 00088 00089 00090 00091 00092 00093 00094 00095 00096 00097 00098 00099 00100 00101 00102 00103 00104 00105 00106 00107 00108 00109 00110 00111 00112 00113 00114 00115 00116 00117 00118 00119 00120 00121 00122 00123 00124 00125 00126 00127 00128 00129 00130 00131 00132 00133 00134 00135 00136 00137 00138 00139 00140 00141 00142 00143 00144 00145 00146 00147 00148 00149 00150 00151 00152 00153 00154 00155 00156 00157 00158 00159 00160 00161 00162 00163 00164 00165 00166 00167 00168 00169 00170 00171 00172 00173 00174 00175 00176 00177 00178 00179 00180 00181 00182 00183 00184 00185 00186 00187 00188 00189 00190 00191 00192 00193 00194 00195 00196 00197 00198 00199 00200 00201 00202 00203 00204 00205 00206 00207 00208 00209 00210 00211 00212 00213 00214 00215 00216 00217 00218 00219 00220 00221 00222 00223 00224 00225 00226 00227 00228 00229 00230 00231 00232 00233 00234 00235 00236 00237 00238 00239 00240 00241 00242 00243 00244 00245 00246 00247 00248 00249 00250 00251 00252 00253 00254 00255 00256 00257 00258 00259 00260 00261 00262 00263 00264 00265 00266 00267 00268 00269 00270 00271 00272 00273 00274 00275 00276 00277 00278 00279 00280 00281 00282 00283 00284 00285 00286 00287 00288 00289 00290 00291 00292 00293 00294 00295 00296 00297 00298 00299 00300 00301 00302 00303 00304 00305 00306 00307 00308 00309 00310 00311 00312 00313 00314 00315 00316 00317 00318 00319 00320 00321 00322 00323 00324 00325 00326 00327 00328 00329 00330 00331 00332 00333 00334 00335 00336 00337 00338 00339 00340 00341 00342 00343 00344 00345 00346 00347 00348 00349 00350 00351 00352 00353 00354 00355 00356 00357 00358 00359 00360 00361 00362 00363 00364 00365 00366 00367 00368 00369 00370 00371 00372 00373 00374 00375 00376 00377 00378 00379 00380 00381 00382 00383 00384 00385 00386 00387 00388 00389 00390 00391 00392 00393 00394 00395 00396 00397 00398 00399 00400 00401 00402 00403 00404 00405 00406 00407 00408 00409 00410 00411 00412 00413 00414 00415 00416 00417 00418 00419 00420 00421 00422 00423 00424 00425 00426 00427 00428 00429 00430 00431 00432 00433 00434 00435 00436 00437 00438 00439 00440 00441 00442 00443 00444 00445 00446 00447 00448 00449 00450 00451 00452 00453 00454 00455 00456 00457 00458 00459 00460 00461 00462 00463 00464 00465 00466 00467 00468 00469 00470 00471 00472 00473 00474 00475 00476 00477 00478 00479 00480 00481 00482 00483 00484 00485 00486 00487 00488 00489 00490 00491 00492 00493 00494 00495 00496 00497 00498 00499 00500 00501 00502 00503 00504 00505 00506 00507 00508 00509 00510 00511 00512 00513 00514 00515 00516 00517 00518 00519 00520 00521 00522 00523 00524 00525 00526 00527 00528 00529 00530 00531 00532 00533 00534 00535 00536 00537 00538 00539 00540 00541 00542 00543 00544 00545 00546 00547 00548 00549 00550 00551 00552 00553 00554 00555 00556 00557 00558 00559 00560 00561 00562 00563 00564 00565 00566 00567 00568 00569 00570 00571 00572 00573 00574 00575 00576 00577 00578 00579 00580 00581 00582 00583 00584 00585 00586 00587 00588 00589 00590 00591 00592 00593 00594 00595 00596 00597 00598 00599 00600 00601 00602 00603 00604 00605 00606 00607 00608 00609 00610 00611 00612 00613 00614 00615 00616 00617 00618 00619 00620 00621 00622 00623 00624 00625 00626 00627 00628 00629 00630 00631 00632 00633 00634 00635 00636 00637 00638 00639 00640 00641 00642 00643 00644 00645 00646 00647 00648 00649 00650 00651 00652 00653 00654 00655 00656 00657 00658 00659 00660 00661 00662 00663 00664 00665 00666 00667 00668 00669 00670 00671 00672 00673 00674 00675 00676 00677 00678 00679 00680 00681 00682 00683 00684 00685 00686 00687 00688 00689 00690 00691 00692 00693 00694 00695 00696 00697 00698 00699 00700 00701 00702 00703 00704 00705 00706 00707 00708 00709 00710 00711 00712 00713 00714 00715 00716 00717 00718 00719 00720 00721 00722 00723 00724 00725 00726 00727 00728 00729 00730 00731 00732 00733 00734 00735 00736 00737 00738 00739 00740 00741 00742 00743 00744 00745 00746 00747 00748 00749 00750 00751 00752 00753 00754 00755 00756 00757 00758 00759 00760 00761 00762 00763 00764 00765 00766 00767 00768 00769 00770 00771 00772 00773 00774 00775 00776 00777 00778 00779 00780 00781 00782 00783 00784 00785 00786 00787 00788 00789 00790 00791 00792 00793 00794 00795 00796 00797 00798 00799 00800 00801 00802 00803 00804 00805 00806 00807 00808 00809 00810 00811 00812 00813 00814 00815 00816 00817 00818 00819 00820 00821 00822 00823 00824 00825 00826 00827 00828 00829 00830 00831 00832 00833 00834 00835 00836 00837 00838 00839 00840 00841 00842 00843 00844 00845 00846 00847 00848 00849 00850 00851 00852 00853 00854 00855 00856 00857 00858 00859 00860 00861 00862 00863 00864 00865 00866 00867 00868 00869 00870 00871 00872 00873 00874 00875 00876 00877 00878 00879 00880 00881 00882 00883 00884 00885 00886 00887 00888 00889 00890 00891 00892 00893 00894 00895 00896 00897 00898 00899 00900 00901 00902 00903 00904 00905 00906 00907 00908 00909 00910 00911 00912 00913 00914 00915 00916 00917 00918 00919 00920 00921 00922 00923 00924 00925 00926 00927 00928 00929 00930 00931 00932 00933 00934 00935 00936 00937 00938 00939 00940 00941 00942 00943 00944 00945 00946 00947 00948 00949 00950 00951 00952 00953 00954 00955 00956 00957 00958 00959 00960 00961 00962 00963 00964 00965 00966 00967 00968 00969 00970 00971 00972 00973 00974 00975 00976 00977 00978 00979 00980 00981 00982 00983 00984 00985 00986 00987 00988 00989 00990 00991 00992 00993 00994 00995 00996 00997 00998 00999 01000 01001 01002 01003 01004 01005 01006 01007 01008 01009 01010 01011 01012 01013 01014 01015 01016 01017 01018 01019 01020 01021 01022 01023 01024 01025 01026 01027 01028 01029 01030 01031 01032 01033 01034 01035 01036 01037 01038 01039 01040 01041 01042 01043 01044 01045 01046 01047 01048 01049 01050 01051 01052 01053 01054 01055 01056 01057 01058 01059 01060 01061 01062 01063 01064 01065 01066 01067 01068 01069 01070 01071 01072 01073 01074 01075 01076 01077 01078 01079 01080 01081 01082 01083 01084 01085 01086 01087 01088 01089 01090 01091 01092 01093 01094 01095 01096 01097 01098 01099 01100 01101 01102 01103 01104 01105 01106 01107 01108 01109 01110 01111 01112 01113 01114 01115 01116 01117 01118 01119 01120 01121 01122 01123 01124 01125 01126 01127 01128 01129 01130 01131 01132 01133 01134 01135 01136 01137 01138 01139 01140 01141 01142 01143 01144 01145 01146 01147 01148 01149 01150 01151 01152 01153 01154 01155 01156 01157 01158 01159 01160 01161 01162 01163 01164 01165 01166 01167 01168 01169 01170 01171 01172 01173 01174 01175 01176 01177 01178 01179 01180 01181 01182 01183 01184 01185 01186 01187 01188 01189 01190 01191 01192 01193 01194 01195 01196 01197 01198 01199 01200 01201 01202 01203 01204 01205 01206 01207 01208 01209 01210 01211 01212 01213 01214 01215 01216 01217 01218 01219 01220 01221 01222 01223 01224 01225 01226 01227 01228 01229 01230 01231 01232 01233 01234 01235 01236 01237 01238 01239 01240 01241 01242 01243 01244 01245 01246 01247 01248 01249 01250 01251 01252 01253 01254 01255 01256 01257 01258 01259 01260 01261 01262 01263 01264 01265 01266 01267 01268 01269 01270 01271 01272 01273 01274 01275 01276 01277 01278 01279 01280 01281 01282 01283 01284 01285 01286 01287 01288 01289 01290 01291 01292 01293 01294 01295 01296 01297 01298 01299 01300 01301 01302 01303 01304 01305 01306 01307 01308 01309 01310 01311 01312 01313 01314 01315 01316 01317 01318 01319 01320 01321 01322 01323 01324 01325 01326 01327 01328 01329 01330 01331 01332 01333 01334 01335 01336 01337 01338 01339 01340 01341 01342 01343 01344 01345 01346 01347 01348 01349 01350 01351 01352 01353 01354 01355 01356 01357 01358 01359 01360 01361 01362 01363 01364 01365 01366 01367 01368 01369 01370 01371 01372 01373 01374 01375 01376 01377 01378 01379 01380 01381 01382 01383 01384 01385 01386 01387 01388 01389 01390 01391 01392 01393 01394 01395 01396 01397 01398 01399 01400 01401 01402 01403 01404 01405 01406 01407 01408 01409 01410 01411 01412 01413 01414 01415 01416 01417 01418 01419 01420 01421 01422 01423 01424 01425 01426 01427 01428 01429 01430 01431 01432 01433 01434 01435 01436 01437 01438 01439 01440 01441 01442 01443 01444 01445 01446 01447 01448 01449 01450 01451 01452 01453 01454 01455 01456 01457 01458 01459 01460 01461 01462 01463 01464 01465 01466 01467 01468 01469 01470 01471 01472 01473 01474 01475 01476 01477 01478 01479 01480 01481 01482 01483 01484 01485 01486 01487 01488 01489 01490 01491 01492 01493 01494 01495 01496 01497 01498 01499 01500 01501 01502 01503 01504 01505 01506 01507 01508 01509 01510 01511 01512 01513 01514 01515 01516 01517 01518 01519 01520 01521 01522 01523 01524 01525 01526 01527 01528 01529 01530 01531 01532 01533 01534 01535 01536 01537 01538 01539 01540 01541 01542 01543 01544 01545 01546 01547 01548 01549 01550 01551 01552 01553 01554 01555 01556 01557 01558 01559 01560 01561 01562 01563 01564 01565 01566 01567 01568 01569 01570 01571 01572 01573 01574 01575 01576 01577 01578 01579 01580 01581 01582 01583 01584 01585 01586 01587 01588 01589 01590 01591 01592 01593 01594 01595 01596 01597 01598 01599 01600 01601 01602 01603 01604 01605 01606 01607 01608 01609 01610 01611 01612 01613 01614 01615 01616 01617 01618 01619 01620 01621 01622 01623 01624 01625 01626 01627 01628 01629 01630 01631 01632 01633 01634 01635 01636 01637 01638 01639 01640 01641 01642 01643 01644 01645 01646 01647 01648 01649 01650 01651 01652 01653 01654 01655 01656 01657 01658 01659 01660 01661 01662 01663 01664 01665 01666 01667 01668 01669 01670 01671 01672 01673 01674 01675 01676 01677 01678 01679 01680 01681 01682 01683 01684 01685 01686 01687 01688 01689 01690 01691 01692 01693 01694 01695 01696 01697 01698 01699 01700 01701 01702 01703 01704 01705 01706 01707 01708 01709 01710 01711 01712 01713 01714 01715 01716 01717 01718 01719 01720 01721 01722 01723 01724 01725 01726 01727 01728 01729 01730 01731 01732 01733 01734 01735 01736 01737 01738 01739 01740 01741 01742 01743 01744 01745 01746 01747 01748 01749 01750 01751 01752 01753 01754 01755 01756 01757 01758 01759 01760 01761 01762 01763 01764 01765 01766 01767 01768 01769 01770 01771 01772 01773 01774 01775 01776 01777 01778 01779 01780 01781 01782 01783 01784 01785 01786 01787 01788 01789 01790 01791 01792 01793 01794 01795 01796 01797 01798 01799 01800 01801 01802 01803 01804 01805 01806 01807 01808 01809 01810 01811 01812 01813 01814 01815 01816 01817 01818 01819 01820 01821 01822 01823 01824 01825 01826 01827 01828 01829 01830 01831 01832 01833 01834 01835 01836 01837 01838 01839 01840 01841 01842 01843 01844 01845 01846 01847 01848 01849 01850 01851 01852 01853 01854 01855 01856 01857 01858 01859 01860 01861 01862 01863 01864 01865 01866 01867 01868 01869 01870 01871 01872 01873 01874 01875 01876 01877 01878 01879 01880 01881 01882 01883 01884 01885 01886 01887 01888 01889 01890 01891 01892 01893 01894 01895 01896 01897 01898 01899 01900 01901 01902 01903 01904 01905 01906 01907 01908 01909 01910 01911 01912 01913 01914 01915 01916 01917 01918 01919 01920 01921 01922 01923 01924 01925 01926 01927 01928 01929 01930 01931 01932 01933 01934 01935 01936 01937 01938 01939 01940 01941 01942 01943 01944 01945 01946 01947 01948 01949 01950 01951 01952 01953 01954 01955 01956 01957 01958 01959 01960 01961 01962 01963 01964 01965 01966 01967 01968 01969 01970 01971 01972 01973 01974 01975 01976 01977 01978 01979 01980 01981 01982 01983 01984 01985 01986 01987 01988 01989 01990 01991 01992 01993 01994 01995 01996 01997 01998 01999 02000 02001 02002 02003 02004 02005 02006 02007 02008 02009 02010 02011 02012 02013 02014 02015 02016 02017 02018 02019 02020 02021 02022 02023 02024 02025 02026 02027 02028 02029 02030 02031 02032 02033 02034 02035 02036 02037 02038 02039 02040 02041 02042 02043 02044 02045 02046 02047 02048 |
    //=============================================================================
    // Spatial Fear
    // Name: SFScriptedPawn
    // Description: Spatial Fear implementation of base scripted pawn functionality.
    //
    // Author: Markus Nuebel
    //=============================================================================
    class SFScriptedPawn extends ScriptedPawn
    	abstract;

    #exec obj load file=k_GorillaTex.utx package=k_GorillaTex

    var (SpatialFear) Sound	WalkSound; // Sound played during walking animation
    var (SpatialFear) name WalkAnim; // Walking animation
    var (SpatialFear) Sound	RunSound; // Sound played during running animation
    var (SpatialFear) name RunAnim; // Running animation
    var (SpatialFear) name ThreatenAnim; // Threaten animation
    var (SpatialFear) name TakeHitAnim; // Take a hit animation
    var (SpatialFear) name VictoryAnim; // victory dance animation
    var (SpatialFear) float SmellRadius; // smell range in UUs
    var (SpatialFear) float fMeleeDamage; // Damage applied during a melee attack
    var (SpatialFear) bool 	bCanHear;	// Can this creature hear? Or is it dumb.
    var (SpatialFear) bool	bCanSee;	// Can this creature see? Or is it blind.
    var (SpatialFear) bool	bCanSmell;	// Can this creature smell?
    var (SpatialFear) float fHealingTimer; // If this is a positive value, a hurt creature will restore one point of health every 'fHealingTimer' seconds. This is limited by the default health value of the creature. Default: 30 (SF creatures are challenging)
    var (SpatialFear) bool	bRandomSenses; // If this is checked, the sense settings (bCanHear, bCanSee, bCanSmell) are randomly defined at startup. Default: false
    var (SpatialFear) class<weapon> WeaponType; // Type of weapon this pawn can carry
    var (SpatialFear) float fStunnedTime; // Time this pawn is stunned by a "stunned effect" weapon, e.g. HardWave in average.
    var (SpatialFear) bool bFightOtherCreatures; // Determines if the pawn will fight other creatures. Default: true;
    var	Weapon myWeapon;	// The carried weapon
    var int		m_nStunnedRound; // Private: Number of times this pawn has been continuously set to stunned.

    var bool	m_bStunned;		// Private: Inicates a switch to the stunned state.
    var float	m_fSmellCounter; // Private: Counter for smell tracking
    var float	m_fSmellImportance; // Importance value of last smelled particle
    var int		m_nTacticalCounter; // To prent a long running loop of Retreating/TacticalMove/Attacking during retreat with no homebase
    var vector	m_vecSmellLocation; // Location of last smelled particle
    var SFStunnedEffect m_oStunnedEffect; // Effect displayed during stunned state
    var rotator	m_rotSavedRot; // Saved view rotation for stunned state
    var float	m_fStunnedCounter;
    // logging
    var name	m_nameStateSaved;
    var name	m_NextStateSaved;
    var name	m_NextLavelSaved;

    /////////////////////// Testing stuff, can be removed //////////////////////////

    function eAttitude AttitudeTo(Pawn Other)
    {
    //log(Self.name $ ": AttitudeTo: " $ Other.name $ " called from: " $ GetStateName());
    	if (Other.bIsPlayer)
    	{
    		if ( bIsPlayer && Level.Game.IsA('TeamGame') && (Team == Other.PlayerReplicationInfo.Team) )
    			return ATTITUDE_Friendly;
    		else if ( (Intelligence > BRAINS_None) &&
    			((AttitudeToPlayer == ATTITUDE_Hate) || (AttitudeToPlayer == ATTITUDE_Threaten)
    				|| (AttitudeToPlayer == ATTITUDE_Fear)) ) //check if afraid
    		{
    			if (RelativeStrength(Other) > Aggressiveness)
    			{
    				AttitudeToPlayer = AttitudeWithFear();
    //log(Self.name $ ": MUST Fear: AttitudeToPlayer " $ AttitudeToPlayer );
    			}
    			else if (AttitudeToPlayer == ATTITUDE_Fear)
    			{
    				AttitudeToPlayer = ATTITUDE_Hate;
    //log(Self.name $ ": MUST Hate: AttitudeToPlayer " $ AttitudeToPlayer );
    			}
    		}
    		return AttitudeToPlayer;
    	}
    	else if (Hated == Other)
    	{
    //log("Other is HATED scripted pawn");
    		if (RelativeStrength(Other) >= Aggressiveness)
    		{
    //log(Self.name $ ": MUST Fear: AttitudeToHated " $ AttitudeWithFear());
    			return AttitudeWithFear();
    		}
    		else
    		{
    //log(Self.name $ ": MUST Hate: AttitudeToHated ATTITUDE_Hate");
    			return ATTITUDE_Hate;
    		}
    	}
    	else if ( (TeamTag != '') && (ScriptedPawn(Other) != None) && (TeamTag == ScriptedPawn(Other).TeamTag) )
    		return ATTITUDE_Friendly;
    	else
    	{
    //log(Self.name $ ": MUST Hate: AttitudeToCreature " $ AttitudeToCreature(Other));
    		return AttitudeToCreature(Other);
    	}
    }

    ////////////////////////////////////////////////////////////////////////////////
    ////////////////////////////////////////////////////////////////////////////////

    function eAttitude AttitudeToCreature(Pawn Other)
    {
    	if(!bFightOtherCreatures)
    		return ATTITUDE_IGNORE;
    	else
    		return Super.AttitudeToCreature(Other);
    }

    function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation,
    						Vector momentum, name damageType)
    {
    	local int actualDamage;
    	local bool bAlreadyDead;
    	// Call to base class
    	Super.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);

    	if('SFstunned' == damageType)
    	{
    		m_bStunned=true;
    		NextState='Stunned';
    	}

    }

    function PostBeginPlay()
    {
    	if(bRandomSenses)
    	{
    		if(FRand() > 0.5f)
    			bCanHear = true;
    		else
    			bCanHear = false;
    		if(FRand() > 0.5f)
    			bCanSee = true;
    		else
    			bCanSee = false;
    		if(FRand() > 0.5f)
    			bCanSmell = true;
    		else
    			bCanSmell = false;
    	}
    }
    // Calculates the current hurt rate
    function float getHurtRate()
    {
    	return 1.0f - float(Health)/float(Default.Health);
    }

    // Overwritten, make pawns fear, even if there is no homebase.
    function eAttitude AttitudeWithFear()
    {
    	local vector HitLocation, HitNormal;
    	local actor HitActor;

    	if ( Homebase(home) == None )
    	{
    		CombatStyle -= 1.0;
    		// We are fearing
    		return ATTITUDE_Fear;
    	}
    	else if ( VSize(home.Location - Location) < Homebase(home).extent )
    	{
    		HitActor =  Trace( HitLocation, HitNormal, home.Location, Location, false);
    		if (HitActor == None)
    			return ATTITUDE_Hate;
    	}

    	return ATTITUDE_Fear;
    }

    // Handles new stimuli and hear/smell/see logic
    function bool ChooseTeamAttackFor(ScriptedPawn TeamMember)
    {
    	if ( (Enemy == None) && (TeamMember.Enemy != None) && LineOfSightTo(TeamMember) && bCanSee)
    	{
    		if (SetEnemy(TeamMember.Enemy))
    			MakeNoise(1.0);
    	}

    	// speak order
    	if ( !bTeamSpeaking )
    		SpeakOrderTo(TeamMember);

    	// set CombatStyle and Aggressiveness of TeamMember
    	if ( TeamMember == Self )
    	{
    		ChooseLeaderAttack();
    		return true;
    	}

    	if ( TeamMember.bReadyToAttack )
    	{
    		////class'SFUtils'.static.sfLogEx(5,"Attack!");
    		TeamMember.Target = TeamMember.Enemy;
    		If (VSize(Enemy.Location - Location) <= (TeamMember.MeleeRange + TeamMember.Enemy.CollisionRadius + TeamMember.CollisionRadius))
    		{
    			TeamMember.GotoState('MeleeAttack');
    			return true;
    		}
    		else if (TeamMember.bMovingRangedAttack || (TeamMember.TeamID == 1) )
    			TeamMember.SetTimer(TimeBetweenAttacks, False);
    		else if (TeamMember.bHasRangedAttack && (TeamMember.bIsPlayer || TeamMember.Enemy.bIsPlayer) && TeamMember.CanFireAtEnemy() )
    		{
    			if ( !TeamMember.bIsPlayer || (3 * FRand() > Skill) )
    			{
    				TeamMember.GotoState('RangedAttack');
    				return true;
    			}
    		}
    	}

    	if ( !TeamMember.bHasRangedAttack || (TeamMember.TeamID == 1) )
    		TeamMember.GotoState('Charging');
    	else if ( TeamMember.TeamID == 2 )
    	{
    		TeamMember.bStrafeDir = true;
    		TeamMember.GotoState('TacticalMove', 'NoCharge');
    	}
    	else if ( TeamMember.TeamID == 3 )
    	{
    		TeamMember.bStrafeDir = false;
    		TeamMember.GotoState('TacticalMove', 'NoCharge');
    	}
    	else
    		TeamMember.GotoState('TacticalMove');

    	return true;
    }

    // Handles new stimuli and hear/smell/see logic
    function bool SetEnemy( Pawn NewEnemy )
    {
    	local bool result;
    	local eAttitude newAttitude, oldAttitude;
    	local bool noOldEnemy;
    	local float newStrength;

    //log( Self.name $ ": SetEnemy called from " $ GetStateName());

    	if ( !bCanWalk && !bCanFly && !NewEnemy.FootRegion.Zone.bWaterZone )
    		return false;
    	if ( (NewEnemy == Self) || (NewEnemy == None) || (NewEnemy.Health <= 0) )
    		return false;
    	if ( (PlayerPawn(NewEnemy) == None) && (ScriptedPawn(NewEnemy) == None) )
    		return false;

    	noOldEnemy = (Enemy == None);
    	result = false;
    	newAttitude = AttitudeTo(NewEnemy);
    	// log ("Attitude to potential enemy is "$newAttitude);
    	if ( !noOldEnemy )
    	{
    		if (Enemy == NewEnemy)
    			return true;
    		else if ( NewEnemy.bIsPlayer && (AlarmTag != '') )
    		{
    			OldEnemy = Enemy;
    			Enemy = NewEnemy;
    			result = true;
    		}
    		else if ( newAttitude == ATTITUDE_Friendly )
    		{
    			if ( bIgnoreFriends )
    				return false;
    			if ( (NewEnemy.Enemy != None) && (NewEnemy.Enemy.Health > 0) )
    			{
    				if ( NewEnemy.Enemy.bIsPlayer && (NewEnemy.AttitudeToPlayer < AttitudeToPlayer) )
    					AttitudeToPlayer = NewEnemy.AttitudeToPlayer;
    				if ( AttitudeTo(NewEnemy.Enemy) < AttitudeTo(Enemy) )
    				{
    					OldEnemy = Enemy;
    					Enemy = NewEnemy.Enemy;
    					result = true;
    				}
    			}
    		}
    		else
    		{
    			oldAttitude = AttitudeTo(Enemy);
    			if ( (newAttitude < oldAttitude) ||
    				( (newAttitude == oldAttitude)
    					&& ((VSize(NewEnemy.Location - Location) < VSize(Enemy.Location - Location))
    						|| !LineOfSightTo(Enemy) || !bCanSee) ) )
    			{
    				if ( bIsPlayer && Enemy.IsA('PlayerPawn') && !NewEnemy.IsA('PlayerPawn') )
    				{
    					newStrength = relativeStrength(NewEnemy);
    					if ( (newStrength < 0.2) && (relativeStrength(Enemy) < FMin(0, newStrength))
    						&& (IsInState('Hunting')) && (Level.TimeSeconds - HuntStartTime < 5) )
    						result = false;
    					else
    					{
    						result = true;
    						OldEnemy = Enemy;
    						Enemy = NewEnemy;
    					}
    				}
    				else
    				{
    					result = true;
    					OldEnemy = Enemy;
    					Enemy = NewEnemy;
    				}
    			}
    		}
    	}
    	else if ( newAttitude < ATTITUDE_Ignore )
    	{
    		result = true;
    		Enemy = NewEnemy;
    	}
    	else if ( newAttitude == ATTITUDE_Friendly ) //your enemy is my enemy
    	{
    		//log("noticed a friend");
    		if ( NewEnemy.bIsPlayer && (AlarmTag != '') )
    		{
    			Enemy = NewEnemy;
    			result = true;
    		}
    		if (bIgnoreFriends)
    			return false;

    		if ( (NewEnemy.Enemy != None) && (NewEnemy.Enemy.Health > 0) )
    		{
    			result = true;
    			//log("his enemy is my enemy");
    			Enemy = NewEnemy.Enemy;
    			if (Enemy.bIsPlayer)
    				AttitudeToPlayer = ScriptedPawn(NewEnemy).AttitudeToPlayer;
    			else if ( (ScriptedPawn(NewEnemy) != None) && (ScriptedPawn(NewEnemy).Hated == Enemy) )
    				Hated = Enemy;
    		}
    	}

    	if ( result )
    	{
    		//log(class$" has new enemy - "$enemy.class);
    		LastSeenPos = Enemy.Location;
    		LastSeeingPos = Location;
    		EnemyAcquired();
    		if ( !bFirstHatePlayer && Enemy.bIsPlayer && (FirstHatePlayerEvent != '') )
    			TriggerFirstHate();
    	}
    	else if ( NewEnemy.bIsPlayer && (NewAttitude < ATTITUDE_Threaten) )
    		OldEnemy = NewEnemy;

    	return result;
    }

    // Overwritten to add our own fear handling
    function damageAttitudeTo(pawn Other)
    {
    	local eAttitude OldAttitude;
    	local float fTakenDamage;	// Percentage

    	// Early out
    	if ( (Other == Self) || (Other == None) || (FlockPawn(Other) != None) )
    		return;

    	// Some inits
    	fTakenDamage	= 1.0f - float(Health)/float(Default.Health);

    	// Check for fear
    	if((0.5 < fTakenDamage) && (!m_bStunned))
    	{
    		if(FRand() < fTakenDamage)
    		{
    			if( Other.bIsPlayer ) //change attitude to player
    			{
    				AttitudeToPlayer 	= ATTITUDE_Fear;
    				Aggressiveness		= 0.1;
    //log("fearing: new attitude: " $ AttitudeToPlayer);
    			}
    			//SetEnemy(Other);
    			NextState = 'Retreating';
    			GotoState('Retreating', 'RunAway');
    		}

    		// Do not continue, if we are frightened
    		return;
    	}
    	else
    	{
    		// Call to base class
    		Super.damageAttitudeTo( Other);
    	}
    }

    // Starts to look for pheromones
    function lookForScent()
    {
    	local vector   	vectLocation;
    	local float 	fImportance;

    	if(smell())
    	{
    		// Call the event function
    		SmellScent(m_fSmellImportance, m_vecSmellLocation);
    	}

    }

    state TakeHit
    {
    ignores seeplayer, hearnoise, bump, hitwall;

    	function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation,
    						Vector momentum, name damageType)
    	{
    //log(self.name $ " receiving damage");

    		Global.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);
    	}

    	function Landed(vector HitNormal)
    	{
    		if (Velocity.Z < -1.4 * JumpZ)
    			MakeNoise(-0.5 * Velocity.Z/(FMax(JumpZ, 150.0)));
    		bJustLanded = true;
    	}

    	function Timer()
    	{
    		bReadyToAttack = true;
    		if ( SpeechTime > 0 )
    		{
    			SpeechTime = -1.0;
    			bIsSpeaking = false;
    			if ( TeamLeader != None )
    				TeamLeader.bTeamSpeaking = false;
    		}
    	}

    	function PlayHitAnim(vector HitLocation, float Damage)
    	{
    		if ( LastPainTime - Level.TimeSeconds > 0.1 )
    		{
    			PlayTakeHit(0.1, hitLocation, Damage);
    			BeginState();
    			GotoState('TakeHit', 'Begin');
    		}
    	}

    	function BeginState()
    	{
    		LastPainTime = Level.TimeSeconds;
    		LastPainAnim = AnimSequence;
    	}

    Begin:
    	// Acceleration = Normal(Acceleration);
    	FinishAnim();
    	if ( skill < 2 )
    		Sleep(0.05);
    	if(m_bStunned)
    		GotoState('Stunned');
    	else if ( (Physics == PHYS_Falling) && !Region.Zone.bWaterZone )
    	{
    		Acceleration = vect(0,0,0);
    		NextAnim = '';
    		GotoState('FallingState', 'Ducking');
    	}
    	else if (NextState != '')
    	{
    		GotoState(NextState, NextLabel);
    	}
    	else
    	{
    		GotoState('Attacking');
    	}
    }

    function bool smell()
    {
    	local SFPheromone 	oParticle;
    	local bool			bFound;
    	local float			fBestImportance, fDist;
    	local vector		vecBestLoc, vecDir;

    	if(0 >= SmellRadius)
    		return false;

    	bFound 		= false;
    	fBestImportance	= 0.0f;

    	foreach RadiusActors(class'SFPheromone', oParticle, SmellRadius, Location)
    	{
    		// class'SFUtils'.Static.sfLogEx(15,"SFScriptedPawn - smell: Actor in range: " $ oParticle.name);
    		if(None != oParticle)
    		{
    			if(oParticle.IsA('SFPheromone'))
    			{
    				bFound = true;
    				// Pheromone calculation
    				vecDir	= 	oParticle.Location - Location;
    				vecDir  *= 	oParticle.m_fImportance;
    				if(fBestImportance < oParticle.m_fImportance)
    				{
    					// Save new best distance
    					fBestImportance		= oParticle.m_fImportance;
    					m_fSmellImportance	= oParticle.m_fImportance;
    					m_vecSmellLocation	= Location + vecDir;
    				}
    			}
    		}
    	}

    	return bFound;
    }

    // Overwritten here to add the "blind" logig
    function SeePlayer(Actor SeenPlayer)
    {
    	//log(class$" has line of sight to player");
    	if(!bCanSee)
    		return;

    	if (SetEnemy(Pawn(SeenPlayer)))
    		LastSeenPos = Enemy.Location;
    }

    function HearNoise(float Loudness, Actor NoiseMaker)
    {
    	local float fDist;

    	// Check for dumb creature;
    	if(!bCanHear)
    		return;

    	//log(class$" heard noise by "$NoiseMaker.class);
    	fDist = vsize(NoiseMaker.Location-Location);

    	if ( SetEnemy(NoiseMaker.instigator) )
    		LastSeenPos = 0.5 * (NoiseMaker.Location + VSize(NoiseMaker.Location - Location) * vector(Rotation));
    }

    event SmellScent(float fImportance, vector vectPosition)
    {
    	LastSeenPos = vectPosition; // 0.5 * (vectPosition + VSize(vectPosition - Location) * vector(Rotation));
    	Destination = LastSeenPos;
    	if (Physics == PHYS_None)
    		SetPhysics(PHYS_Walking);
    //	if(GetStateName() != 'Wandering')
    		GotoState('Wandering', 'Smelled');
    }

    function TweenToWalking(float tweentime)
    {
    	if(AnimSequence != WalkAnim || !bAnimLoop)
    		TweenAnim(WalkAnim, tweentime);
    }

    function PlayWalking()
    {
    	PlaySound(WalkSound, SLOT_Interact);
    	LoopAnim(WalkAnim, -4.0/GroundSpeed,,0.4);
    }

    function TweenToStunned(float tweentime)
    {
    	TweenToWaiting(tweentime);
    }
    function PlayStunned()
    {
    	PlayWaiting();
    }

    function TweenToRunning(float tweentime)
    {
    	if (AnimSequence != RunAnim || !bAnimLoop)
    		TweenAnim(RunAnim, tweentime);
    }

    function PlayRunning()
    {
    	PlaySound(RunSound, SLOT_Interact);
    	LoopAnim(RunAnim, -4.0/GroundSpeed,,0.4);
    }

    function PlayThreatening()
    {
    	local float fAnimRate;

    	fAnimRate = 0.6f + 0.6*FRand();

    	PlaySound(Threaten, SLOT_Interact);
    	LoopAnim(ThreatenAnim, fAnimRate, 0.1 ,0.4); // 0.05); // , -4.0/GroundSpeed,,0.4);
    }

    function PlayTurning()
    {
    	TweenAnim(WalkAnim, 0.3);
    }

    // Assuming a god waiting animation is choosen in
    // the subclass
    function PlayPatrolStop()
    {
    	PlayWaiting();
    }

    function TweenToPatrolStop(float tweentime)
    {
    	TweenToWaiting(tweentime);
    }

    // Assuming a god waiting animation is choosen in
    // the subclass
    function PlayWaitingAmbush()
    {
    	PlayWaiting();
    }

    function PlayTakeHit(float tweentime, vector HitLoc, int damage)
    {
    	PlayAnim(TakeHitAnim);
    }

    function PlayVictoryDance()
    {
    	PlayAnim(VictoryAnim);
    }

    event Tick(float DeltaTime)
    {
    	local name nameState;

    	// Call to base class
    	Super.Tick(DeltaTime);

    	// Log state settings
    	nameState = GetStateName();

    	if((nameState != m_nameStateSaved) || (NextState != m_NextStateSaved) || (NextLabel != m_NextLavelSaved))
    	{

    //		if(None != Enemy)
    //			class'SFUtils'.static.sfLogEx(5, Self.name $ ": State: " $ nameState $ " NextState: " $ NextState $ " NextLabel: " $ NextLabel $ " Enemy: " $ enemy.name $ " AttitutdeToPlayer: " $ AttitudeToPlayer);
    //		else
    //			class'SFUtils'.static.sfLogEx(5, Self.name $ ": State: " $ nameState $ " NextState: " $ NextState $ " NextLabel: " $ NextLabel $ " Enemy: None" $ " AttitutdeToPlayer: " $ AttitudeToPlayer);

    		m_nameStateSaved	= nameState;
    		m_NextStateSaved	= NextState;
    		m_NextLavelSaved	= NextLabel ;
    	}

    	// Are we going to be healed
    	if(-1 != Default.fHealingTimer)
    	{
    		if((0 > fHealingTimer) && (Health < Default.Health))
    		{
    			Health			+=1;
    			fHealingTimer	= Default.fHealingTimer;
    		}
    		else
    			fHealingTimer	-= DeltaTime;
    	}

    	if(m_bStunned)
    	{
    		GotoState('Stunned');
    		return;
    	}

    	// Additional small logic
    	if(bCanSmell)
    	{
    		if((nameState == 'Wandering') || (nameState == 'Roaming') || (nameState=='Waiting') || (nameState == 'Ambushing'))
    		{
    			m_fSmellCounter -= DeltaTime;
    			if(0 >m_fSmellCounter)
    			{
    				m_fSmellCounter = Default.m_fSmellCounter;
    				lookForScent();
    			}
    		}
    	}
    }

    function ChangedWeapon()
    {
    	Super.ChangedWeapon();
    	bIsPlayer = false;
    	bMovingRangedAttack = false;
    	bHasRangedAttack = true;
    	Weapon.AimError += 200;
    //	Weapon.FireOffset = Weapon.FireOffset * 1.5 * DrawScale;
    //	Weapon.PlayerViewOffset = Weapon.PlayerViewOffset * 1.5 * DrawScale;
    }

    function TossWeapon()
    {
    	if ( Weapon == None )
    		return;
    	Weapon.FireOffset = Weapon.Default.FireOffset;
    	Weapon.PlayerViewOffset = Weapon.Default.PlayerViewOffset;
    	Super.TossWeapon();
    }

    function Died(pawn Killer, name damageType, vector HitLocation)
    {
    	bIsPlayer = false;
    	Super.Died(Killer, damageType, HitLocation);
    }

    /////////////// States  //////////////////

    state Hunting
    {
    ignores EnemyNotVisible;

    	// Hunting has a special HearNoise function, since we
    	// are more aware of stimuli. No error is added to the NoiseMaker location
    	function HearNoise(float Loudness, Actor NoiseMaker)
    	{
    		// Can we hear?
    		if(bCanHear)
    			Super.HearNoise(Loudness, NoiseMaker);
    	}

    	function bool SetEnemy(Pawn NewEnemy)
    	{
    		local float rnd;

    		if (Global.SetEnemy(NewEnemy))
    		{
    			rnd = FRand();
    			if ( bReadyToAttack )
    			{
    				if (rnd < 0.3)
    					PlayAcquisitionSound();
    				else if (rnd < 0.6)
    					PlayThreateningSound();
    			}
    			bReadyToAttack = true;
    			DesiredRotation = Rotator(Enemy.Location - Location);
    			if ( !bHasRangedAttack || (CombatStyle > FRand()) )
    				GotoState('Charging');
    			else
    				GotoState('Attacking');
    			return true;
    		}
    		return false;
    	}

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	if ( MoveTarget != None )
    		Goto('SpecialNavig');
    	else
    		Goto('Follow');

    Begin:
    	numHuntPaths = 0;
    	HuntStartTime = Level.TimeSeconds;
    AfterFall:
    	TweenToRunning(0.15);
    	bFromWall = false;

    Follow:
    	WaitForLanding();
    	if ( CanSee(Enemy) && !bCanSee)
    		SetEnemy(Enemy);
    	PickDestination();
    SpecialNavig:
    	if ( SpecialPause > 0.0 )
    	{
    		Disable('AnimEnd');
    		Acceleration = vect(0,0,0);
    		PlayChallenge();
    		Sleep(SpecialPause);
    		SpecialPause = 0.0;
    		Enable('AnimEnd');
    	}
    	if (MoveTarget == None)
    		MoveTo(Destination);
    	else
    		MoveToward(MoveTarget);
    	if ( Intelligence < BRAINS_Human )
    	{
    		if ( FRand() > 0.3 )
    			PlayRoamingSound();
    		else if ( FRand() > 0.3 )
    			PlayThreateningSound();
    	}
    	if ( (Orders == 'Guarding') && (!LineOfSightTo(OrderObject) || !bCanSee) )
    		GotoState('Guarding');
    	Goto('Follow');
    }

    state StakeOut
    {
    ignores EnemyNotVisible;

    	// Hunting has a special HearNoise function, since we
    	// are more aware of stimuli. No error is added to the NoiseMaker location
    	function StakeOut(float Loudness, Actor NoiseMaker)
    	{
    		// Can we hear?
    		if(bCanHear)
    			Super.HearNoise(Loudness, NoiseMaker);
    	}
    }

    // Adds our own stimuli handling
    state Acquisition
    {
    ignores falling, landed; //fixme

    	function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation,
    							Vector momentum, name damageType)
    	{
    		LastSeenPos = Enemy.Location;
    		Global.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);
    		if ( health <= 0 )
    			return;
    		if (NextState == 'TakeHit')
    		{
    			if(bCanSee)
    			{
    				NextState = 'Attacking';
    				NextLabel = 'Begin';
    			}
    			else
    			{
    				NextState = 'Hunting';
    			}
    			GotoState('TakeHit');
    		}
    		else
    		{
    			if(bCanSee)
    				GotoState('Attacking');
    			else
    				GotoState('Hunting');
    		}
    	}

    	// Aquisition has special HearNoise function, since
    	// we have to keep track of the old enemy position
    	function HearNoise(float Loudness, Actor NoiseMaker)
    	{
    		// Can we hear?
    		if(bCanHear)
    			Super.HearNoise(Loudness, NoiseMaker);
    	}

    	function SeePlayer(Actor SeenPlayer)
    	{
    		if(!bCanSee)
    			return;

    		if ( SetEnemy(Pawn(SeenPlayer)) )
    		{
    			PlayAcquisitionSound();
    			//log("Enemy Acquired!");
    			MakeNoise(1.0);
    			NextAnim = '';
    			LastSeenPos = Enemy.Location;
    			GotoState('Attacking');
    		}
    	}

    	function BeginState()
    	{
    		Disable('Tick'); //only used for bounding anim time
    		SetAlertness(-0.5);
    	}

    PlayOut:
    	Acceleration = vect(0,0,0);
    	if ( (AnimFrame < 0.6) && IsAnimating() )
    	{
    		Sleep(0.05);
    		Goto('PlayOut');
    	}

    Begin:
    	SetMovementPhysics();
    	//log("Acquiring enemy");
    	////log("Enemy position = "$Enemy.Location);
    	////log("Last seen position = "$LastSeenPos);
    AcquTurn:
    	Acceleration = vect(0,0,0);
    	if (NeedToTurn(LastSeenPos))
    	{
    		PlayTurning();
    		TurnTo(LastSeenPos);
    	}
    	DesiredRotation = Rotator(LastSeenPos - Location);
    	TweenToFighter(0.2);
    	FinishAnim();
    	////log("Stimulus = "$Stimulus);
    	if ( AttitudeTo(Enemy) == ATTITUDE_Fear )  //will run away from noise
    	{
    		////log("Run away from noise");
    		PlayFearSound();
    		LastSeenPos = Enemy.Location;
    		MakeNoise(1.0);
    		NextAnim = '';
    		if(bCanSee)
    			GotoState('Retreating');
    	}
    	else //investigate noise
    	{
    		////log("investigate noise");
    		if ( pointReachable((Location + LastSeenPos) * 0.5) )
    		{
    			TweenToWalking(0.3);
    			FinishAnim();
    			PlayWalking();
    			MoveTo((Location + LastSeenPos) * 0.5, WalkingSpeed);
    			Acceleration = vect(0,0,0);
    		}
    		WhatToDoNext('','');
    	}
    }

    state Attacking
    {
    ignores SeePlayer, HearNoise, Bump, HitWall;

    	// Handles new stimuli and hear/smell/see logic
    	function ChooseAttackMode()
    	{
    		local eAttitude AttitudeToEnemy;
    		local float Aggression;
    		local pawn changeEn;

    		if(m_bStunned)
    		{
    			GotoState('Stunned');
    			return;
    		}

    		if ((Enemy == None) || (Enemy.Health <= 0))
    		{
    			if (Orders == 'Attacking')
    				Orders = '';
    			WhatToDoNext('','');
    			return;
    		}

    		if ( (AlarmTag != '') && Enemy.bIsPlayer )
    		{
    			if (AttitudeToPlayer > ATTITUDE_Ignore)
    			{
    				GotoState('AlarmPaused', 'WaitForPlayer');
    				return;
    			}
    			else if ( (AttitudeToPlayer != ATTITUDE_Fear) || bInitialFear )
    			{
    				GotoState('TriggerAlarm');
    				return;
    			}
    		}

    		AttitudeToEnemy = AttitudeTo(Enemy);

    		if (AttitudeToEnemy == ATTITUDE_Fear)
    		{
    			GotoState('Retreating');
    			return;
    		}

    		else if (AttitudeToEnemy == ATTITUDE_Threaten)
    		{
    			GotoState('Threatening');
    			return;
    		}

    		else if (AttitudeToEnemy == ATTITUDE_Friendly)
    		{
    			if (Enemy.bIsPlayer)
    				GotoState('Greeting');
    			else
    				WhatToDoNext('','');
    			return;
    		}

    		else if (!LineOfSightTo(Enemy) || !bCanSee)
    		{
    			if ( (OldEnemy != None)
    				&& (AttitudeTo(OldEnemy) == ATTITUDE_Hate) && LineOfSightTo(OldEnemy) && bCanSee )
    			{
    				changeEn = enemy;
    				enemy = oldenemy;
    				oldenemy = changeEn;
    			}
    			else
    			{
    				if ( (Orders == 'Guarding') && (!LineOfSightTo(OrderObject) || !bCanSee) )
    					GotoState('Guarding');
    				else if ( !bHasRangedAttack || VSize(Enemy.Location - Location)
    							> 600 + (FRand() * RelativeStrength(Enemy) - CombatStyle) * 600 )
    					GotoState('Hunting');
    				else if ( bIsBoss || (Intelligence > BRAINS_None) )
    				{
    					HuntStartTime = Level.TimeSeconds;
    					NumHuntPaths = 0;
    					GotoState('StakeOut');
    				}
    				else
    					WhatToDoNext('Waiting', 'TurnFromWall');
    				return;
    			}
    		}

    		else if ( (TeamLeader != None) && TeamLeader.ChooseTeamAttackFor(self) )
    			return;
    		if (bReadyToAttack)
    		{
    			////log("Attack!");
    			Target = Enemy;
    			If (VSize(Enemy.Location - Location) <= (MeleeRange + Enemy.CollisionRadius + CollisionRadius))
    			{
    				GotoState('MeleeAttack');
    				return;
    			}
    			else if (bMovingRangedAttack)
    				SetTimer(TimeBetweenAttacks, False);
    			else if (bHasRangedAttack && (bIsPlayer || enemy.bIsPlayer) && CanFireAtEnemy() )
    			{
    				if (!bIsPlayer || (2.5 * FRand() > Skill) )
    				{
    					GotoState('RangedAttack');
    					return;
    				}
    			}
    		}

    		if(!bCanSee)
    		{
    			// Handle blind here
    			if(FRand() < 0.9)
    				GotoState('Hunting');
    		}
    		//decide whether to charge or make a tactical move
    		if ( !bHasRangedAttack )
    		{
    			GotoState('Charging');
    		}
    		else
    		{
    			GotoState('TacticalMove');
    		}
    		//log("Next state is "$state);
    	}

    }

    // Overwritten to do our own stimuli handling
    state MeleeAttack
    {
    ignores SeePlayer, HearNoise, Bump;

    	function KeepAttacking()
    	{

    		// Handle blind pawn
    		if((!bCanSee) && (FRand() < 0.8))
    			GotoState('Retreating');

    		if ( (Enemy == None) || (Enemy.Health <= 0)
    			|| (VSize(Enemy.Location - Location) > (MeleeRange + Enemy.CollisionRadius + CollisionRadius)) )
    			GotoState('Attacking');
    	}
    }

    state RangedAttack
    {
    ignores SeePlayer, HearNoise, Bump;

    	function KeepAttacking()
    	{
    		// Handle blind pawn
    		if((!bCanSee) && (FRand() < 0.8))
    			GotoState('Retreating');

    		if ( !bFiringPaused && ((FRand() > ReFireRate) || (Enemy == None) || (Enemy.Health <= 0) || !CanFireAtEnemy()) )
    			GotoState('Attacking');
    	}
    }

    state Retreating
    {
    ignores SeePlayer, EnemyNotVisible, HearNoise;

    	// Handles new stimuli and hear/smell/see logic
    	function ReachedHome()
    	{
    		if (LineOfSightTo(Enemy) && bCanSee)
    		{
    			if (Homebase(home) != None)
    			{
    				//log(class$" reached home base - turn and fight");
    				Aggressiveness += 0.2;
    				if ( !bMoraleBoosted )
    					health = Min(default.health, health+20);
    				MakeNoise(1.0);
    				GotoState('Attacking');
    			}
    			else
    				ChangeDestination();
    		}
    		else
    		{
    			if (Homebase(home) != None)
    				MakeNoise(1.0);
    			aggressiveness += 0.2;
    			if ( !bMoraleBoosted )
    				health = Min(default.health, health+5);
    			GotoState('Retreating', 'TurnAtHome');
    		}
    		bMoraleBoosted = true;
    	}

    	function AnimEnd()
    	{
    		if ( bSpecialPausing )
    			PlayPatrolStop();
    		else if ( bCanFire && LineOfSightTo(Enemy) && bCanSee)
    			PlayCombatMove();
    		else
    			PlayRunning();
    	}

    	/* if has a base then run toward it if its not visible to player. (FIXME)
    	adjusts attitude based on proximity to base
    	Else pick a random pathnode not visible to player and run toward it.
    	Also - modify weights of paths visible and near to player up.
    	*/
    	function PickDestination()
    	{
    	 	//log("find retreat destination");
    		if (HomeBase(Home) == None)
    		{
    			Home = FindRandomDest(); //find temporary home
    			if (Home == None)
    			{
    				if (bReadyToAttack)
    				{
    					setTimer(3.0, false);
    					Target = Enemy;
    					GotoState('RangedAttack');
    				}
    				else
    				{
    					// Changed from original code, to wait for
    					// healing, before attacking again
    					if(getHurtRate() < 0.8)
    						Aggressiveness += 0.3;
    					GotoState('TacticalMove', 'NoCharge');
    				}
    			}
    		}
    	}

    	function ChangeDestination()
    	{
    		local actor oldTarget;
    		local Actor path;

    		oldTarget = Home;
    		PickDestination();
    		if (Home == oldTarget)
    		{
    			Aggressiveness += 0.3;
    			//log("same old target");
    			GotoState('TacticalMove', 'TacticalTick');
    		}
    		else
    		{
    			path = FindPathToward(Home);
    			if (path == None)
    			{
    				// Changed from original code, to wait for
    				// healing, before attacking again
    				if(getHurtRate() < 0.8)
    					Aggressiveness += 0.3;
    				GotoState('TacticalMove', 'TacticalTick');
    			}
    			else
    			{
    				MoveTarget = path;
    				Destination = path.Location;
    			}
    		}
    	}

    Begin:
    	if ( bReadyToAttack && (FRand() < 0.6) )
    	{
    		SetTimer(TimeBetweenAttacks, false);
    		bReadyToAttack = false;
    	}
    	TweenToRunning(0.1);
    	WaitForLanding();
    	PickDestination();

    Landed:
    	TweenToRunning(0.1);

    RunAway:
    	PickNextSpot();
    SpecialNavig:
    	if (SpecialPause > 0.0)
    	{
    		if ( LineOfSightTo(Enemy) && bCanSee )
    		{
    			bFiringPaused = true;
    			NextState = 'Retreating';
    			NextLabel = 'Moving';
    			GotoState('RangedAttack');
    		}
    		bSpecialPausing = true;
    		Acceleration = vect(0,0,0);
    		TweenToPatrolStop(0.25);
    		Sleep(SpecialPause);
    		SpecialPause = 0.0;
    		bSpecialPausing = false;
    		TweenToRunning(0.1);
    	}
    Moving:
    	if ( MoveTarget == None )
    	{
    		Sleep(0.0);
    		Goto('RunAway');
    	}
    	if ( !bCanStrafe || !LineOfSightTo(Enemy) || !bCanSee ||
    		(Skill - 2 * FRand() + (Normal(Enemy.Location - Location - vect(0,0,1) * (Enemy.Location.Z - Location.Z))
    			Dot Normal(MoveTarget.Location - Location - vect(0,0,1) * (MoveTarget.Location.Z - Location.Z))) < 0) )
    	{
    		bCanFire = false;
    		MoveToward(MoveTarget);
    	}
    	else
    	{
    		bCanFire = true;
    		StrafeFacing(MoveTarget.Location, Enemy);
    	}
    	Goto('RunAway');

    TakeHit:
    	TweenToRunning(0.12);
    	Goto('Moving');

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	MoveTo(Destination);
    	Goto('Moving');

    TurnAtHome:
    	Acceleration = vect(0,0,0);
    	TurnTo(Homebase(Home).lookdir);
    	GotoState('Ambushing', 'FindAmbushSpot');

    }

    state Charging
    {
    ignores SeePlayer, HearNoise;

    	// changed for our own stimuli
    	function Timer()
    	{
    		bReadyToAttack = True;
    		if(bCanSee)
    		{
    			Target = Enemy;
    			if (VSize(Enemy.Location - Location)
    					<= (MeleeRange + Enemy.CollisionRadius + CollisionRadius))
    				GotoState('MeleeAttack');
    			else if ( bHasRangedAttack && (FRand() > 0.7 + 0.1 * skill) )
    				GotoState('RangedAttack');
    			else if ( bHasRangedAttack && !bMovingRangedAttack)
    			{
    				if ( FRand() < CombatStyle * 0.8 ) //then keep charging
    					SetTimer(1.0,false);
    				else
    					GotoState('Attacking');
    			}
    		}
    	}

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Goto('CloseIn');

    ResumeCharge:
    	PlayRunning();
    	Goto('Charge');
    Begin:
    	TweenToRunning(0.15);

    Charge:
    	bFromWall = false;

    CloseIn:
    	if ( (Enemy == None) || (Enemy.Health <=0) )
    		GotoState('Attacking');

    	if ( Enemy.Region.Zone.bWaterZone )
    	{
    		if (!bCanSwim)
    			GotoState('TacticalMove', 'NoCharge');
    	}
    	else if (!bCanFly && !bCanWalk)
    		GotoState('TacticalMove', 'NoCharge');

    	if (Physics == PHYS_Falling)
    	{
    		DesiredRotation = Rotator(Enemy.Location - Location);
    		Focus = Enemy.Location;
    		Destination = Enemy.Location;
    		WaitForLanding();
    	}
    	if( (Intelligence <= BRAINS_Reptile) || actorReachable(Enemy) )
    	{
    		bCanFire = true;
    		if ( FRand() < 0.3 )
    			PlayThreateningSound();
    		if(bCanSee)
    		{
    			MoveToward(Enemy);
    		}
    		else
    		{
    			MoveTo(LastSeenPos, WalkingSpeed);
    		}
    		if (bFromWall)
    		{
    			bFromWall = false;
    			if (PickWallAdjust())
    			{
    				StrafeFacing(Destination, Enemy);
    			}
    			else
    			{
    				GotoState('TacticalMove', 'NoCharge');
    			}
    		}
    	}
    	else
    	{
    NoReach:
    		bCanFire = false;
    		bFromWall = false;
    		//log("route to enemy "$Enemy);
    		if (!FindBestPathToward(Enemy))
    		{
    			Sleep(0.0);
    			GotoState('TacticalMove', 'NoCharge');
    		}
    SpecialNavig:
    		if ( SpecialPause > 0.0 )
    		{
    			bFiringPaused = true;
    			NextState = 'Charging';
    			NextLabel = 'Moving';
    			GotoState('RangedAttack');
    		}
    Moving:
    		if (VSize(MoveTarget.Location - Location) < 2.5 * CollisionRadius)
    		{
    			bCanFire = true;
    			StrafeFacing(MoveTarget.Location, Enemy);
    		}
    		else
    		{
    			if ( !bCanStrafe || !LineOfSightTo(Enemy) || !bCanSee ||
    				(Skill - 2 * FRand() + (Normal(Enemy.Location - Location - vect(0,0,1) * (Enemy.Location.Z - Location.Z))
    					Dot Normal(MoveTarget.Location - Location - vect(0,0,1) * (MoveTarget.Location.Z - Location.Z))) < 0) )
    			{
    				if ( GetAnimGroup(AnimSequence) == 'MovingAttack' )
    				{
    					AnimSequence = '';
    					TweenToRunning(0.12);
    				}
    				MoveToward(MoveTarget);
    			}
    			else
    			{
    				bCanFire = true;
    				StrafeFacing(MoveTarget.Location, Enemy);
    			}
    			if ( !bFromWall && (FRand() < 0.5) )
    				PlayThreateningSound();
    		}
    	}

    	//log("finished move");
    	if (VSize(Location - Enemy.Location) < CollisionRadius + Enemy.CollisionRadius + MeleeRange)
    	{
    		Goto('GotThere');
    	}
    	if ( bIsPlayer || (!bFromWall && bHasRangedAttack && (FRand() > CombatStyle + 0.1)) )
    	{
    		GotoState('Attacking');
    	}
    	MoveTimer = 0.0;
    	bFromWall = false;

    	// Blind ones will not close in
    	if(!bCanSee)
    		GotoState('Roaming');

    	Goto('CloseIn');

    GotThere:
    	////log("Got to enemy");
    	Target = Enemy;
    	GotoState('MeleeAttack');

    TakeHit:
    	TweenToRunning(0.12);
    	if (MoveTarget == Enemy)
    	{
    		bCanFire = true;
    		MoveToward(MoveTarget);
    	}

    	Goto('Charge');
    }

    state TacticalMove
    {
    ignores SeePlayer, HearNoise;

    	function GiveUpTactical(bool bNoCharge)
    	{
    		if((m_nTacticalCounter < 5) && (getHurtRate() > 0.5))
    		{
    			m_nTacticalCounter++;
    			if(5 == m_nTacticalCounter)
    			{
    				m_nTacticalCounter=0;
    				GotoState('Wandering', 'Smelled');
    			}
    		}
    		else if (m_nTacticalCounter >= 5)
    			m_nTacticalCounter =0;

    		if ( !bNoCharge && (2 * CombatStyle > (3 - Skill) * FRand()) )
    			GotoState('Charging');
    		else if ( bReadyToAttack && (skill > 3 * FRand() - 1) )
    			GotoState('RangedAttack');
    		else
    			GotoState('RangedAttack', 'Challenge');
    	}

    //FIXME - what if bReadyToAttack at start
    TacticalTick:
    	Sleep(0.02);
    Begin:
    	TweenToRunning(0.15);
    	Enable('AnimEnd');
    	if (Physics == PHYS_Falling)
    	{
    		DesiredRotation = Rotator(Enemy.Location - Location);
    		Focus = Enemy.Location;
    		Destination = Enemy.Location;
    		WaitForLanding();
    	}
    	PickDestination(false);

    DoMove:
    	if ( !bCanStrafe )
    	{
    DoDirectMove:
    		Enable('AnimEnd');
    		if ( GetAnimGroup(AnimSequence) == 'MovingAttack' )
    		{
    			AnimSequence = '';
    			TweenToRunning(0.12);
    		}
    		bCanFire = false;
    		MoveTo(Destination);
    	}
    	else
    	{
    DoStrafeMove:
    		Enable('AnimEnd');
    		bCanFire = true;
    		StrafeFacing(Destination, Enemy);
    	}
    	if (FRand() < 0.5)
    		PlayThreateningSound();

    	if ( (Enemy != None) && (!LineOfSightTo(Enemy) || !bCanSee) && ValidRecovery() )
    		Goto('RecoverEnemy');
    	else
    	{
    		bReadyToAttack = true;
    		GotoState('Attacking');
    	}

    NoCharge:
    	TweenToRunning(0.15);
    	Enable('AnimEnd');
    	if (Physics == PHYS_Falling)
    	{
    		DesiredRotation = Rotator(Enemy.Location - Location);
    		Focus = Enemy.Location;
    		Destination = Enemy.Location;
    		WaitForLanding();
    	}
    	PickDestination(true);
    	Goto('DoMove');

    AdjustFromWall:
    	Enable('AnimEnd');
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	Goto('DoMove');

    TakeHit:
    	TweenToRunning(0.12);
    	Goto('DoMove');

    RecoverEnemy:
    	Enable('AnimEnd');
    	bReadyToAttack = true;
    	HidingSpot = Location;
    	bCanFire = false;
    	Destination = LastSeeingPos + 3 * CollisionRadius * Normal(LastSeeingPos - Location);
    	if ( bCanStrafe || (VSize(LastSeeingPos - Location) < 3 * CollisionRadius) )
    		StrafeFacing(Destination, Enemy);
    	else
    		MoveTo(Destination);
    	if ( Weapon == None )
    		Acceleration = vect(0,0,0);
    	if ( NeedToTurn(Enemy.Location) )
    	{
    		PlayTurning();
    		TurnToward(Enemy);
    	}
    	if ( bHasRangedAttack && CanFireAtEnemy() )
    	{
    		Disable('AnimEnd');
    		DesiredRotation = Rotator(Enemy.Location - Location);
    		if ( Weapon == None )
    		{
    			PlayRangedAttack();
    			FinishAnim();
    			TweenToRunning(0.1);
    			bReadyToAttack = false;
    			SetTimer(TimeBetweenAttacks, false);
    		}
    		else
    		{
    			FireWeapon();
    			if ( Weapon.bSplashDamage )
    			{
    				bFire = 0;
    				bAltFire = 0;
    			}
    		}

    		if ( bCanStrafe && (FRand() + 0.1 > CombatStyle) )
    		{
    			Enable('EnemyNotVisible');
    			Enable('AnimEnd');
    			Destination = HidingSpot + 4 * CollisionRadius * Normal(HidingSpot - Location);
    			Goto('DoMove');
    		}
    	}
    	if ( !bMovingRangedAttack )
    		bReadyToAttack = false;

    	GotoState('Attacking');
    }

    state TriggerAlarm
    {
    	ignores HearNoise, SeePlayer;
    	function AlarmDone()
    	{
    		local pawn OtherPawn;
    		local Actor A;
    		local AlarmPoint AlarmSpot;

    		AlarmSpot = AlarmPoint(OrderObject);
    		if ( AlarmSpot != None )
    		{
    			if( AlarmSpot.Event != '' )
    				foreach AllActors( class 'Actor', A, AlarmSpot.Event )
    				{
    					if ( (ScriptedPawn(A) != None) && AlarmSpot.bKillMe )
    						ScriptedPawn(A).Hated = self;
    					A.Trigger( self, instigator );
    				}
    			if ( AlarmSpot.bDestroyAlarmTriggerer )
    			{
    				OtherPawn = Level.PawnList;
    				while ( OtherPawn != None )
    				{
    					OtherPawn.Killed(self, self, '');
    					OtherPawn = OtherPawn.nextPawn;
    				}
    				level.game.Killed(self, self, '');
    				//log(class$" dying");
    				if( Event != '' )
    					foreach AllActors( class 'Actor', A, Event )
    						A.Trigger( Self, Instigator );
    				Weapon = None;
    				Level.Game.DiscardInventory(self);
    				Destroy();
    				return;
    			}
    			AlarmTag = AlarmSpot.NextAlarm;

    			if ( AlarmSpot.pausetime > 0.0 )
    			{
    				Acceleration = vect(0,0,0);
    				if (AttitudeTo(Enemy) > ATTITUDE_Ignore)
    					GotoState('AlarmPaused', 'WaitAround');
    				else
    					GotoState('AlarmPaused');
    			}
    			else if ( AlarmTag != '' )
    			{

    				FindAlarm();

    				GotoState('TriggerAlarm', 'Begin');
    			}
    			else if (AttitudeTo(Enemy) > ATTITUDE_Ignore)
    			{
    				Acceleration = vect(0,0,0);
    				GotoState('Roaming');
    			}
    			else
    			{
    				bReadyToAttack = true;
    				GotoState('Attacking');
    			}
    			return;
    		}

    		AlarmTag = '';

    		if (AttitudeToPlayer > ATTITUDE_Ignore)
    			GotoState('AlarmPaused', 'WaitAround');
    		else
    		{
    			bReadyToAttack = true;
    			GotoState('Attacking');
    		}
    	}

    /*
    	function FindAlarm()
    	{
    		if ( (OrderObject == None) || (OrderObject.Tag != AlarmTag) ) //find alarm object
    		{
    			if ( (AlarmPoint(OrderObject) != None) && (AlarmPoint(OrderObject).NextAlarm == AlarmTag) )
    				OrderObject = AlarmPoint(OrderObject).NextAlarmObject;
    			else if ( AlarmTag != '' )
    				foreach AllActors(class 'Actor', OrderObject, AlarmTag)
    					break;
    		}
    		if ( (OrderObject == None) || (OrderObject.Tag != AlarmTag) )
    		{
    			AlarmTag = '';
    			GotoState('Attacking');
    		}
    	}
    */
    Recover:
    	if ( (AlarmPoint(OrderObject) != None) && !AlarmPoint(OrderObject).bNoFail
    		&& !actorReachable(OrderObject) )
    	{
    		AlarmTag='';
    		GotoState('Attacking');
    	}

    Begin:
    	bReadyToAttack = false;
    	Target = Enemy;
    	TweenToRunning(0.15);
    	bFromWall = false;

    CloseIn:
    	WaitForLanding();
    	Enable('AnimEnd');
    	if ( OrderObject == None )
    	{
    		Alarmtag = '';
    		GotoState('Attacking');
    	}
    	If ( actorReachable(OrderObject) )
    	{
    		if ( bCanStrafe && (AlarmPoint(OrderObject) != None) && AlarmPoint(OrderObject).bStrafeTo )
    		{
    			bCanFire = true;
    			StrafeFacing(OrderObject.Location, Enemy);
    		}
    		else
    		{
    			bCanFire = false;
    			MoveToward(OrderObject);
    		}
    	}
    	else
    	{
    		if (SpecialGoal != None)
    			MoveTarget = FindPathToward(SpecialGoal);
    		else
    			MoveTarget = FindPathToward(OrderObject);
    		if (MoveTarget == None)
    		{
    			AlarmTag = '';
    			GotoState('Attacking');
    		}
    		if ( SpecialPause > 0.0 )
    		{
    			if ( (AlarmPoint(OrderObject) != None) && AlarmPoint(OrderObject).bStrafeTo )
    			{
    				bFiringPaused = true;
    				NextState = 'Charging';
    				NextLabel = 'Moving';
    				GotoState('RangedAttack');
    			}
    			bSpecialPausing = true;
    			Acceleration = vect(0,0,0);
    			TweenToPatrolStop(0.3);
    			if ( (SpecialPause == 2.5) && IsA('Nali') )
    				SpecialPause = 8;
    			Sleep(SpecialPause);
    			SpecialPause = 0.0;
    			TweenToRunning(0.1);
    			bSpecialPausing = False;
    		}
    		if ( bCanStrafe && (AlarmPoint(OrderObject) != None) && AlarmPoint(OrderObject).bStrafeTo )
    		{
    			bCanFire = true;
    			StrafeFacing(MoveTarget.Location, Enemy);
    		}
    		else
    		{
    			bCanFire = false;
    			MoveToward(MoveTarget);
    		}

    		if ( !bNoWait && (AttitudeToPlayer > ATTITUDE_Ignore)
    			&& ((VSize(Location - Enemy.Location) > CollisionRadius + Enemy.CollisionRadius + 320)
    				|| !LineOfSightTo(Enemy) || !bCanSee) )
    		{
    			Acceleration = vect(0,0,0);
    			GotoState('AlarmPaused', 'WaitForPlayer');
    		}
    	}

    	if ( ( NavigationPoint(OrderObject) != None)
    		&& (VSize(Location - OrderObject.Location) < CollisionRadius + Abs(CollisionHeight - OrderObject.CollisionHeight)) )
    		Touch(OrderObject);
    	else if ( VSize(Location - OrderObject.Location) <
    			CollisionRadius + CollisionHeight + OrderObject.CollisionRadius + 10 )
    		Touch(OrderObject);

    	Goto('CloseIn');

    }

    state Wandering
    {
    	ignores EnemyNotVisible;
    Begin:

    	//log(class$" Wandering");

    Wander:
    	TweenToWalking(0.15);
    	WaitForLanding();
    	PickDestination();
    	FinishAnim();
    	PlayWalking();

    Moving:
    	Enable('HitWall');
    	MoveTo(Destination, WalkingSpeed);
    Pausing:
    	Acceleration = vect(0,0,0);
    	if ( NearWall(2 * CollisionRadius + 50) )
    	{
    		PlayTurning();
    		TurnTo(Focus);
    	}
    	if (FRand() < 0.3)
    		PlayRoamingSound();
    	Enable('AnimEnd');
    	NextAnim = '';
    	TweenToPatrolStop(0.2);
    	Sleep(1.0);
    	Disable('AnimEnd');
    	FinishAnim();
    	Goto('Wander');

    ContinueWander:
    	FinishAnim();
    	PlayWalking();
    	if ( !bQuiet && (FRand() < 0.3) )
    		PlayRoamingSound();
    	if (FRand() < 0.2)
    		Goto('Turn');
    	Goto('Wander');

    Turn:
    	Acceleration = vect(0,0,0);
    	PlayTurning();
    	TurnTo(Location + 20 * VRand());
    	Goto('Pausing');

    AdjustFromWall:
    	StrafeTo(Destination, Focus);
    	Destination = Focus;
    	Goto('Moving');

    Smelled:
    	FinishAnim();
    	TweenToWalking(0.15);
    	WaitForLanding();
    	PlayWalking();
    	MoveTo(Destination, WalkingSpeed);
    	FinishAnim();
    	PlayWalking();
    	Goto('Moving');

    }

    state Stunned
    {
    	ignores SeePlayer, EnemyNotVisible, HearNoise, bump, hitwall, SmellScent;

    	function TakeDamage( int Damage, Pawn instigatedBy, Vector hitlocation,
    							Vector momentum, name damageType)
    	{
    		class'SFUtils'.static.sfLogEx(5,"SFScritptedPawn - TakeDamage: " $ damage $ " type: " $ damageType);
    		Global.TakeDamage(Damage, instigatedBy, hitlocation, momentum, damageType);
    		if ( health <= 0 )
    			return;
    	}

    	function Bump(actor Other)
    	{
    	}

    	simulated function Tick(float DeltaTime)
    	{
    		local int IdealFatness;
    		local rotator	rotNew;
    		local float		fRnd;

    		m_fStunnedCounter	+= DeltaTime;
    		if(m_fStunnedCounter>0.05)
    		{
    			fRnd			= FRand()*2-1;
    			rotNew			= m_rotSavedRot;
    			rotNew.Yaw		+= fRnd *2048;
    			rotNew.Roll		+= fRnd *256;
    			SetRotation(rotNew);
    			m_fStunnedCounter	= 0.05;
    		}

    		IdealFatness	= Fatness; // Convert to int for safety.
    		IdealFatness	+= m_oStunnedEffect.FatnessOffset;

    		if ( m_oStunnedEffect.Fatness > IdealFatness )
    			m_oStunnedEffect.Fatness = Max(IdealFatness, m_oStunnedEffect.Fatness - 130 * DeltaTime);
    		else
    			m_oStunnedEffect.Fatness = Min(IdealFatness, 255);
    	}

    	function Timer()
    	{
    		// Check for maximum stunned rounds
    		if((FRand() < 0.7) || (2<m_nStunnedRound))
    		{
    			//class'SFUtils'.static.sfLogEx(5,"SFScritptedPawn - Stunned - Timer: " $ Self.name $ " Expired, leaving state");
    			GotoState('Waiting');
    		}
    		else
    		{
    			SetTimer(fStunnedTime, false);
    			// Increase the counter
    			m_nStunnedRound++;
    		}
    	}

    	function EnemyAcquired()
    	{
    	}

    	function AnimEnd()
    	{
    		PlayStunned();
    		bStasis = true;
    	}

    	function Landed(vector HitNormal)
    	{
    		SetPhysics(PHYS_None);
    	}

    	function BeginState()
    	{
    		//class'SFUtils'.static.sfLogEx(5,"SFScritptedPawn - BeginState: " $ Self.name $ " entering stunned");
    		SetTimer(fStunnedTime, false);
    		Enemy = None;
    		bStasis = false;
    		Acceleration	= vect(0,0,0);
    		m_nStunnedRound	= 0;
    		m_rotSavedRot	= ViewRotation;

    		m_oStunnedEffect 			= Spawn(class'SFStunnedEffect', Self,,Self.Location, Self.Rotation);
    		m_oStunnedEffect.Mesh 		= Mesh;
    		m_oStunnedEffect.DrawScale 	= Drawscale;
    		m_oStunnedEffect.ScaleGlow 	= 1.0;
    		m_oStunnedEffect.Texture 	= FireTexture'k_GorillaTex.FX.sfhwstun';

    	}

    	function EndState()
    	{
    		// Restore rot
    		SetRotation(m_rotSavedRot);

    		//class'SFUtils'.static.sfLogEx(5,"SFScritptedPawn - BeginState: " $ Self.name $ "  leaving stunned");
    		SetTimer(0.0f, false);
    		m_oStunnedEffect.Destroy();
    		m_oStunnedEffect= None;
    		// Reset the stunned flag
    		m_bStunned=false;

    	}

    Begin:
    	TweenToStunned(0.4);
    	bReadyToAttack = false;
    	DesiredRotation = rot(0,0,0);
    	DesiredRotation.Yaw = Rotation.Yaw;
    	SetRotation(DesiredRotation);
    	if (Physics != PHYS_Falling)
    		SetPhysics(PHYS_None);
    KeepWaiting:
    	NextAnim = '';

    }

    auto state Startup
    {

    	// Overwritten, to spawn a weapon
    	function BeginState()
    	{
    		// Call to base class
    		Super.BeginState();

    		// This pawn can handle a weapon
    		if ( WeaponType != None )
    		{
    			bIsPlayer = true;
    			myWeapon = Spawn(WeaponType);
    			if ( myWeapon != None )
    				myWeapon.ReSpawnTime = 0.0;
    		}
    		if(bFightOtherCreatures)
    			if(FRand()<0.7)
    				bFightOtherCreatures=false;
    	}

    	function SetHome()
    	{
    		// Call to base class
    		Super.SetHome();
    		if ( myWeapon != None )
    			myWeapon.Touch(self);
    	}
    Begin:
    	SetHome();
    	if (SharedAlarmTag != '')
    		SetAlarm();
    	if (TeamTag != '')
    		SetTeam();
    	if (Orders == 'Guarding')
    	{
    		OrderObject = Spawn(class 'GuardPoint');
    		if (OrderTag != '')
    			Tag = OrderTag; //so will be triggered if guarded object is touched
    	}
    	else if (!bFixedStart)
    	{
    		if (Orders == 'Patroling')
    			InitPatrolLoc();
    		else if (Orders == 'Ambushing')
    			InitAmbushLoc();
    	}

    	if (Orders != '')
    	{
    		if (Orders == 'Attacking')
    		{
    			Orders = '';
    			if (enemy != None)
    				GotoState('Attacking');
    			else
    				StartRoaming();
    		}
    		else if ( bDelayedPatrol && (Orders == 'Patroling') )
    			GotoState('Patroling', 'DelayedPatrol');
    		else
    			GotoState(Orders);
    		if ( Physics == PHYS_Falling )
    			SetFall();
    		else
    			SetMovementPhysics();
    	}
    	else
    		GotoState('Waiting');
    }

    defaultproperties
    {
         SmellRadius=500.000000
         bCanHear=True
         bCanSee=True
         bCanSmell=True
         fHealingTimer=30.000000
         fStunnedTime=5.000000
         bFightOtherCreatures=True
         m_fSmellCounter=5.000000
         TimeBetweenAttacks=0.800000
         Aggressiveness=0.900000
    }

class file time: 12/7/2003 3:58:24 PM - creation time: 12/7/2003 4:03:45 PM
Created with UnCodeX